Outro Ativação e Desativação automática de interfaces de rede

[Jason GBDS]

Boa Tarde, eu novamente rsrs...

Venho o um problema que pretendo resolver com o batch, porém não sei como pegar um valor para realizar uma condição.

O problema é que, possuo duas interfaces de rede, e precisava de um bat que quando executado, ele verifica se interface 1 esta ativa, se tiver ativa, ele desativa a mesma e após esse procedimento ele ativa a segunda  interface. Ou seja cada vez que o bat executado ele altera  o estado administrativo de cada interface.

 

Minha Ideia..

@echo off

if "Exemplo** Ethernet esta ativa" (goto:externo)
if "Exemplo** Ethernet esta desativado" (goto:interno)

:externo
netsh interface set interface name="Ethernet" admin=enable
netsh interface set interface name="Wi-Fi" admin=disabled
@echo  Ativando..
exit

:interno
netsh interface set interface name="Ethernet" admin=disabled
netsh interface set interface name="Wi-Fi" admin=enable
@echo Ativando..
exit

 

[ricardo_br]

Você quer o bat altere entre rede cabeada "Ethernet" e sem fio "Wi-Fi" sempre que é executado correto?

 

@echo off
chcp 1252 1> Nul
net session 1> Nul 2> Nul
If /i "%Errorlevel%"=="2" (
echo.
echo Atenção, o script precisa ser executado como administrador!
echo.
pause
Exit
)

echo.
for /f "skip=3 tokens=1,3,*" %%a in ('netsh interface show interface') do (
if /i "%%c"=="Ethernet" IF /i "%%a"=="Habilitado" goto :interno
if /i "%%c"=="Wi-Fi" if /i "%%a"=="Habilitado" goto :externo
)

:externo
netsh int set int "Ethernet" Enabled
netsh int set int "Wi-Fi" Disabled
@echo A interface "Ethernet" está ativa
echo.
pause
exit

:interno
netsh int set int "Wi-Fi" Enabled
netsh int set int "Ethernet" Disabled
@echo A interface "Wi-Fi" está ativa
echo.
pause
exit

 

[Jason GBDS]

@ricardo_br Isso mesmo que eu queria, Obrigado!

Gostaria de saber de onde você tira essas sintaxe? rsrs Se não for perguntar muito.

[ricardo_br]

@Jason GBDS Basicmente o comando for verifica o status de cada interface e dependendo do resultado ele executa a função "interno" ou "externo" ou você tá falando do encurtamento do comando "netsh int set int "Ethernet" Disabled", acho que descobri por acaso um dia desses....