VisualG Junção de duas matriz em uma outra

Soul1Gamer · 14 de junho de 2020

ler duas matrizes do tipo vetor, sendo a com 20 elementos e b com 30 elementos. construir uma
matriz c, sendo esta a junção das duas outras matrizes. desta forma, c deverá ter a capacidade de
armazenar 50 elementos. apresentar a matriz c.

meu algoritmo está com algum problema e não consigo resolver fiquei dias tentando e nada e ainda tenho mais para resolver.

algoritmo "semnome"
// função :
// autor :
// data : 14/06/2020
// seção de declarações
var
a : vetor [1..5] de inteiro
b : vetor [1..5] de inteiro
c : vetor [1..10] de inteiro
i : inteiro
inicio
para i <-1 ate 5 faca
escreva ("digite o ",i,"o. valor:")
leia (a)
c <- (a)
fimpara
para i <-1 ate 5 faca
escreva ("digite o ",i,"o. valor:")
leia (b)
c <- (b)
fimpara
para i de 1 ate 10 faca
escreval ("digite o ",i,"o. valor:",c)
fimpara
fimalgoritmo

Simon Viegas · 14 de junho de 2020

@Soul1Gamer, o teu código saiu incompleto. Para postar um código no Fórum, clique antes no botão <>. Fica na barra de ferramentas:

Outro ponto: por quê iniciar os novos períodos com letras minúsculas? Deu defeito no shift?

3 horas atrás, Soul1Gamer disse:

meu algoritmo está com algum problema e não consigo resolver fiquei dias tentando e nada e ainda tenho mais para resolver.

Que problema? Seria mais interessante se relatasse o que está acontecendo...

Mas vamos lá:

3 horas atrás, Soul1Gamer disse:

ler duas matrizes do tipo vetor, sendo a com 20 elementos e b com 30 elementos. construir uma
matriz c, sendo esta a junção das duas outras matrizes. desta forma, c deverá ter a capacidade de
armazenar 50 elementos. apresentar a matriz c.

Primeiro apenas leia o vetor a. Depois apenas leia o vetor b. Após, insira todas os elementos de a no vetor c e após também insira os elementos de b em c.

Se ocorrer algum problema, entenda o quê está ocorrendo... tente corrigir... daí, caso tenha dúvidas, nos relate qual problema está ocorrendo e onde está com dúvidas.

devair1010 · 15 de junho de 2020

@Soul1Gamer parece que você esqueceu de colocar em qual posição do vetor vai armazenar o dado , nessa parte

para i <-1 ate 20 faca
  escreva ("digite o ",i,"º valor : ")
  leia(a[i])
fimpara

e depois de inserir os números nos vetores use um laço de repetição indo de 1 até 50 para preencher vetor c .

Soul1Gamer · 15 de junho de 2020

@devair1010 entao, eu estou fazendo de uma forma diferente, como: eu coloco pra ler e armazenar no vetor "a" de 1 a 20 porém fica procurando valor em vetor[0] sendo que disse que era de 1 a 20.

fica difícil nao sei o que fazer...

adicionado 9 minutos depois

algoritmo "semnome"
var
A: VETOR [1..20] DE INTEIRO
B: VETOR [1..30] DE INTEIRO
C: VETOR [1..50] DE INTEIRO
I: INTEIRO
inicio
PARA I DE 1 ATE 20 FACA
ESCREVA ("DIGITE O",I,"o. VALOR: ")
LEIA (A[I])
C[I] <- A[I]
FIMPARA
PARA I DE 1 ATE 30 FACA
ESCREVAL ("DIGITE O",I,"o. VALOR: ")
LEIA (B[I])
C[I] <-B[I]
FIMPARA
PARA I DE 1 ATE 50 FACA
ESCREVAL ("OS NUMEROS LIDOS SÃO ",C[I])
FIMPARA

fimalgoritmo

devair1010 · 15 de junho de 2020

@soul1gamer o primeiro laço de repetição está certo mas no segundo você precisa colocar vinte posições a mais no vetor c , assim

para i de 1 ate 30 faca
  escreval ("digite o",i,"o. valor: ")
  leia (b[i])
  c[i+20] <-b[i]
fimpara

escreval ("os numeros lidos são ")
para i de 1 ate 50 faca
  escreval (c[i]:3)
fimpara

Soul1Gamer · 15 de junho de 2020

@devair1010, olha ae! mesmo assim está dando problema...

algoritmo "semnome"
var
   a: vetor [1..20] de inteiro
   b: vetor [1..30] de inteiro
   c: vetor [1..50] de inteiro
   i: inteiro
