Ir ao conteúdo
  • Cadastre-se
Amilton Cândido

VisualG Salário líquindo de funcionário

Recommended Posts

Construa um algoritmo em Visualg, que calcule o salário líquido de um funcionário. O programa recebe o salário bruto do funcionário, caso este seja inferior a R$1.000,00 é descontado 7% em impostos, se o salário variar de R$ 1.000,00 até R$1.500,00 é descontado 12% em imposto, se for superior a R$1.500,00 é descontado 15%. Ao final o programa deve exibir o nome e o salário líquido do funcionário.

 

Aonde está o erro?

var
   salb: real
   NOME: CARACTERE
Inicio
   Escreval("Sistema de gestão de pagamentos")
   Escreva ("Digite o nome do funcionário:")
   Leia(nome)
   Escreva("Digite o salário bruto do funcionário:R$")
   Leia (salb)
   se (salb<1000) então
      escreva ("O salário liquido é: ",salb - (salb*0.07))
      se (salb>=1000 e <=1500) então
         escreva ("O salário liquido é: ",salb - (salb*0.12))
         se (salb>1500) então
            escreva ("O salário liquido é: ",salb - (salb*0.15))
         fimse
      fimse
   fimse

 

Compartilhar este post


Link para o post
Compartilhar em outros sites
var
   salb: real
   NOME: CARACTERE
Inicio
   Escreval("Sistema de gestão de pagamentos")
   Escreva ("Digite o nome do funcionário:")
   Leia(nome)
   Escreva("Digite o salário bruto do funcionário:R$")
   Leia (salb)
   se (salb<1000) então
      escreva ("O salário liquido é: ",salb - (salb*0.07))
   fimse
   se (salb<=1500) então
      escreva ("O salário liquido é: ",salb - (salb*0.12))
   senao
      escreva ("O salário liquido é: ",salb - (salb*0.15))
   fimse

 

Tente assim e poste o resultado.
 

Compartilhar este post


Link para o post
Compartilhar em outros sites

Não use acentos nos comandos do VisualG, como a mensagem de erro informa.

 

Para postar o código use a tag code (ver orientação no alto da página).

Compartilhar este post


Link para o post
Compartilhar em outros sites

Olá.

 

Só para complementar...

 

Como são condições mutuamente excludentes, é necessário o uso dos senão. Seu código poderia ficar assim:

Algoritmo "semnome"
//ENUNCIADO
//Construa um algoritmo em Visualg, que calcule o salário líquido de um
//funcionário. O programa recebe o salário bruto do funcionário, caso este
//seja inferior a R$1.000,00 é descontado 7% em impostos, se o salário variar
//de R$ 1.000,00 até R$1.500,00 é descontado 12% em imposto, se for superior
//a R$1.500,00 é descontado 15%. Ao final o programa deve exibir o nome e o
//salário líquido do funcionário.
var
   nome :caractere
   salb :real
Inicio
   escreval("Sistema de gestão de pagamentos")
   escreva ("Digite o nome do funcionário: ")
   leia(nome)
   escreva("Digite o salário bruto do funcionário: R$")
   leia(salb)
   se (salb<1000) ENTÃO
      escreva ("O salário liquido é: ",salb-(salb*0.07))
   senao
      se (salb<=1500) ENTÃO
        escreva ("O salário liquido é: ",salb-(salb*0.12))
      senao
           escreva ("O salário liquido é: ",salb-(salb*0.15))
      fimse
   fimse
Fimalgoritmo

 

Como a "frase final" é praticamente igual, só mudando o resultado... poderia fazer assim:

var
   nome :caractere
   salb :real
   sall :real
...
   se (salb<1000) ENTÃO
      sall<-salb-(salb*0.07))
   senao
      se (salb<=1500) ENTÃO
        sall<-salb-(salb*0.12))
      senao
           sall<-salb-(salb*0.15))
      fimse
   fimse
   escreva ("O salário liquido é: ",sall)

 

Como a fórmula do salário líquido também é constante, só mudando o valor da taxa, poderia ficar assim:

var
   nome :caractere
   salb :real
   taxa :real
   sall :real
....
   se (salb<1000) ENTÃO
      taxa<-0.07
   senao
      se (salb<=1500) ENTÃO
        taxa<-0.12
      senao
           taxa<-0.15
      fimse
   fimse
   sall<-salb-(salb*taxa)
   escreva ("O salário liquido é: ",sall)

 

