Visual Basic abrir nova sheet atraves da informação da primeira

[monalisamesquita]

Ola, gostaria de uma ajuda.

Tenho uma planilha com varias informações cujo o filtro tem que ocorrer pelo municipio, gostaria que a partir da sheet principal abrisse outras sheets para cada municipio. 

tem como ?

[Basole]

@monalisamesquita tem sim. Mas por favor crie um exemplo da sua planilha com alguns dados ficticios

 detalhando melhor a sua demanda 

 

[monalisamesquita]

@Basole ola!

Coloquei de exemplo uma planilha em anexo: 

Nela tem a sheet BASE, que contem informações que quero que sejam puxadas para as proximas sheet por municipio. 

coloquei um exemplo nela, fiiz na mao. 

diego.xlsx

[Basole]

@monalisamesquita veja se e realmente que eu entendi, que voce deseja:

  O codigo abaixo divide os dados nas respectivas abas de acordo com a coluna N

  E caso nao exista a aba, cria e nomeia

  E na coluna O cria um link para visualizar a respectiva aba           

          * Para inserir o codigo em um modulo siga os passos veja o link abaixo: 

                       Inserir código VBA na pasta de trabalho do Excel       

Sub PuxarParaAsProximasSheets()
Dim irs   As Integer, irt   As Integer, wsb As Worksheet
Dim strTab   As String, sh   As Worksheet, ShNoEx   As Boolean

irs = 2
Set wsb = Sheets("Base")
Do Until VBA.IsEmpty(wsb.Cells(irs, 1))
   
   strTab = VBA.Trim(wsb.Cells(irs, "N").Value2)
 
   ShNoEx = False
   
   For Each sh In ThisWorkbook.Worksheets
    If VBA.UCase(sh.Name) = VBA.UCase(strTab) Then
       ShNoEx = True
    End If
    Next sh
    
     If Not ShNoEx Then
            With ThisWorkbook 'Cria Nova Aba Caso nao Exista
                .Sheets.Add(After:=.Sheets(.Sheets.Count)).Name = strTab
            End With
                wsb.Rows(1).Copy Sheets(strTab).Rows(1)
                irt = Sheets(strTab).Cells(Rows.Count, 1).End(xlUp).Offset(1).Row
                wsb.Rows(irs).Copy Sheets(strTab).Rows(irt)
     Else
            irt = Sheets(strTab).Cells(Rows.Count, 1).End(xlUp).Offset(1).Row
            wsb.Rows(irs).Copy Sheets(strTab).Rows(irt)
     End If
   
   With wsb
     .Activate
     .Cells(irs, "O").Activate
  End With
      ActiveCell.Hyperlinks.Add Anchor:=Selection, Address:="", _
             SubAddress:="'" & Sheets(strTab).Name & "'!A1", TextToDisplay:="CLICK AQUI"
   
  irs = irs + 1
Loop

End Sub