Access Banco de Dados - Anexar Comentários do Excel

[zPenguin]

Gostaria de saber se é possivel guardar um comentário do excel no BD do access. Se for possivel, como poderia estar fazendo isso ? 

Agradeço desde já 

[Basole]

Sim eh possivel. 

Segue um exemplo. Ajuste no codigo no local indicado, de acordo com as caracteristicas dos seus arquivo excel e access. 

 

Sub EnviaComentariosExcelParaAccess()
' Ative as referências no editor do VB --> Ferramentas --> Referências --> Microsoft ActiveX Data Objects 6.1 Library
'  Exporta dados dos comentarios da planilha ativa para uma tabela em um banco de dados do Access
'  Este procedimento deve ser editado antes de usar
Dim cn As ADODB.Connection, rs As ADODB.Recordset, r As Long
' Conecta-se ao banco de dados do Access
Set cn = New ADODB.Connection
cn.Open "Provider=microsoft.ace.oledb.12.0; " & _
"Data Source=" & ThisWorkbook.Path & "\NOME_DA_SUA_TABELA_AQUI.accdb;"
' Abre um recordset
Set rs = New ADODB.Recordset
rs.Open "NOME_DA_SUA_TABELA_AQUI", cn, adOpenKeyset, adLockOptimistic, adCmdTable
    
r = 1 'a linha inicial na planilha

Do Until Range("A" & r).Comment Is Nothing
' Repete até a primeira célula vazia na coluna A
With rs
.AddNew 'criar um novo registro
' Adiciona comentarios a cada campo no registro

On Error Resume Next
.Fields("NOME_DO_CAMPO_1") = Range("A" & r).Comment.Text
.Fields("NOME_DO_CAMPO_2") = Range("B" & r).Comment.Text
.Fields("NOME_DO_CAMPO_3") = Range("C" & r).Comment.Text
  '  * Adicione mais campos, se necessário ...

.Update  ' armazena o novo registro
End With
r = r + 1 'proxima linha ...
On Error GoTo 0
Loop
rs.Close
Set rs = Nothing
cn.Close
Set cn = Nothing
End Sub