VisualG Lista de Exercicios Visualg!!!

cslinhares · 29 de setembro de 2009

Pessoal sou iniciante e preciso de ajuda nestes exercícios. Help me please!!!!1

Os exercicios devem ser feitos no visualg.

Capitulo 12 e 15 Exercícios

Exercício 1

Escrever um algoritmo que lê um número desconhecido de valores, um de cada vez, e conta quantos

deles estão em cada um dos intervalos [0,25], (25,50], (50,75], (75,100].

Exercício 2

Escrever um algoritmo que leia informações sobre um grupo de 250 pessoas e calcule alguns dados

estatísticos. Para cada pessoas do grupo deve ler o nome da pessoa, a altura, o peso e o sexo (“F” para

feminino e “M” para o masculino). Calular e escrever:

A quantidade total de homens e mulheres e o percentual de cada.

A média de peso das pessoas (somatório dos pesos de todas as pessoas pela quantidade de pessoas)

O nome da pessoa mais alta.

Exercício 3

Escrever um algoritmo que gera e escreve os 4 primeiros números perfeitos. Um número perfeito é

aquele que é igual à soma dos seus divisores. Ex: 6 = 1+2+3, 28 = 1+2+4+7+14.

Exercício 4

Escrever um algoritmo que lê um número não determinado de valores para m, todos inteiros e

positivos, um de cada vez. Se m for par, verificar quantos divisores possui e escrever esta informação.

Se m for ímpar e menor do que 12 calcular e escrever o fatorial de m. Se m for ímpar e maior ou igual a

12 calcular e escrever a soma dos inteiros de 1 até numero lido.

Exercício 5

Faça um algoritmo que gere uma tabela com os números de 1 a 10 e mostre o seu quadrado, cubo,

fatorial, número de divisores e uma mensagem dizendo se o número é primo ou não. A cada 20 linhas

deve ser escrito o cabeçalho novamente:

"Número Quadrado Cubo Fatorial Divisores Primo"

1 1 1 1 1 Sim

2 4 8 2 2 Sim

Desafio

Escrever um algoritmo que lê um conjunto não determinado de pares de valores a, b, todos inteiros

e positivos, e para cada par lido, obtém o M.D.C. e o M.M.C. de a,b, escrevendo-os juntamente com os

valores lidos.

dr4cker · 29 de setembro de 2009

O que você já conseguiu fazer?

cslinhares · 29 de setembro de 2009

Pra falar a verdade não consegui fazer nada parei em estrutura ondional quando chegou em vetores travei!!!!

cslinhares · 30 de setembro de 2009

Consegui fazer o exercicio 2 e 3 falta agora o 1,4,5 e o desafio!!!

nicolas.tanski · 30 de setembro de 2009

Post o código fonte dos programas para podermos ajudá-lo, mesmo que não tenha conseguido terminar.

Falou!

cslinhares · 30 de setembro de 2009

Esses que estão faltando nem tentei fazer!!!! Tô sem tempo tá corrido!!!

Mel Piquenàáh · 2 de novembro de 2009

CsLinhares eu fiz o 1º e o 3º se voce puder me ajudar a terminar o 2° seria bom ... tenho que entregar esse exercicio essa semana que vai entra...

Não consigo fazer a parte de ver a pessoa mais alta e mostrar o nome dela!!!

você pode me ajuda....???

iftriangulo · 3 de dezembro de 2009

alguem pode me enviar a resposta deste exercicios , obrigada

nighthunder5 · 5 de julho de 2018

Eu resolvi dessa maneira:

Algoritmo "exercício 1"
Var
   n,inter_1, inter_2, inter_3, inter_4 : inteiro
   i : caractere

