Bat Bat para Ingressar e Remover PC no Domínio

[OJAUUM]

Isso, reiniciei e não estava no dominio...

Pronto, deu certo...

 

Eu adicionei 

fjoinoptions=3

após o 

call joindomainorWorkgroup

 

e inseriu no dominio

Obrigado pela ajuda e parabéns pelo script.

 

[ricardo_br]

@OJAUUM Legal, onde você achou essa opção de "fjoinoptions=3"?

[OJAUUM]

Opa, encontrei aqui:

https://community.spiceworks.com/topic/1072332-using-wmic-cmd-to-add-computer-to-domain-add-to-nested-ou

E também no site da documentação da microsoft algumas sintaxes:

https://docs.microsoft.com/pt-br/windows/win32/cimwin32prov/joindomainorworkgroup-method-in-class-win32-computersystem

 

e no forum da overflow:

https://stackoverflow.com/questions/63096295/use-wmic-to-join-domain-and-change-computer-name-simultaneously

[ricardo_br]

valeu, vou adicionar ao código então...

[Wilson Gomes]

Podem postar o bat completo?

Testei, mas funcionou pra remover do dominio, mas não renomeia.

Quando um funciona o outro não.

[ricardo_br]

@Wilson Gomes Lembrando que tem que reiniciar o computador para que faça efeito:

 

@echo off

net session >nul 2>&1 || (powershell start -verb runas '"%~0"' &exit /b)
for /f %%a in ('"prompt $H&for %%b in (1) do rem"') do set "BS=%%a"
mode con cols=80 lines=25
Title Adicionar ^| Remover Computador Dominio

chcp 1252 >nul
:MenuP
for /f "delims=" %%a in ('"wmic computersystem get domain,workgroup,PartofDomain /value"') do for /f "tokens=1,2 delims==" %%b in ("%%~a") do (
                                                                                                                                               IF /i "%%b"=="Domain" set "Dominio=%%c"
                                                                                                                                               IF /i "%%b"=="Workgroup" set "GrupoDeTrabalho=%%c"
                                                                                                                                               IF /i "%%b"=="PartOfDomain" (IF /i "%%c"=="TRUE" (set "TRede=Dominio") else (set "TRede=Grupo de Trabalho"))                                                                                                                                               
                                                                                                                                              )
:: Coloquei como teste para que reconheça como domínio yahoo.com porque não tenho domínio para testar
if /i "%GrupoDeTrabalho%"=="yahoo.com" set "TRede=Dominio"
IF /i "%TRede%"=="Dominio" (set "TRede=%TRede% (%Dominio%)") else (set "TRede=%TRede% (%GrupoDeTrabalho%)")
set Opcao=
cls
echo.
echo  Menu Principal  ^| PC: %Computername% ^| %TRede% 
echo  --------------
echo.
echo  O que gostaria de fazer?
echo.
echo  (A)dicionar ao Dominio
echo.
echo  (R)emover do Dominio
echo.
echo  (S)air
echo  -------------
echo.
set /p "Opcao=%BS% Escolha uma Opção: "
IF /I "%Opcao%"=="a" goto :MAdicionar
IF /I "%Opcao%"=="r" goto :MRemover
IF /i "%Opcao%"=="s" exit
pause

:MAdicionar
set Opcao=
set Usuario=
set Senha=
set NovoNome=
cls
echo.
set /p "Dominio=%BS% Especifique o novo Dominio: "
set /p "Usuario=%BS% Especifique um nome de usuário de Administrador de Dominio: "
set /p "Senha=%BS% Especifique a senha de Administrador de Dominio: "
set /p "Opcao=%BS% Deseja renomear o computador antes (s) (n)? "
IF /i "%Opcao%"=="s" set /p "NovoNome=%BS% Novo Nome: "
IF /i "%Opcao%"=="s" wmic computersystem where name="%ComputerName%" call rename name="%NovoNome%" 1>nul 2>nul
set Opcao=
wmic computersystem where name="%Computername%" call joindomainorWorkgroup fjoinoptions=3 name="%Dominio%" UserName="%Usuario%" Password="%Senha%" 1>nul 2>nul
echo.
echo  O computador precisa ser reiniciado para que as alterações tenham efeito!
set /p "Opcao=%BS% Reiniciar agora (s) (n)? "
IF /i "%Opcao%"=="s" shutdown -r -t 20
goto :MenuP

:MRemover
set Opcao=
set NovoNome=
set /p "Opcao=%BS% Deseja remover o computador: %Computername% de %TRede% (s) (n)? "
IF /i not "%Opcao%"=="s" goto :MenuP
set Opcao=
set /p "Opcao=%BS% Deseja renomear o computador antes (s) (n)? "
IF /i "%Opcao%"=="s" set /p "NovoNome=%BS% Novo Nome: "
IF /i "%Opcao%"=="s" wmic computersystem where name="%ComputerName%" call rename name="%NovoNome%" 1>nul 2>nul
wmic /interactive:off ComputerSystem Where "Name='%computername%'" Call UnJoinDomainOrWorkgroup FUnjoinOptions=0 1>nul 2>nul
echo.
set Opcao=
echo  O computador precisa ser reiniciado para que as alterações tenham efeito!
set /p "Opcao=%BS% Reiniciar agora (s) (n)? "
IF /i "%Opcao%"=="s" shutdown -r -t 20
goto :MenuP

 

[Wilson Gomes]

@ricardo_br  Sim. A linha:  IF /i "%Opcao%"=="s" shutdown -r -t 20, somente aguardo.

Vou testar esse último. Obrigado.

34 minutos atrás, Wilson Gomes disse:

@ricardo_br  Sim. A linha:  IF /i "%Opcao%"=="s" shutdown -r -t 20, somente aguardo.

Vou testar esse último. Obrigado.

 

Testei, insere mas não renomeia. Único que não funciona.

[ricardo_br]

@Wilson Gomes Tente isso, inverte essas linhas:

IF /i "%Opcao%"=="s" wmic computersystem where name="%ComputerName%" call rename name="%NovoNome%" 1>nul 2>nul
wmic /interactive:off ComputerSystem Where "Name='%computername%'" Call UnJoinDomainOrWorkgroup FUnjoinOptions=0 1>nul 2>nul

 

Deixando assim:

 

wmic /interactive:off ComputerSystem Where "Name='%computername%'" Call UnJoinDomainOrWorkgroup FUnjoinOptions=0 1>nul 2>nul
IF /i "%Opcao%"=="s" wmic computersystem where name="%ComputerName%" call rename name="%NovoNome%" 1>nul 2>nul

 

[Matheus Raniery]

@ricardo_brComigo já aconteceu o contrário! consigo renomear tranquilo mas não entra de jeito nenhum no domínio

[Matheus Raniery]

4 horas atrás, Matheus Raniery disse:

@ricardo_brComigo já aconteceu o contrário! consigo renomear tranquilo mas não entra de jeito nenhum no domínio

Deu certo agora! valeu guerreiro! 

[Martinelli_55]

Show de bola o Script, funcionou perfeitamente para ingressar e para remover, mas eu preciso que ele faça esse script em um range de IP porque tenho várias máquinas para jogar esse script, alguém poderia me ajudar acrescentando essa opção de range de IP pfv ?

 

[dineres]

@ricardo_br chefe boa noite tudo certo tentei usar seu script mesmo fazendo as alteração acima n deu se deixar o normal ele renomeia e se mudar ele só coloca no domínio mais se eu usar na aba :MRemover ele remove e renomeia 

[ricardo_br]

@dineresTentou reiniciar o computador para ver se depois de reiniciar ele renomeia?