Função SE + =hoje()

[menjol]

Senhores, bom dia

Estou tentando fazer uma fórmula em que possa incluir a fórmula HOJE dentro da fórmula SE.

Trata-se de uma planilha de cobrança, preciso de uma coluna onde possa informar SE determinada coluna com várias datas for maior que HOJE (=hoje()) me retorne a informação "a vencer". Ao contrário SE na coluna dos vencimentos eu tiver uma data menor que HOJE me retorne a informação "vencida".

Estou com um problema de sintaxe nessa fórmula e não consigo fazê-la. Alguém pode me explicar?

Menjol

[iwwgia]

Tente assim:

=SE(HOJE()>C4;"vencido";"a vencer")

aonde C4 é a célula aonde se encontra a data de vencimento.

[menjol]

Era isso, muitíssimo obrigado.

[thelesf]

Eu estou tentando utilizar essa função Hoje() também, só que eu gostaria que eu puxasse a data do computador e verificasse se no dia seguinte é ou não sábado,,, se for sábado, o sistema puxasse a data de segunda-feira, e se não fosse sábado, ele informasse a data de hoje mesmo.

Obrigado!

Thelis

[XFlaPc]

vê se é isto que procura:

=DIATRABALHO(HOJE()-1;1;)

[ErikaMartins]

Gostaria de uma função que leia uma determinada data, e que verifica-se ela é menor ou maior do que 3 meses em relação a data hoje.

caso seja maior imprima vencida com o quadrinho vermelho.

caso seja menor imprima a vencer com o quadrinho verde.

[Patropi]

Boa tarde Erika

 

Seja bem-vinda ao fórum!

 

Podemos ajudar, mas para facilitar anexe uma planilha de exemplo, demonstrando manualmente o resultado esperado.

 

[]s

 

 

[Mayara Bandeira]

Boa Tarde, 

Preciso controlar o vencimento e emissão de relatórios em uma planilha do excel. 

Criei uma condição "Se" Para me alertar se a data de envio de relatório estava próxima ou vencida, segue 

=SE(G16-HOJE()>30;"Prazo - Mais de 1 mês"; SE(G16=HOJE();"Hoje"; SE(G16<HOJE();"Venceu"; SE(G16-HOJE()<10;"Prazo - Menos de 10 dias"; SE(G16-HOJE()<15;"Prazo - Menos de 15 dias"; "Prazo - Menos de 1 Mês")))))

Porém queria criar uma condição nessa expressão com a coluna da data que os relatórios foram enviados, pois muitas vezes eles estão são enviando antes do vencimento. 

Que a condição satisfaze se Se na coluna (DATA LIMITE RT) for menor que o dia de HOJE() satisfazer todas aquelas condições criadas anteriormente, porém se na coluna (DATA ENVIO RELATÓRIO) estiver com a data de envio contar na mensagem "Relatório Enviado". 

 

exemplo.xlsx

[FRANCIANY AGUIAR]

=SE(HOJE()<H4;"GARANTIA";"FORAGARANTIA") 

 

Bom dia, a formula acima nao esta fazendo a leitura correta... o que devo corrigi?

Preciso que me diga se o equipamento ainda tem garantia tambem acrescentar cores diferenciadas nas células.

 

[Patropi]

Boa tarde @FRANCIANY AGUIAR

 

Anexe uma planilha de exemplo, demonstrando manualmente o resultado esperado, pois a imagem não permite testar formulas.

 

[]s

[Janderson Coelho]

Bom dia!

Estou tentando concatenar dentro da fórmula SE.

 

O que estou querendo fazer é algo como =SE(A1<0="Target" + =hoje() + "12am"), quem puder me ajudar, agradeço.

[Visitante]

 

=SE(A1<0;"Target "&TEXTO(HOJE();"dd/mm/aa")&" 12am";"")

 

[Janderson Coelho]

Muito obrigado Osvaldo, funcionou aqui, só tem mais uma coisa... Gostaria de saber se há a possibilidade de deixar a a data com este formato (Target 25th Sep 12am).

[Visitante]

Qual o idioma da versão do seu Excel ?

[Janderson Coelho]

Utilizo-o em inglês... Segue a fórmula.

 

=IF(I11<0;"-Target "&TEXT(TODAY();"dd/mm/aa")&" 12am";"")

[Visitante]

target 26 set 12am

=if(i11<0,"target "&text(today(),"dd mmm")&" 12am","")

 

target 26 set 12am ~~~> retorna "S" maiúsculo, é que este site continua com o velho problema de transformar as maiúsculas inseridas no post em minúsculas

=if(i11<0,"target "&proper(text(today(),"dd mmm"))&" 12am","")

 

target 26th set 12am ~~~> idem comentário acima

