VisualG Visualg não reconhece palavra reservada

[Aleksandro Pereira Freires]

Olá, estou cursando Análise e Desenvolvimento de Sistemas, estou indo para o segundo semestre, embora a classe esteja indo para o terceiro. Por esse motivo, estou me atualizando em lógica básica. Eu estou tentando criar um prótotipo de formulário.Quando executo o programa, o Visualg não reconhece o ENTAO na linha 32 ( " se (x =/= 1) entao ").  Esse é o programa: 

( Sei que poderia deixar esse programa mais prático utilizando repetições e até o SENAO, porém estou indo aos poucos, para aprender cada comando e suas utilizações corretas)

 

 

 

Algoritmo "semnome"


Var

    nome : caractere
    idade: inteiro
    cpf: inteiro
    x : inteiro

Inicio

      escreval("Digite seu nome completo: ")
      leia(nome)

      escreval("Digite a sua idade: ")
      leia(idade)

      escreval("Digite o número do seu CPF: ")
      leia(cpf)
      
      escreval("Confirmação dos Dados Informados: ")

      escreval("")

      escreval("O seu nome é " ,nome, " ,? Se sim, digite 1:")
      
      leia(x)
      se (x =/= 1) entao
      escreval("Digite novamente seu nome: ")
      leia(nome)
       escreva("O seu nome  " ,nome, " ? Se sim, digite 1:")
       leia(x)
       se (x = 1) entao


       escreval("Sua idade é ",idade, " ? Se sim, digite 1:")
       leia(x)
      se (x =/= 1) entao
      escreval ("Digite novamente sua idade: ")
      leia(idade)
      escreval("Sua idade é ",idade," anos ? Se sim, digite 1: ")
      leia(x)
      se (x = 1) entao

      
      escreval("O seu CPF é " , cpf , " ? Se sim, digite 1: ")
      leia(x)
      se (x =/= 1) entao
      escreval("Digite novamente seu CPF: ")
      leia(cpf)
      escreval("Seu CPF é: " , cpf , " ? Se sim, digite 1: ")
      se (x = 1)entao

      
      escreval ("Nome: ", nome)
      escreval ("Idade: ", idade, " anos" )
      escreval ("CPF: ", cpf)
      
      escreva ("Dados inseridos !")

Fimalgoritmo

 

 

[Simon Viegas]

21 horas atrás, Aleksandro Pereira Freires disse:

Eu estou tentando criar um protótipo de formulário. Quando executo o programa, o Visualg não reconhece o ENTAO na linha 32 ( " se (x =/= 1) entao ")

 

O VisualG não é muito bom para tratar erros. Ele as vezes atrapalha mais do que ajuda! rs

O que está errado nessa linha é o operador lógico... Esse "=/=" não existe no VisualG! Caso tenha dúvidas em qual seria o comando, poderia consultar no Google... por exemplo por "diferente em VisualG". . O comando correto seria "<>". Basta substitui-los.

 

Além disso, ficou faltando os fimSe para cada um dos se. Nesse caso, seria necessário entender o que você estaria tentando fazer, pois as posições onde vão colocar os fimSe, vão influenciar no resultado da lógica... em fim... Ex.:

 

Algoritmo "semnome"
Var
   nome : caractere
   idade: inteiro
   cpf: inteiro
   x : inteiro
Inicio
   escreval("Digite seu nome completo: ")
   leia(nome)
   escreval("Digite a sua idade: ")
   leia(idade)
   escreval("Digite o número do seu CPF: ")
   leia(cpf)
   escreval("Confirmação dos Dados Informados: ")
   escreval("")
   escreval("O seu nome é " ,nome, " ,? Se sim, digite 1:")
   leia(x)
   se (x <> 1) entao
      escreval("Digite novamente seu nome: ")
      leia(nome)
      escreva("O seu nome  " ,nome, " ? Se sim, digite 1:")
      leia(x)
      se (x = 1) entao
         escreval("Sua idade é ",idade, " ? Se sim, digite 1:")
         leia(x)
         se (x <> 1) entao
            escreval ("Digite novamente sua idade: ")
            leia(idade)
            escreval("Sua idade é ",idade," anos ? Se sim, digite 1: ")
            leia(x)
            se (x = 1) entao
               escreval("O seu CPF é " , cpf , " ? Se sim, digite 1: ")
               leia(x)
               se (x <> 1) entao
                  escreval("Digite novamente seu CPF: ")
                  leia(cpf)
                  escreval("Seu CPF é: " , cpf , " ? Se sim, digite 1: ")
                  se (x = 1)entao
                     escreval ("Nome: ", nome)
                     escreval ("Idade: ", idade, " anos" )
                     escreval ("CPF: ", cpf)
                     escreva ("Dados inseridos !")
                  fimse
               fimse
            fimse
         fimse
      fimse
   fimse
Fimalgoritmo

 

Veja...inicialmente você se esbarrou num problema de sintaxe (está tentando usar um comando que não existe no VisualG e esqueceu de colocar os fimSe), mas aí também vai entrar num problema de lógica, ou seja: está tentando implementar algo que talvez não faça muito sentido prático. Entende? para o teu programa funcionar, o usuário sempre teria que responder uma vez que o dado está incorreto (responder algo diferente de 1), e após digitar novamente e responder que "1"... Qualquer uso fora dessa ordem, o programa não vai funcionar direito.

 

Sugiro procurar listas de exercícios na internet, geralmente vão seguir uma sequência de "mais fácil para os mais complexos". Ex.:

Comandos de Decisão Simples e Encadeados

 

 

Exemplo de resposta de um exercício:

3. Crie um algoritmo que leia dois valores (x e y) e informe qual o menor valor

algoritmo "semnome"
//Crie um algoritmo que leia dois valores (x e y) e informe qual o menor valor
var
   x, y : inteiro
Inicio
   escreval("Informe o valor de X")
   leia(x)
   escreval("Informa o valor de Y")
   leia(y)
   se (x < y) entao
      escreval("X é menor que Y")
   fimSe
   se (y < x) entao
      escreval("Y é menor que X")
   fimSe
fimAlgoritmo

 

Sugiro tentar fazer todos os exercício de "COMANDOS DE DECISÃO SIMPLES" e postar as respostas aqui. Caso tenha dúvidas sobre algum, é só postar.