Para tentar ainda mais organizar, poderia deixar as taxas como constantes.

Algoritmo "semnome"
const
   TAXA1 = 0.07 //taxa para salários menores que 1000
   TAXA2 = 0.12 //taxa para salários entre 1000 e 1500 (inclusos)
   TAXA3 = 0.15 //taxa para salários maiores que 1500
var
   nome :caractere
   salb :real
   taxa :real
   sall :real
Inicio
   escreval("Sistema de gestão de pagamentos")
   escreva ("Digite o nome do funcionário: ")
   leia(nome)
   escreva("Digite o salário bruto do funcionário: R$")
   leia(salb)
   se (salb<1000) ENTÃO
      taxa<-TAXA1
   senao
      se (salb<=1500) ENTÃO
        taxa<-TAXA2
      senao
           taxa<-TAXA4
      fimse
   fimse
   sall<-salb-(salb*taxa)
   escreva ("O salário liquido é: ",sall)
Fimalgoritmo

 

 

adicionado 20 minutos depois

Ah! Sobre o erro que você teve.

 

19 horas atrás, Amilton Cândido disse:

Não está calculando com o valor 1.500. Quando são valores menores que 1.000, ele calcula, porém, dá esse erro.

Isso acontece porque você deixou os se dentro do outro... observe seu primeiro código lá em cima...

 

DICA:
O Visualg tem um recurso de auto-indentação. Basta pressionar Ctrl+G. Se fizesse isso, já veria que tem alguma coisa errada. Pois todos os se deveriam ficar na mesma linha.

 

PS:

O código do @Olinad212 também tem um errinho... experimente inserir valores menos que 1000.

 

19 horas atrás, Olinad212 disse:

   //estrutura se 1
   se (salb<1000) então
      escreva ("O salário liquido é: ",salb - (salb*0.07))
   fimse
   //estrutura se 2
   se (salb<=1500) então
      escreva ("O salário liquido é: ",salb - (salb*0.12))
   senao
      escreva ("O salário liquido é: ",salb - (salb*0.15))
   fimse

 

Vejam, o código está com duas estruturas de se separadas. A primeira verifica e independente do que aconteça, após vai verificar a segunda... ou seja, mesmo que a resposta desse sempre certa (como se só existissem salários maiores que 1000), mesmo assim a estrutura estaria com erro... A correção desse código do @Olinad212 seria esse meu primeiro desse tópico (uso do senão para deixar apenas uma estrutura). Ou também poderia ficar assim:

algoritmo "FCdG"
var
   salb: real
   NOME: CARACTERE
Inicio
   Escreval("Sistema de gestão de pagamentos")
   Escreva ("Digite o nome do funcionário:")
   Leia(nome)
   Escreva("Digite o salário bruto do funcionário:R$")
   Leia (salb)
   se (salb<1000) ENTÃO
      escreva ("O salário liquido é: ",salb - (salb*0.07))
   fimse
   se (salb>=1000) e (salb<=1500) ENTÃO
      escreva ("O salário liquido é: ",salb - (salb*0.12))
   fimse
   se (salb>1500) ENTÃO
      escreva ("O salário liquido é: ",salb - (salb*0.15))
   fimse
fimalgoritmo

Dessa forma, a mais simples possível, teríamos 3 estruturas... são 3 se diferentes, ou seja, mesmo que já tenha encontra a taxa correta, o programa ainda sim vai verificar se é uma outra.... o que não faz sentido... logo, entra a tal necessidade dos senão, como já citado lá em cima:

 

20 minutos atrás, Simon Viegas disse:

Como são condições mutuamente excludentes, é necessário o uso dos senão.

 

Compartilhar este post


Link para o post
Compartilhar em outros sites

Crie uma conta ou entre para comentar

Você precisar ser um membro para fazer um comentário

Criar uma conta

Crie uma nova conta em nossa comunidade. É fácil!

Crie uma nova conta

Entrar

Já tem uma conta? Faça o login.

Entrar agora





Sobre o Clube do Hardware

No ar desde 1996, o Clube do Hardware é uma das maiores, mais antigas e mais respeitadas publicações sobre tecnologia do Brasil. Leia mais

Direitos autorais

Não permitimos a cópia ou reprodução do conteúdo do nosso site, fórum, newsletters e redes sociais, mesmo citando-se a fonte. Leia mais

×