Ir ao conteúdo
  • Cadastre-se

salvar em pdf escolhendo a pasta


Posts recomendados

 Bom dia pessoal,

 

Fiz a macro abaixo e está funcionando normalmente, porém eu preciso que a pasta onde o arquivo será salvo seja escolhida pelo usuário pois varias pessoas estarão utilizando a mesma planilha e cada um pode escolher salvar o arquivo em seu computador.. Alguém pode me ajudar?

 

 Sheets("COTAÇÃO").Select
    Range("B2:F55").Select
    Range("F2").Activate
    ChDir "S:\Vendas\Gerência Comercial\Vendas Nacionais\Relatórios de desempenho"
    Selection.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
        "S:\Vendas\Gerência Comercial\Vendas Nacionais\Relatórios de desempenho\teste.pdf" _
        , Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _
        :=False, OpenAfterPublish:=True
    Range("H39").Select
End Sub

Link para o comentário
Compartilhar em outros sites

Boa tarde, Alex

 

Teste e dê retorno:

 

Sub SalvaPDFEscolhendoPasta()
  'Exibe caixa de diálogo padrão solicitando ao usuário escolher nome e local de salvamento do pdf
  'Em resposta à dúvida de AlexAltheman fórum ClubeDoHardware em 27/01/17 tópico
  'https://www.clubedohardware.com.br/forums/topic/1209486-salvar-em-pdf-escolhendo-a-pasta/#comment-6652121
  Dim cxDialogo As FileDialog
  Set cxDialogo = Application.FileDialog(msoFileDialogSaveAs)
  With cxDialogo
    .InitialFileName = "*.pdf"
     If .Show = -1 Then 'Se o usuário pressionou "Salvar":-1 "Cancelar": 0
       Sheets("COTAÇÃO").Range("B2:F55").ExportAsFixedFormat Type:=xlTypePDF, _
                       Filename:=.SelectedItems(1), Quality:=xlQualityStandard, _
                           IncludeDocProperties:=True, IgnorePrintAreas:=False, _
                       OpenAfterPublish:=True
     End If
  End With
End Sub

Obs.: eliminei por conta algumas instruções Select  de seu código para torná-lo mais enxuto, ok?

Link para o comentário
Compartilhar em outros sites

@Edson Luiz Branco  funcionou sim muito obrigado. porém tive que escolher salvar em PDF e escolher o nome.

 

A minha ideia é de a opção salvar em PDF esteja selecionada automatico e o nome do arquivo seja uma concatenação de (D10; " "; "-"; C55; "m³/h").. Isto é possível??

Podeira me ajudar?

Link para o comentário
Compartilhar em outros sites

Sim, é possível, só não pode usar aquela barra (/) da unidade de vazão, substitui por underline. Veja agora:

 

Sub SalvaPDFEscolhendoPasta()
  'Exibe caixa de diálogo padrão solicitando ao usuário escolher nome e local de salvamento do pdf
  'Em resposta à dúvida de AlexAltheman fórum ClubeDoHardware em 27/01/17 tópico
  'https://www.clubedohardware.com.br/forums/topic/1209486-salvar-em-pdf-escolhendo-a-pasta/#comment-6652121
  Dim cxDialogo As FileDialog
  Dim NomeSugerido As String
  With Sheets("COTAÇÃO")
    NomeSugerido = .Range("D10") & "-" & .Range("C55") & "m³_h" & ".pdf"
  End With
  Set cxDialogo = Application.FileDialog(msoFileDialogSaveAs)
  With cxDialogo
    .InitialFileName = NomeSugerido
     If .Show = -1 Then  'Se o usuário pressionou "Salvar":-1 "Cancelar": 0
       Sheets("COTAÇÃO").Range("B2:F55").ExportAsFixedFormat Type:=xlTypePDF, _
                       Filename:=.SelectedItems(1), Quality:=xlQualityStandard, _
                           IncludeDocProperties:=True, IgnorePrintAreas:=False, _
                       OpenAfterPublish:=True
     End If
  End With
End Sub

 

Link para o comentário
Compartilhar em outros sites

@Edson Luiz Branco eu conseguir adaptar a sua programação e deu certo porém tive mesmo o problema com a barra... Muito obrigado mais uma vez

adicionado 1 minuto depois

@CasaDoHardware  sim...é exatamente essa a intenção pois a planilha será utilizada por varias pessoas e cada um poderá salvar no local que quiser..

 

Obrigado pela ajuda

Link para o comentário
Compartilhar em outros sites

Visitante
Este tópico está impedido de receber novas respostas.

Sobre o Clube do Hardware

No ar desde 1996, o Clube do Hardware é uma das maiores, mais antigas e mais respeitadas comunidades sobre tecnologia do Brasil. Leia mais

Direitos autorais

Não permitimos a cópia ou reprodução do conteúdo do nosso site, fórum, newsletters e redes sociais, mesmo citando-se a fonte. Leia mais

×
×
  • Criar novo...