Inicio
   enquanto n > -1 faca
      escreva("INSIRA UM NÚMERO, PARA FINALIZAR DIGITE UM NÚMERO NEGATIVO:  ")
      leia(n)
      escreval()
      se (n >= 0) e (n < 25) então
         inter_1 <- inter_1 + 1
      fimse

      se (n >= 25) e (n < 50) então
         inter_2 <- inter_2 + 1
      fimse

      se (n >= 50) e (n < 75) então
         inter_3 <- inter_3 + 1
      fimse

      se (n >= 75) e (n <= 100) então
         inter_4 <- inter_4 + 1
      fimse
   fimenquanto

   escreval(i:13, "TABELA DE INTERVALOS")
   escreval("|  0 a 25  |  25 a 50  |  50 a 75  |  75 a 100  |")
   escreval("|  ", inter_1:6, "  |   ", inter_2:6, "  |   ", inter_3:6, "  |   ", inter_4:7, "  |")

Fimalgoritmo

nighthunder5 · 5 de julho de 2018

EXERCÍCIO 2 SEM VETOR

Algoritmo "exercício 2"
Var
   nome, sexo, nome_alto : caractere
   alt, peso, media_peso, perc_homens, perc_mulheres, total_peso, mais_alta : real
   n, homens, mulheres : inteiro
Inicio
   para n de 1 ate 250 faca
      escreval("NÚMERO DE CADASTRO", n)
      escreval()
      escreva("NOME: ")
      leia(nome)
      escreval()
      escreva("ALTURA: ")
      leia(alt)
      escreval()
      escreva("PESO: ")
      leia(peso)
      escreval()
      escreva("SEXO (M) MASCULINO (F) FEMININO :")
      leia(sexo)
      escreval()

      se sexo = "M" então
         homens <- homens + 1
      senao
         se sexo = "F" então
            mulheres <- mulheres + 1
         fimse
      fimse

      total_peso <- total_peso + peso

      se (alt > mais_alta) então
         mais_alta <- alt
         nome_alto <- nome
      fimse
   fimpara
   media_peso <- total_peso / 250
   perc_homens <- homens / 250 * 100
   perc_mulheres <- mulheres / 250 * 100

   escreval("HOMENS: ", homens, perc_homens:3:2, "%")
   escreval("MULHERES: ", mulheres, perc_mulheres:3:2, "%")
   escreval("MÉDIA DE PESO DOS CADASTRADOS: ", media_peso:3:2)
   escreval("CADASTRADO MAIS ALTO(A): ", nome_alto)


Fimalgoritmo

Shinda Júlio · 3 de setembro de 2018

@nighthunder5

Boa noite

tenho uma duvida porquê que escreval colocaste na resposta como " Media_peso2:3 " ?

devair1010 · 4 de setembro de 2018

@Shinda Júlio isso é por que para formatar a saída com casas decimais depois da vírgula precisa ser assim , nesse caso o programa imprimirá três casas depois da vírgula .

Simon Viegas · 4 de setembro de 2018

Complementando.

A formatação do número no Visualg funciona mais ou menos assim:

variável:E:D
//E=quantidade de caracteres que o número ocupará. Quando
//necessário, vai inserindo espaços a esquerda
//
//D=quantidade de números decimais. Esses números e também
//o "." fazem parte do total que foi reservado em E.
//
//Usando ou não o D, se o número tiver a parte decimal, será 
//exibido número com um valor arredondado (para + ou para -)

Veja um exemplo:

Algoritmo "FCdH"
var
   x,y:real

inicio
x<-9.49897
y<-9.504638245
//imprime o número original com UM espaço a esquerda (depois do "r")
escreval("X tem o valor",x,".") //X tem o valor 9.49897.
//imprime o número arredondado com pelo menos 10 casas a esquerda (se precisar
//insere espaços até ocupar as 10 casas)
escreval("X tem o valor",x:10,".") //X tem o valor         9.
//imprime o número arredondado com pelo menos 10 casas a esquerda (se precisar
//insere espaços até ocupar as 10 casas). E com duas casas decimais
escreval("X tem o valor",x:10:2,".") //X tem o valor      9.50.