=if(i11<0,"target "&day(today())&choose(if(and(right(text(today(),"dd"),1)*1<>0,right(day(today()),1)<4,left(text(today(),"dd"),1)*1<>1),right(day(today()),1),4),"st ","nd ","rd ","th ")&proper(text(today(),"mmm"))&" 12am","")

 

[Edson Luiz Branco]

Só uma observação em relação à fórmula do amigo @osvaldomp no que diz respeito aos ordinais em inglês: os ordinais de 21, 22, 23 e 31 seguem a sequência equivalente à de 1, 2 e 3, ou seja, 21st, 22nd, 23rd e 31st e não o th.  Já os ordinais 11, 12 e 13 são exceção e não seguem essa regra.

Como sugestão:

=IF(I11<0,"target "&DAY(TODAY())&CHOOSE(SUMPRODUCT((DAY(TODAY())={1;21;31})*1+(DAY(TODAY())={2;22;0})*2+(DAY(TODAY())={3;23;0})*3)+1,"th ","st ","nd ","rd ")&PROPER(TEXT(TODAY(),"mmm"))&" 12am","")

 

 

[Visitante]

Em 26/09/2020 às 20:19, Edson Luiz Branco disse:

Só uma observação em relação à fórmula do amigo @osvaldomp no que diz respeito aos ordinais em inglês: os ordinais de 21, 22, 23 e 31 seguem a sequência equivalente à de 1, 2 e 3, ou seja, 21st, 22nd, 23rd e 31st ~~~> sim, e se aplica também para 41, 42, 43, ... 51, 52, 53, ... 101, 102, 103, ... 701, 702, 703, ... isso já é sabido e previsto na fórmula que passei. A inconsistência é outra, a função CHOOSE() está recebendo o valor 4 para todos os dias do mês, e por isso retorna "th" para todos os dias.

Segue abaixo a fórmula corrigida.

 

 

=IF(I11<0,"Target "&DAY(TODAY())&CHOOSE(IF(AND(LEFT(TEXT(TODAY(),"dd"),1)*1=0,RIGHT(DAY(TODAY()),1)*1<4),RIGHT(DAY(TODAY()),1)*1,IF(AND(LEFT(DAY(TODAY()),1)*1>1,RIGHT(DAY(TODAY()),1)*1<4,RIGHT(DAY(TODAY()),1)*1<>0),RIGHT(DAY(TODAY()),1)*1,4)),"st ","nd ","rd ","th ")&PROPER(TEXT(TODAY(),"mmm"))&" 12am","")

 

[Edson Luiz Branco]

1 hora atrás, osvaldomp disse:

...sim, e se aplica também para 41, 42, 43, ... 51, 52, 53, ... 101, 102, 103, ... 701, 702, 703, ... isso já é sabido

    

[Janderson Coelho]

Obrigado Osvaldo e Edson, agradeço pela ajuda, funcionou perfeitamente aqui, só precisei trocar as vírgulas por pontos e vírgulas e irei deixar aqui a fórmula para quem quiser utilizar.

 

=IF(I4<0;"Target "&DAY(TODAY())&CHOOSE(SUMPRODUCT((DAY(TODAY())={1;21;31})*1+(DAY(TODAY())={2;22;0})*2+(DAY(TODAY())={3;23;0})*3)+1;"th ";"st ";"nd ";"rd ")&PROPER(TEXT(TODAY();"mmm"))&" 12am";"")

 

Só tenho mais uma dúvida... E acho que vocês podem me responder... Eu gostaria de saber se é possível por exemplo, "congelar" esta data, por exemplo, pela fórmula, ele vai retornar a data de hoje e isso está correto, mas há alguma possibilidade de ele continuar com a data de criação / modificação até ser atualizado?
Por exemplo, hoje é dia 28th, há alguma possibilidade de o excel me mostrar a data 28th quando eu abrir no dia 29th ou em qualquer outro dia?

[Visitante]

32 minutos atrás, Janderson Coelho disse:

Por exemplo, hoje é dia 28th, há alguma possibilidade de o excel me mostrar a data 28th quando eu abrir no dia 29th ou em qualquer outro dia?

 

E quanto ao mês? Por exemplo, em 10/out qual o resultado esperado?

[Janderson Coelho]

4 minutos atrás, osvaldomp disse:

E quanto ao mês? Por exemplo, em 10/out qual o resultado esperado?

O do dia em que foi criado.

Exemplo, enquanto ninguém atualizar o arquivo, ele continua a mostrar do dia em que foi criado.

[Visitante]

4 minutos atrás, Janderson Coelho disse:

O do dia em que foi criado.

 

Você quis dizer dia e mês em que foi criado, é isso?

[Janderson Coelho]

2 minutos atrás, osvaldomp disse:

 

Você quis dizer dia e mês em que foi criado, é isso?

Isso mesmo.

[Visitante]

Seria viável você inserir e manter a data da criação em uma célula auxiliar ?