inicio
   para i de 1 ate 20 faca
      escreva ("digite o",i,"o. valor: ")
      leia (a[i])
      c[i] <-b[i+20]
   fimpara
   para i de 1 ate 30 faca
      escreval ("digite o",i,"o. valor: ")
      leia (b[i])
      c[i] <-b[i]
   fimpara
   escreval ("os numeros lidos são ")
   para i de 1 ate 50 faca
      escreval ("o",i," valor eh ",(c[i]:3)
   fimpara

fimalgoritmo

devair1010 · 15 de junho de 2020

@Soul1Gamer para postar seu código é melhor usar o botão <> que está desenhado lá na barra de ferramentas da janela de postar

pois senão seu código fica faltando alguns caracteres como os { i } , que sumiram do seu código , e você precisa colocar vinte posições a mais é no segundo loop assim

algoritmo "vetores2"
var
  a: vetor [1..20] de inteiro
  b: vetor [1..30] de inteiro
  c: vetor [1..50] de inteiro
  i: inteiro
inicio
  para i de 1 ate 2 faca
    escreva("digite o",i,"º valor: ")
    leia (a[i])
    c[i] <-a[i]
  fimpara
  para i de 1 ate 3 faca
    escreva("digite o",i,"º valor: ")
    leia (b[i])
    c[i+20] <-b[i]
  fimpara
  escreval
  escreval("    o vetor c")
  para i de 1 ate 50 faca
    escreval("o",i:3,"º valor eh ",c[i]:3)
  fimpara
fimalgoritmo

Soul1Gamer · 15 de junho de 2020

@devair1010

agora no final pede "]" mas não encontro onde colocar

algoritmo "semnome"
var
a: vetor [1..20] de inteiro
b: vetor [1..30] de inteiro
c: vetor [1..50] de inteiro
i: inteiro
inicio
para i de 1 ate 20 faca
escreva ("digite o",i,"o. valor: ")
leia (a[i])
c[i] <-a[i]
fimpara
limpatela
para i de 1 ate 30 faca
escreva ("digite o",i,"o. valor: ")
leia (b[i])
c[i+20] <-b[i]
fimpara
escreval("    o vetor c")
para i de 1 ate 50 faca
escreval ("o",i:3," valor eh ",(c[i]:3))
fimpara

fimalgoritmo

devair1010 · 15 de junho de 2020

@Soul1Gamer você testou o que eu postei ? pois o seu está modificado e para que esses parênteses lá na linha no final ? pode ser isso que esteja com erro .

e precisa identar o código para facilitar na hora da leitura e descobrir erros , pois assim organiza as ações do código por tipo de estrutura dele , e pode se ver o que está dentro ou fora de loop por exemplo .

Soul1Gamer · 15 de junho de 2020

@devair1010, puts mano!!! O seu funcionou legal!!! Muito obrigado pela orientação e ajuda!! Eu não entendi foi esses negócios de "i:3", talvez por isso que eu não estava obtendo sucesso no código. Mas mesmo assim agradeço muito!

algoritmo "vetores2"
var
  a: vetor [1..20] de inteiro
  b: vetor [1..30] de inteiro
  c: vetor [1..50] de inteiro
  i: inteiro
inicio
  para i de 1 ate 20 faca
    escreva("digite o",i,"o. valor: ")
    leia (a[i])
    c[i] <-a[i]
  fimpara
  para i de 1 ate 30 faca
    escreva("digite o",i,"o. valor: ")
    leia (b[i])
    c[i+20] <-b[i]
  fimpara
  escreval
  escreval("    o vetor c")
  para i de 1 ate 50 faca
    escreval("o",i:3," valor eh ",c[i]:3)
  fimpara
fimalgoritmo

Simon Viegas · 15 de junho de 2020

Em 15/06/2020 às 01:01, Soul1Gamer disse:

Eu não entendi foi esses negócios de "i:3", talvez por isso que eu não estava obtendo sucesso no código.

Não. Não tem qualquer relação com o algoritmo. Trata-se apenas de uma formatação de texto, ou seja: está voltado para questão estética.

Seria algo assim:

<variável>:x - Esse "x" representando um inteiro que corresponde ao "mínimo de casas que a variável vai ocupar". Nesse "i:3", quando a variável tem menos de 3 caracteres, o VisualG vai inserir espaços a esquerda para completar. Ex.: 7 vira "--7" e "-72" vira "-72" (onde tem "-" entenda como sendo espaços em branco"). Esse recurso é usando para alinhar as colunas...

Veja uma diferença:

Sem formatação:

Com formatação:

Perceba como todos os texto ficam com o mesmo comprimento. Para entender melhor, faça testes mudando os valores. Ex.: i:10, i:5..

Segue um exemplo de código:

algoritmo "vetores2"
var
   a: vetor [1..20] de inteiro
   b: vetor [1..30] de inteiro
   c: vetor [1..50] de inteiro
   i: inteiro
inicio
   escreval("Vetor A: ")
   ALEATORIO 1,100
   para i de 1 ate 20 faca
      escreva ("Digite o ", i:2, "º valor: ")
      leia(a[i])
      c[i] <- a[i]
   fimPara
   ALEATORIO off
   
   escreval("")
   escreval("Vetor B: ")
   ALEATORIO 1,100
   para i de 1 ate 30 faca
      escreva ("Digite o ", i:2, "º valor: ")
      leia(b[i])
      c[i+20] <- b[i]
   fimPara
   ALEATORIO off

   escreval("")
   escreval("Vetor C: ")
   para i de 1 ate 50 faca
      escreval("O ", i:2, "º valor é ", c[i]:2)
   fimPara
fimAlgoritmo

Nesse código acima bastou "reservar" 2 espaços, pois um espaço já tem após o "0". Daí, se o número tiver apenas uma casa, vai inserir um espaço a esquerda. Se tiver 2, não muda nada.