VisualG porque (x:3) e qual a utilidade de var contador

[Orizune]

Estou aprendendo através de um ebook e surgiram algumas dúvidas.

1 - na primeira imagem eu não compreendi o uso do "contador", nem sua necessidade. A forma que foi explicada eu não entendi, então se puderem por gentileza explicar de mais de uma forma para leigos dando exemplos, me ajudaria tipo, muuuuito.

2 - Na segunda imagem não compreendo o (x:3), o que significa e para que serve, de novo, se puder dar exemplos e mais de uma forma de explicar, ajudaria muito.

 

Obrigado a todos, me juntei a comunidade hoje, porque não consegui encontrar respostas as minhas dúvidas específicas.

[devair1010]

@Orizune     o x:3 é para formatar a saída de dados , organizando por colunas ,  alinhando à direita , assim o 3 significa que serão três colunas , que organizará os números até 999 ,  e para organizar até 9999 colocaria x : 4.

 

o contador nesse caso aí não faz diferença nenhuma ,  e ele poderia ser substituído por uma outra variável qualquer , pois não se faz nenhuma referencia a esse nome ,   mas quando se usa o nome de contador para um  variável é por que vai fazer a contagem de alguma coisa ,  e depois usar esse total para fazer cálculos ou comparações .

[Simon Viegas]

Só complementado:

 

Sobre:

Em 15/05/2019 às 22:39, Orizune disse:

1 - na primeira imagem eu não compreendi o uso do "contador", nem sua necessidade. A forma que foi explicada eu não entendi, então se puderem por gentileza explicar de mais de uma forma para leigos dando exemplos, me ajudaria tipo, muuuuito.

 

Isso se refere apenas ao NOME DA VARIÁVEL, ou seja, a sua NOMENCLATURA. No teu programa, você pode usar o nome que quiser... por exemplo:

 

algoritmo "Multiplicação com Para/Faca"
var
   nome, hipotenusa, celular, blablabla: inteiro

inicio
escreval("Informe o primeiro número: ")
leia(nome)
escreval("Informe o segundo número: ")
leia(hipotenusa)

celular <- 0
para blablabla de 1 ate hipotenusa faca
   celular <- celular + nome
fimPara

escreval("Resultado", celular)
fimAlgoritmo

Vai funcionar exatamente da mesma forma... não muda algo para o compilador ou para a execução no computador!!! ou seja, usar nomenclaturas mais coerentes estaria voltado para uma questão de bom senso e boas práticas... é algo relacionado ao programador.

 

No caso, usar nomenclaturas que remetem mais a funcionalidade da variável deixa a compreensão do algoritmo mais fácil. Terá menos esforço para abstrair a lógica. Por exemplo:

 

algoritmo "Multiplicação com Para/Faca"
var
   multiplicando, multiplicador :inteiro
   produto :inteiro
   i :inteiro
   
inicio
escreval("Informe o primeiro número: ")
leia(multiplicando)
escreval("Informe o segundo número: ")
leia(multiplicador)

produto <- 0
para i de 1 ate multiplicador faca
   produto <- produto + multiplicando
fimPara

escreval("Resultado", produto)
fimAlgoritmo

CONCLUSÃO

A nomenclatura contador simplesmente o termo escolhido pelo programador. Talvez para ele fez sentido chamar assim... algo com está "contando a vezes que está somando" etc.

 

De um modo geral para o para/faca é meio que convencionado utilizar a nomenclatura i, ou seja: simplesmente troque de contador para i.

 

 

 

 

Em 15/05/2019 às 22:39, Orizune disse:

2 - Na segunda imagem não compreendo o (x:3), o que significa e para que serve, de novo, se puder dar exemplos e mais de uma forma de explicar, ajudaria muito. 

 

Resumidamente funciona assim: "reserve pela esquerda pelo menos 3 casas para a variável", ou seja, todo número vai ocupar pelo menos 3 casas. Segue um exemplo:

 

algoritmo "FCdH"
var
   x :inteiro
inicio
   x <- 1
   escreval(x:5)
   x <- 22
   escreval(x:5)
   x <- 333
   escreval(x:5)
   x <- 4444
   escreval(x:5)
   x <- 55555
   escreval(x:5)
   x <- 666666
   escreval(x:5)
   x <- 7777777
   escreval(x:5)
   x <- 88888888
   escreval(x:5)
fimAlgoritmo

Como reservei 5, até o 55555 vão ocupar 5 casas. Esse números vão ficar alinhados a direita. Como os outros tem mais de 5 casas, vão ser escritos normalmente, já que estão acima do limite mínimo de casas.

 

Esse tipo de formatação é, por exemplo, muito útil para imprimir uma matriz, ex.:

 

Sem formatação:

algoritmo "FCdH"
var
   i, j :inteiro
inicio
   para i de 1 ate 5 faca
      para j de 1 ate 5 faca
          escreva (RandI(1200))
      fimPara
      escreval
   fimPara
fimAlgoritmo

 

 

Com formatação:

algoritmo "FCdH"
var
   i, j :inteiro
inicio
   para i de 1 ate 5 faca
      para j de 1 ate 5 faca
          escreva (RandI(1200):5)
      fimPara
      escreval
   fimPara
fimAlgoritmo

 

Observe como exibição ficou alinhada a direita.

 

Por ai vai.