Excel Como ler arquivo .ini no vba excel

[Migguds]

Eu encontrei alguns exemplos de códigos para ler arquivos .ini no vba do excel, mais não consegui entender nenhum, algum poderia ajudar com um exemplo?

[Visitante]

Já tentou este ?

https://www.tomasvasquez.com.br/blog/microsoft-office/vba-lendo-um-arquivo-texto-linha-a-linha-sem-filesystemobject/

[Migguds]

Eu estou tentando ler um arquivo ini e preenche os valores em uma coluna...

Ao clicar no botão em G1, executa o script para ler o o arquivo relação.ini, e preenche os valores em F, exemplo no arquivo:

1 = vela

2= milha

etc

Então apos clicar ele preencheria em F tais valores, ficando assim:

 

Isso é possível?

 

 

@osvaldo eu já havia visto esse tópico, eu vi varios assim também em inglês, só que não consegui entender como configurar no meu botão, eu tentei por o codigo assim:

 

Anexei minha planilha, grato.

planilha.rar

[Migguds]

Alguem sabe dizer se é possivel? Já testei varios scripts que encontrei mais não conseguir fazer funcionar ainda.

[Basole]

@Migguds se o resutado desejado é esse (imagem) , segue seu codigo com as alteracoes: 

 

 

                                                   

 

Public Sub LeArquivoTexto()
    Dim Arquivo             As Integer
    Dim CaminhoArquivo      As String
    Dim TextoProximaLinha   As String
    Dim ContadorLinha       As Long
       
    'Configura a leitura do arquivo
     Arquivo = FreeFile
       CaminhoArquivo = "C:\Users\CAIO\Desktop\relação.ini"
  
        'Abre o arquivo para leitura
    Open CaminhoArquivo For Input As Arquivo
    ContadorLinha = 1
        'Lê o conteúdo do arquivo linha a linha
    With ActiveSheet
    
     .[F1:F14].ClearContents
     
    Do While Not EOF(Arquivo)
          Line Input #Arquivo, TextoProximaLinha
        
          If VBA.InStr(TextoProximaLinha, "[") = 0 Then
        
              .Cells(ContadorLinha, "F") = VBA.Right(TextoProximaLinha, (VBA.Len(TextoProximaLinha) - _
                                              VBA.InStr(TextoProximaLinha, "=")))
              ContadorLinha = ContadorLinha + 1
           End If
    Loop
     
    End With
   
    'Fecha o arquivo
    Close Arquivo
 
End Sub

 

[Migguds]

@Basole tem como editar o script para caso a linha esteja com valor vazio pular para proxima linha?

 

Exemplo:

No arquivo .ini:

5=

6=

 

5 e 6, estão vazios, se eu executar o script clicando no botão, ele vai apagar o F5 e F6 no excel que estão com valor "N EDITAR".

 

Teria como, caso não contenha nenhum valor após "="  pular para próxima linha no excel?

 

 

 

 

 

 

 

 

#####EDIT######

Consegui, segue o codigo:

Private Sub CommandButton1_Click()

Call LeArquivoTexto

End Sub


 
Public Sub LeArquivoTexto()
    Dim Arquivo             As Integer
    Dim CaminhoArquivo      As String
    Dim TextoProximaLinha   As String
    Dim ContadorLinha       As Long
       
    'Configura a leitura do arquivo
     Arquivo = FreeFile
       CaminhoArquivo = "C:\Users\CAIO\Desktop\relação.ini"
  
        'Abre o arquivo para leitura
    Open CaminhoArquivo For Input As Arquivo
    ContadorLinha = 1
        'Lê o conteúdo do arquivo linha a linha
    With ActiveSheet
    
     
    Do While Not EOF(Arquivo)
          Line Input #Arquivo, TextoProximaLinha
        
          If VBA.InStr(TextoProximaLinha, "[") = 0 Then
        
            .Cells(ContadorLinha, "F") = VBA.Right(TextoProximaLinha, (VBA.Len(TextoProximaLinha) - VBA.InStr(TextoProximaLinha, "=")))
              ContadorLinha = ContadorLinha + 1
                                
          Else

          ContadorLinha = ContadorLinha + 1
          End If
    Loop
     
    End With
   
    'Fecha o arquivo
    Close Arquivo
 
End Sub

 

[Basole]

@Migguds sim eu alterei para "puilar" linha para este caso.

 

Public Sub LeArquivoTexto()
    Dim Arquivo             As Integer
    Dim CaminhoArquivo      As String
    Dim TextoProximaLinha   As String
    Dim ContadorLinha       As Long
       
    'Configura a leitura do arquivo
     Arquivo = FreeFile
       CaminhoArquivo = ThisWorkbook.Path & "\relação.ini" ' "C:\Users\CAIO\Desktop\relação.ini"
  
        'Abre o arquivo para leitura
    Open CaminhoArquivo For Input As Arquivo
    ContadorLinha = 1
        'Lê o conteúdo do arquivo linha a linha
    With ActiveSheet
    
    Do While Not EOF(Arquivo)
          Line Input #Arquivo, TextoProximaLinha
        
          If VBA.InStr(TextoProximaLinha, "[") = 0 Then
            
             If VBA.Right(TextoProximaLinha, (VBA.Len(TextoProximaLinha) - _
                                              VBA.InStr(TextoProximaLinha, "="))) <> "" Then
        
                 .Cells(ContadorLinha, "F") = VBA.Right(TextoProximaLinha, (VBA.Len(TextoProximaLinha) - _
                                              VBA.InStr(TextoProximaLinha, "=")))
                     ContadorLinha = ContadorLinha + 1
             Else
                   ContadorLinha = ContadorLinha + 1
             End If
           End If
    Loop
     
    End With
   
    'Fecha o arquivo
    Close Arquivo
 
End Sub