VisualG O que estou fazendo de errado??

[gabriela0404]

Var
// Seção de Declarações das variáveis 
resto, cont : real

Inicio
// Seção de Comandos, procedimento, funções, operadores, etc... 
enquanto  cont=1000 ; cont<2000 faca

inicio
resto <- cont mod 11
se (resto =  5) entao
escreva (cont)
fimse
fimenquanto
Fimalgoritmo

Algoritmo que verifique e mostre os números entre 1000 e 2000 (inclusive) que, quando divididos por 11, produzam resto igual a 5.

 

[navegantenarede]

@gabriela0404 se é inclusivo, então tem que ser menor ou igual a 2000 e parece que tá faltando o incrementador do contador, a cada iteração precisa incrementar de alguma forma para o 1000 passar para 1001 e verificar a condição da questão.

[devair1010]

@gabriela0404    seu código está bom ,  faltou alguns comandos e outros fora do lugar ,  e seu código com algumas  modificações poderia ser assim  :

Algoritmo "resta_5"
Var
  cont  : inteiro // o comando mod só funciona com inteiro, se usar outro tipo buga o compilador e trava tudo e é preciso fechar usando o ctrl + alt
  resto : real
Inicio
  cont := 1000//inicializar a variável
  enquanto (cont>=1000) e (cont<=2000) faca// duas comparações use expresão lógica
  //expresões lógicas < e ou nao > precisam ficar entre parenteses
    resto <- cont mod 11
    se resto = 5 entao     // uma comparação apenas , não precisa ficar entre parenteses
      escreva(cont)        // escreve na tela sem pular para outra linha
    fimse
    cont := cont + 1       // incrementar a variável para o loop proseguir até o final, senão loop infinito e buga tudo também
  fimenquanto              // precisa colocar o fimenquanto
  escreval
  escreval                 // pular linhas no final para efeito de apresentação
Fimalgoritmo

 

[Simon Viegas]

Só um adendo:

 

1 hora atrás, devair1010 disse:

    resto : real

 

O resto também seria inteiro mesmo, pois sempre o resto será inteiro.

 

 

Outra forma de fazer seria utilizando o para/faca. Ex.:

algoritmo "resta_5"
var
   cont, resto : inteiro
inicio
   para cont de 1000 ate 2000 faca
      resto <- cont mod 11
      se resto = 5 entao
         escreva(cont)
      fimse
   fimPara
fimAlgoritmo

 

Em ambos os códigos, nem precisaria da variável resto. Ex.:

algoritmo "resta_5"
var
   cont : inteiro
inicio
   para cont de 1000 ate 2000 faca
      se cont mod 11 = 5 entao
         escreva(cont)
      fimse
   fimPara
fimAlgoritmo

 

Aí vai do gosto.