VisualG Exercícios com Procedimentos e com Funções

[fergie]

1)Escrever um programa para ler tipo de ação a ser comercializada na bolsa de valores, preço de compra e o preço de venda de cada ação, calcule e escreva:  a. O lucro de cada ação; b. A quantidade de ações com lucro superior a R$ 1.000,00 c. A quantidade de ações com lucro inferior a R$ 200,00 d. O lucro total das ações; O final da entrada de dados é conhecido quando informado fim como tipo de ação.

 

2)Faça um programa que leia um número inteiro e gere todos os números primos entre 1 e este número fornecido, exibindo-os na tela. O programa deve ter uma sub-rotina função que recebe o número por parâmetro e determina se é ou não primo. Números primos são aqueles que são somente divisíveis por 1 ou por eles mesmos

 

3)Escreva um programa para definir um registro com nome e salário, criar um vetor do registro com 10 elementos, usando procedimentos e menu calcular e escrever. a. Leitura do vetor; b. Ordenação do vetor por nome; c. Mostrar o nome que tem o maior e menor salário; d. Media dos salários; e. Fim

[Simon Viegas]

Caro usuário,

 

Seja bem-vindo ao Clube do Hardware.

 

No intuito de servir como fonte de pesquisa no caso de instituições de ensino, informamos que incorrer no resolvimento por completo de questões relacionadas a disciplinas escolares de cursos técnicos e faculdades podem ser revistas e removidas pela Equipe de Moderação do Clube do Hardware.

 

Para sanar dúvidas sobre esse tipo de problema, por gentileza, publique o passo a passo do desenvolvimento da questão, projeto, monografia ou conteúdo em dúvida para que possamos analisar se a resposta está correta ou não, ou para que possa ser auxiliado com a dúvida no desenvolvimento do exercício.

 

Infelizmente, não há como resolver os trabalhos pelos usuários. O objetivo do Clube do Hardware é auxiliar seus usuários a encontrar soluções para que possam sanar suas dúvidas, e não de trazer soluções prontas para seus usuários. Além disso, copiar e colar respostas que não são de autoria própria do qualquer usuário é considerado plágio, o que é ilegal.

 

Esperamos que compreenda.

 

Atenciosamente,

Equipe Clube do Hardware

[fergie]

@Simon Viegas, na questão 3:
 

i: caractere
j: inteiro
media, salarioMAX, salarioMIN,totalsalarial: real
salario: vetor[1..10] de inteiro
nome:vetor[1..10] de caractere

Inicio
escreval("Nome do empregado:")
leia(nome[1])
escreval("Salário do empregado:")
leia(salario[1])
totalsalarial <- totalsalarial + salario[1]
se(salario[1]>salarioMAX) entao
salarioMAX <- salario[j]
fimse
salarioMIN<-salario[1]
Se(salario[i]<salarioMIN)entao
salarioMIN <- salario[1]
fimse
fimse
fimse
escreva("Media salarial")
escreval(media)
escreva("Maior salario")
escreval(salarioMAX)
escreva("Menor salario")
escreva(salarioMIN)
fimalgoritmo

 

Está dando errado, mas não sei o que.

[Simon Viegas]

@fergie, sugiro fazer os programas aos poucos... A medida que vai implementando, sempre deixando o código rodável. Você postou um código cheio de coisa, mas que sequer inicia, já que falta elementos básicas, como o cabeçalho.

 

 

Vou exemplificar se eu fosse tentar fazer o primeiro exercício:
 

3 horas atrás, fergie disse:

1)Escrever um programa para ler tipo de ação a ser comercializada na bolsa de valores, preço de compra e o preço de venda de cada ação, calcule e escreva:  a. O lucro de cada ação; b. A quantidade de ações com lucro superior a R$ 1.000,00 c. A quantidade de ações com lucro inferior a R$ 200,00 d. O lucro total das ações; O final da entrada de dados é conhecido quando informado fim como tipo de ação.

 

Exemplo de código inicial:

 

algoritmo "Exercício 01"
//1)Escrever um programa para ler tipo de ação a ser comercializada na bolsa
//de valores, preço de compra e o preço de venda de cada ação, calcule e
//escreva:  a. O lucro de cada ação; b. A quantidade de ações com lucro
//uperior a R$ 1.000,00 c. A quantidade de ações com lucro inferior a R$
//200,00 d. O lucro total das ações; O final da entrada de dados é conhecido
// quando informado fim como tipo de ação.
var
   tipoAcao: caractere
   precoCompra, precoVenda: real
   lucro: real
   qtdAcoesLucroSuperior1000: inteiro
   qtdAcoresLucroInferior200: inteiro
   lucroTotal: real