escreval()
//imprime o número original com UM espaço a esquerda (depois do "r")
escreval("Y tem o valor",y,".") //Y tem o valor 9.504638245.
//imprime o número arredondado com pelo menos 5 casas a esquerda (se precisar
//insere espaços até ocupar as 5 casas).
escreval("Y tem o valor",y:5,".") //Y tem o valor   10.
//imprime o número arredondado com pelo menos 6 casas a esquerda (se precisar
//insere espaços até ocupar as 6 casas). E com duas casas decimais
//aqui vai ficar colado no "r", pois o número tera 8 dígitos, e só estou
//reservando 6, logo, o número tera o "tamanho original".
escreval("Y tem o valor",x:6:6,".") //Y tem o valor9.49897.

fimAlgoritmo

Sugiro efetuar testes alterando os valores.

obs.: é importante salientar que no Visualg, ao mandar imprimir variável, o programa já insere um espaço a esquerda. Por isso, na primeira linha "surge" sozinho um espaço entre o "r" e o "número". Em outras linguagens, coo Pascal, C, C++, Java, isso não ocorre!!! ou seja, foi o desenvolvedor do Visualg achou interessante colocar esse espaço!!

Shinda Júlio · 5 de setembro de 2018

@devair1010 @nighthunder5Obrigado já Entende

kibrizah · 16 de março de 2019

Em 29/09/2009 às 08:47, cslinhares disse:

Exercício 1:

Escrever um algoritmo que lê um número desconhecido de valores, um de cada vez, e conta quantos deles estão em cada um dos intervalos [0,25], (25,50], (50,75], (75,100].

Resposta:

Spoiler


Algoritmo "Contagem de intervalos"
Var
   n, c1, c2, c3, c4, x : inteiro
Inicio
   escreval ("Contagem de numeros por intervalo")
   escreval (" ")
   x <- 1
   enquanto x = 1 faca
      escreval ("Informe o numero: ")
      leia (n)
      se (n >= 0) e (n < 25) entao
         c1 <- c1+1
      senao
         se (n >= 25) e (n < 50) entao
            c2 <- c2+1
         senao
            se (n >= 50) e (n < 75) entao
               c3 <- c3+1
            senao
               se (n >= 75) e (n <=100) entao
                  c4 <- c4+1
               senao
                  escreval ("Numero fora da faixa")
               fimse
            fimse
         fimse
      fimse
      escreval ("Deseja continuar? 1- Sim 2- Não")
      leia (x)
   fimenquanto
   escreval ("Quantidade de numeros na faixa 0-24 é: ",c1)
   escreval ("Quantidade de numeros na faixa 25-49 é: ",c2)
   escreval ("Quantidade de numeros na faixa 50-74 é: ",c3)
   escreval ("Quantidade de numeros na faixa 75-100 é: ",c4)
Fimalgoritmo

Em 29/09/2009 às 08:47, cslinhares disse:

Exercício 2:

Escrever um algoritmo que leia informações sobre um grupo de 250 pessoas e calcule alguns dados estatísticos. Para cada pessoas do grupo deve ler o nome da pessoa, a altura, o peso e o sexo (“F” para feminino e “M” para o masculino). Calcular e escrever:

A quantidade total de homens e mulheres e o percentual de cada.

A média de peso das pessoas (somatório dos pesos de todas as pessoas pela quantidade de pessoas)

O nome da pessoa mais alta.

Resposta:

Spoiler


Algoritmo "Dados estatisticos"
Var
   alto, nome, sexo : caractere
   x, tf, tm : inteiro
   peso, malt, media, altura : real
Inicio
   escreval ("Dados estatisticos")
   escreval (" ")
   para x de 1 ate 2 faca
      escreval ("Informe o nome: ")
      leia (nome)
      escreval ("Informe o peso: ")
      leia (peso)
      escreval ("Informe o sexo: (F)eminino ou (M)asculino ")
      leia (sexo)
      escreval ("Informe a altura: ")
      leia (altura)
      media <- media+peso
      se (sexo = "F") ou (sexo = "f") entao
         tf <- tf+1
      senao
         se (sexo = "M") ou (sexo = "m") entao
            tm <- tm+1
         senao
            escreval ("Sexo invalido")
         fimse
      fimse
      se x = 1 entao
         alto <- nome
         malt <- altura
      senao
         se altura > malt entao
            alto <- nome
            malt <- altura
         fimse
      fimse
   fimpara
   escreval ("A pessoa mais alta é ",alto)
   escreval ("A media do peso é ",media/2)
   escreval ("Quantidade de homens é ",tm)
   escreval ("Quantidade de mulheres é ",tf)
   escreval ("Percentual de homens é ",(tm*100)/2)
   escreval ("Percentual de mulheres é ",(tf*100)/2)
