Excel cabeçalho padrão em lote

[djacy.neto]

pessoal,

tenho uma pasta com cerca de 500 planilhas todas no mesmo formato e no mesmo layout. e eu preciso por o mesmo cabeçalho.

eu consigo fazer uma macro para isso?

[Eder Neumann]

receio que não, mas vou acompanhar para o caso de alguém ter ima ideia...

[Midori]

Com macro é possível abrir todas essas planilhas e editar.

 

O cabeçalho seria um texto padrão na primeira linha?

[djacy.neto]

@Midori isso!

acho que eu nao soube explicar,

a macro abre os arquivos ai inclui uma linha para cabeçalho (fixo)

depois salva e fecha

 

[Midori]

@djacy.neto  Veja se assim resolve,

 

Coloque alguns arquivos em C:\Teste para testar se é isso mesmo, deixe apenas arquivos do Excel.

 

A macro vai abrir todos os arquivos, definir a primeira linha como cabeçalho fixo, salvar e fechar.

 

Sub Macro()
    Dim Diretorio   As String
    Dim Arquivo     As String
    Dim Pasta       As Workbook
    
    Diretorio = "C:\Teste\"
    
    Arquivo = Dir(Diretorio & "*")
    
    While Arquivo <> ""
        Set Pasta = Workbooks.Open(Diretorio & Arquivo)
            Pasta.ActiveSheet.PageSetup.PrintTitleRows = "1:1"
            Pasta.Save
            Pasta.Close
        Arquivo = Dir
    Wend
End Sub

 

[djacy.neto]

@Midori  desculpa demora, precisava de tempo p testar, nesse seu script ele define cabeçalho fixo certo?

meu problema é que o cabeçalho nao existe na planilha.  ta ai exemplo1 como vem a planilha

e exemplo2 como ela deve ficar.

 

 

[Midori]

@djacy.neto  Veja se assim resolve,

 

Sub Macro()
    Dim Diretorio   As String
    Dim Arquivo     As String
    Dim Pasta       As Workbook
    
    Diretorio = "C:\Teste\"
    Arquivo = Dir(Diretorio & "*")
    
    While Arquivo <> ""
        Set Pasta = Workbooks.Open(Diretorio & Arquivo)
            With Pasta.ActiveSheet
                .[1:1].Insert Shift:=xlDown
                .[A1:M1] = Array("ORGAO", "MAT", "UPG", "UF", _
                    "NOME", "CPF", "COD", "SEQ", "VALOR", "PRAZO", _
                    "TIPO", "STATUS", "CONTRATO")
                .PageSetup.PrintTitleRows = "1:1"
            End With
            Pasta.Save
            Pasta.Close
        Arquivo = Dir
    Wend
End Sub

 

[djacy.neto]

@Midori  com arquivos em xlsx deu super certo!

uma pergunta, se o arquivo aberto estiver no formato csv eu preciso declarar?

eu tentei fazer com csv e ele deixa todo conteudo na 1 coluna e insere o cabeçalho. fica algo assim:

ele traz todo cabeçalho na celula a1

 

 

[Midori]

@djacy.neto Tente rodar com esta condição,

 

With Pasta.ActiveSheet
    If Right(Arquivo, 3) = "csv" Then
        .[A:A].TextToColumns DataType:=xlDelimited
    Else
        .[1:1].Insert Shift:=xlDown
        .[A1:M1] = Array("ORGAO", "MAT", "UPG", "UF", _
            "NOME", "CPF", "COD", "SEQ", "VALOR", "PRAZO", _
            "TIPO", "STATUS", "CONTRATO")
    End If
    .PageSetup.PrintTitleRows = "1:1"
End With

 

Assim a macro vai tabular os campos dos arquivos csv.

 

Se no csv não tiver o nome dos campos, coloque a linha do insert fora do If-Else e atribua os nomes como fiz para os outros casos (.[A1:M1] = Array("ORGAO", "MAT"...)