inicio
   escreva ("Tipo de ação   : ")
   leia(tipoAcao)
   escreva ("Preco de compra: ")
   leia(precoCompra)
   escreva ("Preco de venda : ")
   leia(precoVenda)
   
   escreval("")
   escreval("Tipo de ação   : ", tipoAcao)
   escreval("Preco de compra: R$ ", precoCompra:1:2)
   escreval("Preco de venda : R$ ", precoVenda:1:2)
fimAlgoritmo

 

 

Observe que só implementei uma leitura de dados e a exibição desses dados... apenas para testar se está lendo corretamente. 

 

Aí testa implementar mais alguma coisa. Ex.:calcular o lucro:

 

   ...
   escreva ("Preco de venda : ")
   leia(precoVenda)
   
   lucro <- precoVenda - precoCompra
   
   escreval("")
   escreval("Tipo de ação   : ", tipoAcao)
   escreval("Preco de compra: R$ ", precoCompra:1:2)
   escreval("Preco de venda : R$ ", precoVenda:1:2)
   escreval("Lucro          : R$ ", lucro:1:2)
   ...

 

 

 

Agora testar ler várias ações (inserir um laço de repetição):

 

algoritmo "Exercício 01"
//1)Escrever um programa para ler tipo de ação a ser comercializada na bolsa
//de valores, preço de compra e o preço de venda de cada ação, calcule e
//escreva:  a. O lucro de cada ação; b. A quantidade de ações com lucro
//uperior a R$ 1.000,00 c. A quantidade de ações com lucro inferior a R$
//200,00 d. O lucro total das ações; O final da entrada de dados é conhecido
// quando informado fim como tipo de ação.
var
   tipoAcao: caractere
   precoCompra, precoVenda: real
   lucro: real
   qtdAcoesLucroSuperior1000: inteiro
   qtdAcoresLucroInferior200: inteiro
   lucroTotal: real
inicio
   enquanto (tipoAcao <> "fim") faca
      escreva ("Tipo de ação   : ")
      leia(tipoAcao)
      escreva ("Preco de compra: ")
      leia(precoCompra)
      escreva ("Preco de venda : ")
      leia(precoVenda)

      lucro <- precoVenda - precoCompra

      escreval("")
      escreval("Tipo de ação   : ", tipoAcao)
      escreval("Preco de compra: R$ ", precoCompra:1:2)
      escreval("Preco de venda : R$ ", precoVenda:1:2)
      escreval("Lucro          : R$ ", lucro:1:2)
      escreval("")
      escreval("")
   fimEnquanto


fimAlgoritmo

 

 

 

Observe que não faz sentido ler e nem exibir o dados para quando for informado o tipo da ação "fim", ou seja: precisa corrigir isso. Daí não faz muito sentido tentar implementar um coisa nova, como tentar calcular "a quantidade de ações com lucro superior a R$ 1.000,00"... entende? Primeiro resolve esse problema... ao ler "fim" o programa NÃO deve ler os preço de compra e venda... 

 

Do código acima, pararia para entender o que está ocorrendo e tentaria implementar uma solução para o problema citado acima. Ex.:

 

algoritmo "Exercício 01"
//1)Escrever um programa para ler tipo de ação a ser comercializada na bolsa
//de valores, preço de compra e o preço de venda de cada ação, calcule e
//escreva:  a. O lucro de cada ação; b. A quantidade de ações com lucro
//uperior a R$ 1.000,00 c. A quantidade de ações com lucro inferior a R$
//200,00 d. O lucro total das ações; O final da entrada de dados é conhecido
// quando informado fim como tipo de ação.
var
   tipoAcao: caractere
   precoCompra, precoVenda: real
   lucro: real
   qtdAcoesLucroSuperior1000: inteiro
   qtdAcoresLucroInferior200: inteiro
   lucroTotal: real
inicio
   enquanto (tipoAcao <> "fim") faca
      escreva ("Tipo de ação   : ")
      leia(tipoAcao)

      se (tipoAcao <> "fim") entao
         escreva ("Preco de compra: ")
         leia(precoCompra)
         escreva ("Preco de venda : ")
         leia(precoVenda)

         lucro <- precoVenda - precoCompra

         escreval("")
         escreval("Tipo de ação   : ", tipoAcao)
         escreval("Preco de compra: R$ ", precoCompra:1:2)
         escreval("Preco de venda : R$ ", precoVenda:1:2)
         escreval("Lucro          : R$ ", lucro:1:2)
         escreval("")
         escreval("")
      fimSe
   fimEnquanto


fimAlgoritmo

 

Por aí vai.

 

Veja: não necessariamente o código precisa fica bom logo de início. O importante é simplesmente fazer rodar de alguma forma... 

 

Resumindo:
É isso... Sempre o que for fazendo, vá deixando funcionando... não tente fazer tudo de uma vez...

 

Escolha um dos exercício e tente fazer do início. Daí poste aqui o que conseguiu fazer e onde está com dúvidas.