Selecionar intervalo após condição

[Roliveira82]

Boa noite pessoal. Estou precisando de uma ajuda e sou novo no fórum. Conforme as linhas abaixo, preciso o intervalo, em linha, das colunas "B" (CÓD) até "E" (um) quando a condição achar o string "DIFERENÇA" e não a linha toda (.EntireRow.Copy). Daí eu pulo pra outra aba e colo valores na primeira linha vazia da coluna "B". Me desculpem se já existe um post como esse... Não achei!

 

Sub SEG_CONT()

'------ DECLARANDO VARIÁVEIS

Dim rng As Range
Dim i As Integer
Dim PrimLin As Integer

'------ SELECIONA ABA E INTERVALO

Sheets("MAR-2016").Select
Set rng = Range("I19:I300")

'------ INICIA A ROTINA DE BUSCA

For i = rng.Rows.Count To 1 Step -1

'------ SE A CÉLULA "I" FOR IGUAL A "DIFERENÇA", ENTÃO SELECIONAR EM LINHA AS CÉLULAS DA COLUNA "B" (cod) ATÉ "E" (UM)

If rng.Cells(i).Value = "DIFERENÇA" Then rng.Cells(i).EntireRow.Copy

'------ SELECIONA A ABA "DOCUMENTO DE CONTAGEM" E COLA VALORES BA PRIMEIRA LINHA VAZIA DA COLUNA "B"

Sheets("DOCUMENTO DE CONTAGEM").Select

PrimLin = Cells(Rows.Count, "B").End(xlUp).Row
Range("B" & PrimLin + 1).Select

Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Next
End Sub
 

[Visitante]

 

Olá, Oliveira.

 

Veja se este código atende.

 

Sub SegCont()
 Dim rng As Range
  With Sheets("MAR-2016")
   For Each rng In .Range("I2:I" & .Cells(Rows.Count, 9).End(3).Row)
    If rng.Value = "DIFERENÇA" Then
     Sheets("DOCUMENTO DE CONTAGEM").Cells(Rows.Count, 2).End(3)(2).Resize(, 4).Value = _
      .Cells(rng.Row, 2).Resize(, 4).Value
    End If
   Next rng
  End With
End Sub

 

[Roliveira82]

Perfeito!!! Muito obrigado oswaldomp!! Agora começarei a trabalhar com essa macro para poder pegar as "DIFERENÇAS" de dias específicos escolhidos na caixa de combinação!

 

 

valeu!!