Bat Alterar opções TaskScheduler via CMD

[Matheus Pimenta 97]

fiz um script via CMD/BAT para criação de tarefas o comando ficou assim:

 

schtasks /create /sc monthly /mo first /d mon /st 08:30 /rl highest /tn \FuncaoSaaS\Expurgo_Pastas_Backup_PRD /tr "C:\Sistemas\Util\Expurgo_Backup.bat" /ru %COMPUTERNAME%\JobService /rp 1234

 

Mas tem dois campos que não consegui alterar via linha de comando que são: "Hidden" e o "Configure for"

 

Vocês conseguem me dizer se é possível?

[ricardo_br]

@Matheus Pimenta 97 a versão do pormpt não tem essas opções incluidas (que eu saiba)

 

O que você tem que fazer é

Passo 1: Criar a tarefa sem "Oculto" e "Configurado para"

Passo 2: Pegar o arquivo de configuração XML da Tarefa

Passo 3: Modificar o arquivo XML para incluir "Oculto" e "Configurado para"

Passo 4: Apagar a tarefa que não tem "Oculto" e "Configurado para"

Passo 5: Criar uma nova tarefa com o arquivo XML modificado

 

 

@echo off

net session >nul 2>&1 || (powershell start -verb runas '"%~0"' &exit /b)

:: Defina aqui o "Configurar para:" ex: vista, 7, 10
set compatível=10

:: Dentro do arquivo XML o que determina a parte de "configurado para" é a versão na segunda linha:
:: Task version="1.2" = vista
:: Task version="1.3" = Windows 7
:: Task version="1.4" = Windows 10

if /i "%compatível%"=="vista" set "versão=1.2"
if /i "%compatível%"=="7" set "versão=1.3"
if /i "%compatível%"=="10" set "versão=1.4"

cd "%~dp0"

:: Passo 1 Criando a tarefa (sem Hidden ou Configurado para:)
schtasks /create /sc monthly /mo first /d mon /st 08:30 /rl highest /tn "\FuncaoSaaS\Expurgo_Pastas_Backup_PRD" /tr "C:\Sistemas\Util\Expurgo_Backup.bat" /ru %COMPUTERNAME%\JobService /rp 1234 /f

:: Passo 2 Salvando o arquivo XML:
schtasks /query /xml /tn "\FuncaoSaaS\Expurgo_Pastas_Backup_PRD">"tarefa1.xml"

:: Passo 3 Modificando o arquivo XML:
powershell -command "Get-Content .\tarefa1.xml | ForEach-Object {$_.replace('Task version=\"1.2\"', 'Task version=\"%versão%\"').replace('<Settings>', '<Settings>  <Hidden>true</Hidden>') } | Set-content .\tarefa2.xml"

:: Passo 4 apagando a primeira tarefa que não tem "Oculto" e "Configurado para":
schtasks /delete /f  /tn "\FuncaoSaaS\Expurgo_Pastas_Backup_PRD"

:: Passo 5 criando uma nova tarefa com o arquivo XML modificado:
schtasks /create /xml tarefa2.xml /tn "\FuncaoSaaS\Expurgo_Pastas_Backup_PRD"

:: apagar arquivos temporarios:
del /q tarefa1.xml
del /q tarefa2.xml  
exit