Fimalgoritmo

Em 29/09/2009 às 08:47, cslinhares disse:

Exercício 3:

Escrever um algoritmo que gera e escreve os 4 primeiros números perfeitos. Um número perfeito é aquele que é igual à soma dos seus divisores. Ex: 6 = 1+2+3, 28 = 1+2+4+7+14.

Resposta:

Spoiler


algoritmo "números perfeitos"
var
   i, num, soma, cont: inteiro
inicio
   cont <- 0
   num <- 1
   enquanto (cont <= 4) faca
      soma <- 0
      para i de 1 ate num-1 faca
         se (num%i = 0) entao
            soma <- soma + i
         fimse
      fimpara
      se (soma = num) entao
         escreval(num)
         cont <- cont + 1
      fimse
      num <- num + 1
   fimenquanto
fimalgoritmo

Em 29/09/2009 às 08:47, cslinhares disse:

Exercício 4:

Escrever um algoritmo que lê um número não determinado de valores para m, todos inteiros e positivos, um de cada vez. Se m for par, verificar quantos divisores possui e escrever esta informação. Se m for ímpar e menor do que 12 calcular e escrever o fatorial de m. Se m for ímpar e maior ou igual a 12 calcular e escrever a soma dos inteiros de 1 até numero lido.

Resposta:

Spoiler


Algoritmo "Numeros M"
// Disciplina   : [Linguagem e Lógica de Programação]
// Professor   : Antonio Carlos Nicolodi
// Descrição   : Aqui você descreve o que o programa faz! (função)
// Autor(a)    : Nome do(a) aluno(a)
// Data atual  : 16/03/2019
Var
   // Seção de Declarações das variáveis
   i, m, x, d, f, c : inteiro
Inicio
   // Seção de Comandos, procedimento, funções, operadores, etc...
   i <- 1
   enquanto i <> 2 faca
      escreval ("Digite um numero: ")
      leia (m)
      se m <= 0 entao
         escreval ("Numero invalido!")
      senao
         se m % 2 = 0 entao
            para x de 1 ate m faca
               se m % x = 0 entao
                  d <- d+1
               fimse
            fimpara
            escreval ("Quantidade de divisores de ",m," é",d)
         senao
            se m < 12 entao
               f <- 1
               para x de 1 ate m faca
                  f <- x*f
               fimpara
               escreval ("Fatorial de ",m," é ",f)
            senao
               para x de 1 ate m faca
                  c <- c+x
               fimpara
               escreval ("Soma de 1 até ",m," é ",c)
            fimse
         fimse
      fimse
      escreval (" ")
      escreval ("Deseja continuar? 1- Sim ou 2-Não")
      leia (i)
   fimenquanto
Fimalgoritmo

Em 29/09/2009 às 08:47, cslinhares disse:

Exercício 5:

Faça um algoritmo que gere uma tabela com os números de 1 a 10 e mostre o seu quadrado, cubo, fatorial, número de divisores e uma mensagem dizendo se o número é primo ou não. A cada 20 linhas deve ser escrito o cabeçalho novamente:

"Número Quadrado Cubo Fatorial Divisores Primo"

1 1 1 1 1 Sim

2 4 8 2 2 Sim

Resposta:

Spoiler


Algoritmo "Tabela INFO"
// Disciplina   : [Linguagem e Lógica de Programação]
// Professor   : Antonio Carlos Nicolodi
// Descrição   : Aqui você descreve o que o programa faz! (função)
// Autor(a)    : Nome do(a) aluno(a)
// Data atual  : 16/03/2019
Var
   // Seção de Declarações das variáveis
   i, x, f, c : inteiro
   p : caractere
