algoritmo (visualg) (iniciante)

[MatheusArtilino]

algoritmo "ativ2"

var
   vet1,vet2 :vetor[1..10] de inteiro
   vet3 :vetor[1..20] de inteiro
   c,x  :inteiro
inicio
   c:= 0
   x:= 0
   escreval (" *preenchendo o vetor 1* ")
   para c de 1 ate 10 faca
      escreval ("=========================")
      escreva (" informe o ",c," número: ")
      leia (vet1[c])
      escreval ("=========================")
      escreval (" *preenchendo o vetor 2* ")
      escreval ("=========================")
      escreva (" informe o ",c," número: ")
      leia (vet2[c])
      escreval ("=========================")
   fimpara
   para x de 1 ate 20 faca
      vet3[x] := vet1[c]
      x:= (x)+(1)
      vet3[x] := vet2[c]
      x:= (x)+(1)
   fimpara
fimalgoritmo

estou com problemas com esse algoritmo, alguém poderia me ajudar ?

[Simon Viegas]

Olá @MatheusArtilino. Seja bem vindo ao Fórum do Clube do Hardware...

 

O comando de "atribuição" no VisuAlg é "<-", em vez de ":=".

 

Outra coisa, precisa seguir a ordem estipulada no enunciado, ou seja, primeiro ler o primeiro vetor, depois ler o segundo... você está fazendo ao mesmo tempo.

 

Dentro do para você está controlando o x tanto pelo para, tanto manualmente (x<-x+1)... não é uma boa ideia. Ou controla só pelo para e ajusta o código, ou implementa usando outra estrutura de repetição, como repita ou enquanto.

 

No aguardo.

 

 

 

[MatheusArtilino]

algoritmo "ativ2"

var
   vet1,vet2 :vetor[1..10] de inteiro
   vet3 :vetor[1..20] de inteiro
   c,x  :inteiro
inicio
   escreval (" *preenchendo o vetor 1* ")
   para c de 1 ate 10 faca
      escreval ("=========================")
      escreva (" informe o ",c," número: ")
      leia (vet1[c])
      escreval ("=========================")
   fimpara
   escreval (" *preenchendo o vetor 2* ")
   para c de 1 ate 10 faca
      escreval ("=========================")
      escreva (" informe o ",c," número: ")
      leia (vet2[c])
      escreval ("=========================")
   fimpara
   c:= 0
   x:= 0
   repita
      c:= (c)+(1)
      x:= (x)+(1)
      vet3[x]:= (vet1[c])
      x:=(x)+(1)
      vet3[x]:= (vet2[c])
   ate (c=10)
   limpatela
   escreval ("=========================================")
   escreval (" * informando  vetor 1 * ")
   para c de 1 ate 10 faca
      escreva (vet1[c],",")
   fimpara
   escreval (" ")
   escreval ("=========================================")
   escreval (" * informando  vetor 2 * ")
   para c de 1 ate 10 faca
      escreva (vet2[c],",")
   fimpara
   escreval (" ")
   escreval ("=========================================")
   escreval (" * informando  vetor 3 [intercalação] * ")
   para x de 1 ate 20 faca
      escreva (vet3[x], ",")
   fimpara
fimalgoritmo

@simon viegas  obrigado por responder, consegui finalizar o algoritmo.

[Simon Viegas]

 

 

@MatheusArtilino, massa...

 

Aproveitando, caso não conheça, apresento um recurso interessante do VisuAgl: ALEATORIO. Com ele, o próprio VisuAlg gera os números automaticamente... facilita muito na hora de testar, ex.:

 

...
inicio
ALEATORIO ON
escreval (" *preenchendo o vetor 1* ")
para c de 1 ate 10 faca
   escreval ("=========================")
   escreva (" informe o ",c," número: ")
   leia (vet1[c])
   escreval ("=========================")
fimpara
escreval (" *preenchendo o vetor 2* ")
para c de 1 ate 10 faca
   escreval ("=========================")
   escreva (" informe o ",c," número: ")
   leia (vet2[c])
   escreval ("=========================")
fimpara
ALEATORIO OFF
c:=0
x:=0
...

É auto explicativo... os leia()  que estiverem dentro do ON e OFF são preenchidos com valores aleatório automaticamente.

 

Outra coisa, dá para fazer com o para também. Se quiser parar para tentar, fique a vontade... uma dica seria utilizando o x de 1 a 10 e fazer a uma correlação das posições entre os vetores...