Assembly + LCD 16X2

Andreluz · 11 de maio de 2011

Olá!

Estou com dificuldade em movimentar as palavras que escrevo no LCD.

Mulder_Fox · 11 de maio de 2011

Olá Andreluz.

Você está trabalhando com qual microcontrolador?

Você mesmo desenvolveu o código ou está usando um pronto?

Se puder poste o arquivo fonte.

Andreluz · 12 de maio de 2011

Estou usando o Microcontrolador AT89S52.

Eu peguei um pronto mas, vou modificar algumas coisas. Queria entender qual procedimento devo usar para a movimentação ou fazer tipo o lance de ônibus (aparece, some e aparece outro).

PROGRAMA (Sem alteração):



	iseg      at 80H

PILHA:	ds	10	; 3 chamadas de subrotina

BUSDISP	EQU	P2
RS	equ	P1.0
EN	equ	P1.2
RW 	equ	P1.1
CLS	EQU	01
FS	equ	0

	cseg	at 0

	JMP	INIT


INIT:	MOV	SP,#PILHA-1	;DEFINE PILHA
	clr	RW

	CALL	IDISP		;INICIALIZA DISPLAY
	MOV	DPTR,#MENS0
	CALL	PRINT0		
	MOV	DPTR,#MENS1	;
	CALL	PRINT1
	jmp	$
;
IDISP:	clr	RW
	CLR	EN
	CALL	DELAY2		;6ms		
	CLR	RS		;PREPARA DISPLAY PARA COMANDO
	MOV	R2,#01		
VOLTA2:	CALL	GETD
	MOV	BUSDISP,A
	SETB	EN
	NOP			
	CLR	EN
	CALL	DELAY2		;6ms		
	INC	R2
	CJNE	R2,#6,VOLTA2
	RET			

GETD:	MOV	A,R2
	MOVC	A,@A+PC
	RET
	DB	38H,38H,06,0CH,01

DELAY2:	MOV	R6,#50		;1 DELAY DE 6ms
DLY21:	MOV	R7,#177		
DLY22:	DJNZ	R7,DLY22	
	DJNZ	R6,DLY21	
	RET			

HOME:	MOV	BUSDISP,#02
	SJMP	HOME0

DCLS0:	CLR	RS		;PREPARA PARA COMANDO
	MOV	BUSDISP,#CLS
HOME0:	SETB	EN
	NOP			
	CLR	EN
	CALL	DELAY2		;6ms		
	RET

PRINT0:	MOV	A,#80H		;Primeira linha
	CALL	WRDISPC		;ENVIA AO DISPLAY
	jmp	print3

PRINT1:	MOV	A,#0C0h
	CALL	WRDISPC		;ENVIA AO DISPLAY

PRINT3:	CLR	A
	MOVC	A,@A+DPTR
	CJNE	A,#FS,PRINT4	
	jmp	print5
PRINT4:	call	WRDISPD
	INC	DPTR		;APONTA NOVO CARACTER
	jmp	print3
print5:	ret
;
WRDISPC:push	acc
	clr	RS
	setb	RW		; Ler Status
waitlcd:setb	EN
	nop
	nop
	mov	a,BUSDISP
	clr	EN
	jb	acc.7,waitlcd
	clr	RW
	pop	acc
	mov	BUSDISP,A	; JOGA VALOR A SER ESCRITO NO DISPLAY
	setb	EN		
	nop
	nop
	clr	EN
	ret

WRDISPD:push	acc
	clr	RS
	setb	RW		; Ler Status
waitlcdd:setb	EN
	nop
	nop
	mov	a,BUSDISP
	clr	EN
	jb	acc.7,waitlcdd
	clr	RW
	pop	acc
	setb	RS		; esvreve dados
	mov	BUSDISP,A		; JOGA VALOR A SER ESCRITO NO DISPLAY
	setb	EN		
	nop
	nop
	clr	EN
	ret

MENS0:	db	" CARA EU ESTOU  ",FS ; 80h-8fh
MENS1:	db	"  FUNCIONANDO!  ",FS ; c0h-cfh


	end