Inicio
   // Seção de Comandos, procedimento, funções, operadores, etc...
   para x de 1 ate 10 faca
      se ((x-1)%20 = 0) entao
         escreval ("Numero, quadrado, cubo, fatorial, divisores, primo")
      fimse
      f <- 1
      f <- f*x
      c <- 0
      para i de 1 ate x faca
         se x % i = 0 entao
            c <- c+1
         fimse
   fimpara
   se c <= 2 entao
      p <- "Sim"
   senao
      p <- "Não"
   fimse
   escreval (x," ",x*x," ",x*x*x," ",f," ",c," ",p)
fimpara
Fimalgoritmo

Em 29/09/2009 às 08:47, cslinhares disse:

Desafio

Escrever um algoritmo que lê um conjunto não determinado de pares de valores a, b, todos inteiros e positivos, e para cada par lido, obtém o M.D.C. e o M.M.C. de a,b, escrevendo-os juntamente com os valores lidos.

Resposta:

Ainda estou trabalhando no Desafio algoritmo trava na hora de calcular MMC, e o calculo de MDC esta dando errado com valores de a e b de 2 e 3 respectivamente. Segue código quem puder ajudar:

Spoiler


Algoritmo "MMC e MDC"
// Disciplina   : [Linguagem e Lógica de Programação]
// Professor   : Antonio Carlos Nicolodi
// Descrição   : Aqui você descreve o que o programa faz! (função)
// Autor(a)    : Nome do(a) aluno(a)
// Data atual  : 16/03/2019
Var
   // Seção de Declarações das variáveis
   a, b, i, maior, menor, aux, r, c : inteiro
Inicio
   // Seção de Comandos, procedimento, funções, operadores, etc...
   enquanto i <> 2 faca
      escreval ("Digite numero A: ")
      leia (a)
      escreval ("Digite numero B: ")
      leia (b)
      se (a < 0) ou (b < 0) entao
         escreval ("Numero invalido!")
      senao
         se (a > b) entao
            maior <- a
            menor <- b
         senao
            maior <- b
            menor <- a
         fimse
         enquanto (maior % menor <> 0) faca
            aux <- menor
            menor <- maior % menor
            maior <- aux
         fimenquanto
         escreval ("")
         escreval ("O Máximo Divisor Comum entre", a, " e", b, " é:", menor)
         r <- 2
         c <- 1
         enquanto (a+b <> 2) faca
            se (a % c = 0) ou (b % c = 0) entao
               r <- r*c
               se (a % c = 0) entao
                  a <- a % c
               fimse
               se (b % c = 0) entao
                  b <- b % c
               fimse
            senao
               c <- c+1
            fimse
         fimenquanto
         escreval ("O Maximo Multiplicador Comum entre ",a, " e",b, "é:", r)
Fimalgoritmo

Simon Viegas · 16 de março de 2019

@kibrizah, segue:

Exercício 1 = ERROS NOS PARÂMETROS

Não está respeitando os intervalos dos números. O enunciado é taxativo: "intervalos [0,25], (25,50], (50,75], (75,100]".

Adendo: [] é uma coisa, () é outra.

Exercício 2 = OK.

Poderia ter uma questão para as validações dos valores inseridos, mas é de boa. Entretanto seria interessante usar o x na hora de calcular a média e as porcentagens.

Exercício 3 = OK, mas pouco otimizado

O algoritmo está muito simples. Precisa dar uma otimizada nesse algoritmo para encontrar os múltiplos. Dá para simplificar e muito as etapas. Está gastando muito recurso computacional.

Exercício 4 = INCOMPLETO

Aqui sim precisa validar os valores de entrada. É especificado que tem que ser inteiro e positivo (ou seja, número naturais). Seu código aceita negativos. Da mesma forma, necessário otimizar o algoritmo que verificar os divisores... está muito "bruto".

Exercício 5 = INCOMPLETO

Não está calculando os fatoriais e as colunas estão desalinhadas.

