Visual Basic Visualg - estudando logística de programação

[bruningomes17]

Bom dia!

 

Estou começando a estudar logica de programação, e quando tento escrever um algorítimo usando as funções "se" e "caso", estou encontrando algumas dificuldades, no exercício em questlao seria um calculo de média de KILL de um jogo, o calculo funciona normalmente, mas por algum motivo eu não consigo fazer o algorítimo realizar uma "escolha caso" o valor de negativo, segue abaixo o código, espero que alguém possa me ajudar a identificar o erro. 

 

var
   MT, MO, M: Real
inicio
      Escreval ("==================")
      Escreval ("       KILL       ")
      Escreval ("==================")
      Escreva ("Quantos personagens você matol? ")
      Leia (MT)
      Escreva ("Quantas vezes te mataram? ")
      Leia (MO)
      M <- MT-MO
      Escreval (" sua media de KILL é ", M)
      Escreval ("==================")
      Se (M>=1) e (M<=10) então
      Escolha (M)
              Caso 1, 2, 3, 4, 5
              Escreval ("Você esta indo bem!")
              Caso 6, 7, 8, 9, 10
              Escreval ("Você esta otimo!")
      Senao
           Se (M>10) então
           Escreval ("Você esta joganndo muito bem")
           Senao
                Se (M<=0) e (M<=-10) então
                Escolha (M)
                        Caso -1, -2, -3, -4, -5
                        Escreval ("Sua média esta negativa, isso não e bom.")
                        Caso -6, -7, -8, -9, -10
                        Escreval ("voce esta indo muito mau")
                Senao
                     Se (M<=-10) então
                     Escreval ("Você devia tentar jogar outro jogo.")
                     Fimse
                        Fimescolha
                Fimse
           Fimse
              Fimescolha
      Fimse
      Escreval ("==================")
fimalgoritmo

[devair1010]

@bruningomes17    seu código está bom , mas você misturou o comando escolha com se e senao ,  e ele não está entrando nos casos negativos por que você colocou 

 se m <= -10

  e  seria 

 m >= - 10

,  então seu código com algumas modificações ficaria assim  :

Algoritmo "kill"
var
   MT, MO, M: Real
inicio
  Escreval("==================")
  Escreval("       KILL       ")
  Escreval("==================")
  Escreva("Quantos personagens você matol? ")
  Leia( MT )
  Escreva("Quantas vezes te mataram? ")
  Leia( MO )
  M <- MT-MO
  Escreval(" sua media de KILL é ", M)
  Escreval("==================")
  Se ( M >= 1 ) e ( M <= 10) ENTÃO
    Escolha( M )
    Caso 1, 2, 3, 4, 5
      Escreval ("Você esta indo bem!")
    Caso 6, 7, 8, 9, 10
      Escreval ("Você esta otimo!")
    Fimescolha
  Senao
    Se ( M > 10 ) ENTÃO
      Escreval("Você esta joganndo muito bem")
    Senao
      Se ( M <= 0) e ( M >= - 10 ) ENTÃO //erro nessa linha
        Escolha( M )
        Caso -1, -2, -3, -4, -5
          Escreval("Sua média esta negativa, isso não e bom.")
        Caso -6, -7, -8, -9, -10
          Escreval("voce esta indo muito mau")
        Fimescolha
      Senao
        Se ( M <= - 10 ) ENTÃO
          Escreval("Você devia tentar jogar outro jogo.")
        Fimse
        //Fimescolha  no lugar errado
      Fimse
    Fimse
    //Fimescolha no lugar errado
  Fimse
  Escreval ("==================")
fimalgoritmo