VisualG Estrutura de repetição com caractér visualg

Iago Anjos · 16 de outubro de 2020

Bom dia gente, quero fazer uma expressao q repita o comando até o usuario botar determinada letra no Visualg

tipo, pra ele escolher entre M ou H, se ele colocar outra letra ou numero, quero dizer pra ele que o genero ta incorreto e fazer ele escrever de novo, mostrando a msg

:escreval("Digite seu gênero(M para mulher ou H para homem): ")

como vocês fariam?
Obrigado pela atenção!

Simon Viegas · 16 de outubro de 2020

Caro usuário,

Seja bem-vindo ao Clube do Hardware.

No intuito de servir como fonte de pesquisa no caso de instituições de ensino, informamos que incorrer no resolvimento por completo de questões relacionadas a disciplinas escolares de cursos técnicos e faculdades podem ser revistas e removidas pela Equipe de Moderação do Clube do Hardware.

Para sanar dúvidas sobre esse tipo de problema, por gentileza, publique o passo a passo do desenvolvimento da questão, projeto, monografia ou conteúdo em dúvida para que possamos analisar se a resposta está correta ou não, ou para que possa ser auxiliado com a dúvida no desenvolvimento do exercício.

Infelizmente, não há como resolver os trabalhos pelos usuários. O objetivo do Clube do Hardware é auxiliar seus usuários a encontrar soluções para que possam sanar suas dúvidas, e não de trazer soluções prontas para seus usuários. Além disso, copiar e colar respostas que não são de autoria própria do qualquer usuário é considerado plágio, o que é ilegal.

Esperamos que compreenda.

Atenciosamente,

Equipe Clube do Hardware

Iago Anjos · 16 de outubro de 2020

Me expressei errado.

Algoritmo "semnome"
// Disciplina   : [Linguagem e Lógica de Programação]
// Professor   : Antonio Carlos Nicolodi 
// Descrição   : Aqui você descreve o que o programa faz! (função)
// Autor(a)    : Nome do(a) aluno(a)
// Data atual  : 16/10/2020
Var
   nome,sexo:caracter
   salario,ticket,valor,total,media:real
   dias,contador:inteiro

Inicio
   escreval("----Sistemas Entretenimento---")

   contador<-1
   escreval("****************************")
   enquanto (contador<=500) faca
      escreva("Digite seu nome: ")
      leia(nome)
      escreval("Digite seu gênero(M para mulher ou H para homem):  ")
      leia(sexo)
      escreval("Digite seu salário em R$: ")
      leia(salario)
      escreval("Digite o dias trabalhados: ")
      leia(dias)

      se(sexo="h") e (salario>=1200)entao
         escreval("Você não tem direito ao plano de saúde")
      senao
         se(sexo="m") e (salario>=1500)entao
            escreval(nome," não tem direito ao plano de saúde")
         senao
            escreval(nome," tem direito ao plano de saúde")
         fimse
      fimse
        
      se(salario<=900)entao
         ticket<-15
      senao
         ticket<-10
      fimse
        
      valor<-(ticket)*(dias)
      escreval(nome," recebeu um total de ",valor,"R$ em tickets")
       
      total<-(total)+(valor)
      media<-(total)/(contador)
       
      contador<-contador+1
   fimenquanto
Fimalgoritmo

Eu quero só dar um algo a mais a meu código. Tentei fazer a estrutura de repetição com

Enquanto(sexo=nao(h)) e (sexo=nao(m)) faca
   escreval("Genero incorreto, tente de novo")
   escreval("Digite seu gênero(M para mulher ou H para homem):  ")
   leia(sexo)
fimenquanto

mas n funcionou

So quero saber como fazer a estrutura com caracteres, pode ser outro exemplo tb. Nao achei na net ainda

Simon Viegas · 16 de outubro de 2020

Tente algo como:

enquanto (sexo <> "h") e (sexo <> "m") faca
   escreval("Genero incorreto, tente de novo")
   escreval("Digite seu gênero (M para mulher ou H para homem):  ")
   leia(sexo)
fimEnquanto