DESAFIO = SÓ METADE

4 horas atrás, kibrizah disse:

[...] o calculo de MDC esta dando errado com valores de a e b de 2 e 3 respectivamente.

Qual erro? testei aqui e funcionou normalmente.

4 horas atrás, kibrizah disse:

Ainda estou trabalhando no Desafio algoritmo trava na hora de calcular MMC

Como é um desafio, por enquanto aí é com você (que aceitou).

Posso ajudar em relação a sintaxe... por exemplo, está faltando um fimSe e um fimEnquanto.

No aguardo.

Luis Bitu · 30 de abril de 2020

Exercício I:

var
valor: inteiro
inicio
// Seção de Comandos
escreva ("Digite um numero de 0 a 100: ")
leia (valor)
enquanto (valor > 100) faca
escreva ("ERRO!Digite um numero de 0 a 100: ")
leia (valor)
fimenquanto
escreval("|--------|---------|---------|----------|")
escreval("|  EX 1 - O Nº ESTÁ NO INTERVALO COM X  |")
escreval("|--------|---------|---------|----------|")
escreval("| 0 a 25 | 26 a 50 | 51 a 75 | 76 a 100 |")
escreval("|---------------------------------------|")
se (valor >=0) e (valor<=25) entao
escreval("|   X    |         |         |          |")
senao
se (valor >=26) e (valor<=50) entao
escreval("|        |    X    |         |          |")
senao
se (valor >=51) e (valor<=75) entao
escreval("|        |         |    X    |          |")
senao
se (valor >=75) e (valor<=100) entao
escreval("|        |         |         |     X    |")
fimse
fimse
fimse
fimse
escreval("|---------------------------------------|")
fimalgoritmo

Simon Viegas · 1 de maio de 2020

@Luis Bitu, o enunciado é este:

Em 29/09/2009 às 08:47, cslinhares disse:

Exercício 1

Escrever um algoritmo que lê um número desconhecido de valores, um de cada vez, e conta quantos

deles estão em cada um dos intervalos [0,25], (25,50], (50,75], (75,100].

Teu* algoritmo não está fazendo isso.

Luis Bitu · 1 de maio de 2020

obrigado pela resposta! Ressalto que sou iniciante, e ainda estou me adaptando ao programa.

Como não entendi o enunciado do exercício 1, peguei seu algoritmo e joguei no meu visualg, depois fiz do meu jeito e deu o mesmo resultado do seu, porém com alguns pequenos ajustes. Minha versão do visualg é a 2.0. Pode ser isso.

Em relação ao exercício 2, não consegui ir muito além. Por curiosidade peguei o exercício 2 já resolvido e fui tentar fazer a leitura. Não consigo entender a logica abaixo:

homens <- homens + 1
total_peso <- total_peso + peso
se (alt > mais_alta) entao
  mais_alta <- alt
  nome_alto <- nome
fimse

pode me explicar melhor?

devair1010 · 1 de maio de 2020

@Luis Bitu quem fez esse exercício foi o @nighthunder5 , e aqui :

se sexo = "M" então              // se sexo masculino 
  homens <- homens + 1           // incrementa a variável homens
senao                            // senão
  se sexo = "F" então            // se sexo for feminino
    mulheres <- mulheres + 1     // increnta a variável mulheres
  fimse
fimse
total_peso <- total_peso + peso  // soma todos os pesos e depois dividir pela qtd
se (alt > mais_alta) então       // verifica qual a maior altura
  mais_alta <- alt               // guarda a maior altura nessa variável
  nome_alto <- nome              // e guarda também o nome da pessoa mais alta
fimse

Simon Viegas · 1 de maio de 2020

14 horas atrás, Luis Bitu disse:

Como não entendi o enunciado do exercício 1, peguei seu algoritmo e joguei no meu visualg, depois fiz do meu jeito e deu o mesmo resultado do seu, porém com alguns pequenos ajustes. Minha versão do visualg é a 2.0. Pode ser isso.

