Ir ao conteúdo
  • Cadastre-se
Marcelo Saldanha

VisualG Algoritmos, mostrar quantidade de divisores

Recommended Posts

Boa Tarde pessoal

se possível alguém me dar uma ajuda

eu tenho que criar um algoritmo que de o quadrado de um numero depois o cudo , os divisores e o primo

pois não consegui fazer com que diga a quantidade de divisores só consegui mostrar os divisores como posso fazer pra mostrar somente a quantidade?

Algoritmo "Atividade 3"

Var
   rep, qd, cb, resto, i, aux  : inteiro
   cabecalho : caractere

Inicio
   cabecalho <- "Numero Quadrado Cubo Divisores Primos"
   escreval (cabecalho)
   para rep de 01 ate 20 faca
      escreva(rep, "")
      qd <- rep * rep
      escreva (qd, "")
      cb <- (rep * rep) * rep
      escreva (cb, "")
      para resto de 1 ate rep faca
         se (rep mod resto = 0) então
            escreva(resto)
         fimse
      fimpara
      aux <- 0
      para i de 2 ate rep -1 faca
         se rep mod i = 0 então
            aux <- aux +1
         fimse
      fimpara
      se aux = 0 então
         escreva ("sim")
      senao aux =
         escreva ("nao")
      fimse
      escreval("")

   fimpara

Fimalgoritmo

 

  • Obrigado 1

Compartilhar este post


Link para o post
Compartilhar em outros sites

Por que de 1 a 20? Não vai pedir pra digitar nenhum número?

O ideal é fazer uma função pra cada objetivo.

  • Obrigado 1

Compartilhar este post


Link para o post
Compartilhar em outros sites

Olá.

 

@Marcelo Saldanha, na sua pergunta já tem a resposta.

 

23 horas atrás, Marcelo Saldanha disse:

não consegui fazer com que diga a quantidade de divisores só consegui mostrar os divisores como posso fazer pra mostrar somente a quantidade?

Não é para mostrar os divisores, mas sim a quantidade de divisores, logo em vez de mostrar ao encontrar um divisor, vá "contando".. Após mostra a quantidade.

 

Abaixo segue um com essa alteração, mais um conjunto de outras sugestões. Sugiro que tente ajustar o seu próprio código antes... mas caso deseje, dê uma analisada no código e vá comparando abaixo. Tente entender cada mudança. Caso tenhas dúvidas, é só perguntar.

 

Ai, a depender vai implementando uma coisa ou outra no seu.

Algoritmo "Atividade 3"
Var
   cabecalho   :caractere
   numero      :inteiro //numero sendo verificado (de 1 a 20)
   quadrado    :inteiro //quandro do número
   cubo        :inteiro //cubo do número
   qtdDivisores:inteiro //quantidade de divisores do número
   divisor     :inteiro //auxiliar para verificar a quantidade de divisores
   
Inicio
cabecalho <- "Numero Quadrado Cubo Divisores Primos"
escreval(cabecalho)
para numero de 1 ate 20 faca
   //o número em si
   escreva(numero:4)
   //quadrado do número
   quadrado <- numero * numero
   escreva (quadrado:8)
   //cubo do número
   cubo <- quadrado * numero
   escreva (cubo:8)
   //quantidade de restos
   qtdDivisores <- 0
   para divisor de 1 ate numero faca
      se (numero mod divisor = 0) ENTÃO
         {escreva(divisor:8)} //não é para escrever
         qtdDivisores <- qtdDivisores + 1
      fimse
   fimpara
   escreva (qtdDivisores:6)
   //primo
   se qtdDivisores = 2 ENTÃO
      escreva ("":7,"Sim")
   senao
      escreva ("":7,"Nao")
   fimse
   escreval("")
fimpara
fimalgoritmo

 

  • Curtir 2

Compartilhar este post


Link para o post
Compartilhar em outros sites

Crie uma conta ou entre para comentar

Você precisar ser um membro para fazer um comentário

Criar uma conta

Crie uma nova conta em nossa comunidade. É fácil!

Crie uma nova conta

Entrar

Já tem uma conta? Faça o login.

Entrar agora





Sobre o Clube do Hardware

No ar desde 1996, o Clube do Hardware é uma das maiores, mais antigas e mais respeitadas publicações sobre tecnologia do Brasil. Leia mais

Direitos autorais

Não permitimos a cópia ou reprodução do conteúdo do nosso site, fórum, newsletters e redes sociais, mesmo citando-se a fonte. Leia mais

×