Outro Script FTP Download e Organização

[Brunim3105]

@echo off
Title Baixar Arquivos do FTP


Rem PDL = Pasta de Download Local
Rem PDR = Pasta de Download Remoto
Rem PDRI = Pasta de Download Remota Intermediaria

Rem Especifique aqui a pasta de download local:
set PDL=E:\meli

Rem Especifique aqui a pasta de download remota:
set PDR=/meli

Rem Especifique aqui a pasta de download remota intermediaria
set PDRI=/meli/enviar

Rem Especifique aqui o seu servidor FTP
set FTPServer=

Rem Especifique seu nome de usuario:
set Usuario=

Rem Especifique sua senha:
set Senha=

echo %Usuario%> %temp%\conectar.txt
echo %Senha%>> %temp%\conectar.txt
echo cd %PDR%>> %temp%\conectar.txt
echo ls * "%temp%\lista.txt">> "%temp%\conectar.txt"
echo bye>> %temp%\conectar.txt

ftp -i -s:%temp%\conectar.txt %FTPServer%

echo %Usuario%> %temp%\conectar.txt
echo %Senha%>> %temp%\conectar.txt

for /f "usebackq Delims=" %%a in ("%temp%\lista.txt") do Echo rename "%PDR%/%%a" "%PDRI%/%%a">> %temp%\conectar.txt

echo cd %PDRI%>> %temp%\conectar.txt
echo lcd %PDL%>> %temp%\conectar.txt
echo mget *>> %temp%\conectar.txt
echo bye>> %temp%\conectar.txt

ftp -i -s:%temp%\conectar.txt %FTPServer%

echo %Usuario%> %temp%\conectar.txt
echo %Senha%>> %temp%\conectar.txt
for /f "usebackq Delims=" %%b in ("%temp%\lista.txt") do if exist "%PDL%\%%b" echo Delete "%PDRI%/%%b">> %temp%\conectar.txt
echo bye>> %temp%\conectar.txt

ftp -i -s:%temp%\conectar.txt %FTPServer%

Set Dia=%Date:~0,2%
set Mes=%Date:~3,2%
set Ano=%Date:~6,4%
set Pasta=%Ano%\%Mes%\%Dia%

if not exist "C:\meli\%Pasta%" md "C:\meli\%Pasta%"
robocopy "C:\meli" "C:\meli\%Pasta%" /xx /mov /maxage:%Ano%%Mes%%Dia%

Bom dia,

 

Eu tenho um script .bat de download e organização de uns arquivos do meu servidor FTP ele acessa o FTP move todos os arquivos para uma pasta e baixa todos dessa pasta verifica se todos foram baixados e depois apaga do servidor FTP, e no meu computador ele organiza por Ano, Mes e dia, porém no meu computador o script funciona normalmente porém no meu servidor Windows server 2012, ele não consegue dar LS dentro do servidor FTP, ele entra no FTP acessar as pasta mas no momento que o script da LS ele para, vou anexar uma imagem do local onde ele para, e queria saber o porque que ele para ali.

 

Quem fez o Script para mim foi o @ricardo_br

[ricardo_br]

Já verificou no roteador por onde o servidor conecta se te tem algum bloqueio. Também pode tentar comlocar seu servidor como DMZ (Desmilitarized Zone) ou fazer redirecionamento de porta para as portas 20 e 21...