@Luis Bitu, está aí toda a questão: não dá* para resolver um problema que não se sabe o que se trata. No caso, se desse um resultado "certo", seria apenas coincidência, concorda? (afinal, não se sabia que era para fazer)

Primeiro tenta entender, depois tenta resolver... "Ah! isso é óbvio", poderiam pensar!, mas não é... e digo mais... isso pode ser levado para o dia-a-dia mesmo... é o que mais ocorre!!! É meio que comum focarmos na solução, onde o correto seria focar no problema!!!

Vamos para exemplo práticos:

Em 29/09/2009 às 08:47, cslinhares disse:

Exercício 1

Escrever um algoritmo que lê um número desconhecido de valores, um de cada vez, e conta quantos

deles estão em cada um dos intervalos [0,25], (25,50], (50,75], (75,100].

Ok! a primeira coisa que deveria vir a cabela é: mais que raios significa esses "[", "]", ")" e "("?

Já sabem?

Eu já tenho um base... mas para ter certeza vamos lá no Google:

https://www.google.com/search?q=intervalos+parenteses+e+colchetes

Futuca, futuca... e olha lá:

https://pt.wikipedia.org/wiki/Intervalo_(matemática)

Pronto! um é para um intervalo aberto e outro para fechado.

Beleza, o @kibrizah postou um código, entretanto faltou apenas justamente esse "detalhe" (que não é apenas um detalhe, é na verdade o cerne!), segue:

Em 16/03/2019 às 17:41, Simon Viegas disse:

Exercício 1 = ERROS NOS PARÂMETROS

Não está respeitando os intervalos dos números. O enunciado é taxativo: "intervalos [0,25], (25,50], (50,75], (75,100]".

Adendo: [] é uma coisa, () é outra.

Aproveitando o código dele, poderia ser algo assim:

algoritmo "Contagem de intervalos"
var
   qtdFaixa1, qtdFaixa2, qtdFaixa3, qtdFaixa4 : inteiro
   numero, qtdNumeros : inteiro
   i : inteiro

inicio
   escreval("Contagem de numeros por intervalo")
   escreval(" ")
   qtdNumeros <- randi(16)+5 //gerar entre 5 e 20 números
   escreval("Serão gerados ", qtdNumeros:1)
   timer 2000
   timer 0

   //obs.: No VisualG nem precisaria zerar, pois é zerado automaticamente!
   qtdFaixa1 <- 0
   qtdFaixa2 <- 0
   qtdFaixa3 <- 0
   qtdFaixa4 <- 0

   para i de 1 ate qtdNumeros faca
      ALEATORIO -5, 105
      leia(numero)
      ALEATORIO OFF
      timer 50
      timer 0

      se ((numero >= 0) e (numero <= 25)) entao //[0,25]
         qtdFaixa1 <- qtdFaixa1+1
      senao
         se (numero > 25) e (numero <= 50) entao //(25,50]
            qtdFaixa2 <- qtdFaixa2+1
         senao
            se (numero > 50) e (numero <= 75) entao //(50,75]
               qtdFaixa3 <- qtdFaixa3+1
            senao
               se (numero > 75) e (numero <=100) entao //(75,100]
                  qtdFaixa4 <- qtdFaixa4+1
               fimSe
            fimSe
         fimSe
      fimSe
   fimPara
   escreval("")
   escreval("Quantidade de numeros na faixa [0,25]   é : ", qtdFaixa1:1)
   escreval("Quantidade de numeros na faixa (25,50]  é : ", qtdFaixa2:1)
   escreval("Quantidade de numeros na faixa (50,75]  é : ", qtdFaixa3:1)
   escreval("Quantidade de numeros na faixa (75,100] é : ", qtdFaixa4:1)
fimAlgoritmo

Escrever um algoritmo que lê um número desconhecido de valores [ficou mais ou menos desconhecido. rs]
um de cada vez [OK]
e conta quantos deles estão em cada um dos intervalos [0,25], (25,50], (50,75], (75,100] [OK]

...

Ia tentar o 2, mas preciso sair agora... depois eu volto!