Bat Criar subpastas automaticamente ao criar uma pasta

[_Diego1985]

Olá!

 

Preciso de ajuda com um problema, necessito criar subpastas automaticamente ao criar uma pasta.

 

Exemplo:

- Possuo o diretório D:\Painéis\Orçamentos de Painéis\2022 

- Dentro de D:\Painéis\Orçamentos de Painéis\2022 tenho os clientes (ex.: Google, Microsoft, Amazon e etc)

- Dentro de cada pasta de cliente é criada uma pasta com a OS (ordem de serviço) conforme demanda. (ex.: D:\Painéis\Orçamentos de Painéis\2022\Google crio a pasta OS1458-22).

- Enfim, dentro dessas pastas que serão as OS, preciso criar de forma automática algumas subpastas (ex.: dentro de D:\Painéis\Orçamentos de Painéis\2022\Google\OS1458-22 criar as pastas DESENHOS, EMAIL, MEMORIAIS, ORÇAMENTO, PROPOSTAS e etc)

 

 

[kgin]

1 hora atrás, _Diego1985 disse:

- Dentro de cada pasta de cliente é criada uma pasta com a OS (ordem de serviço) conforme demanda. (ex.: D:\Painéis\Orçamentos de Painéis\2022\Google crio a pasta OS1458-22).

A pasta ordem de serviço vai ser criada automaticamente ou o batch vai ter que criá-la?

[ricardo_br]

Seria isso?

 

[_Diego1985]

Em 23/09/2022 às 15:05, kgin disse:

A pasta ordem de serviço vai ser criada automaticamente ou o batch vai ter que criá-la?

Olá! A OS será feita manualmente e dentro dela que seriam criadas as subpastas de forma automática como nosso amigo @ricardo_brfez.

 

Em 23/09/2022 às 17:48, ricardo_br disse:

Seria isso?

 

Exatamente isso.

[ricardo_br]

Você deve arrastar a pasta base que contem os arquivos OS##-#### para o bat, na parte de salvar o bat, vai em "Salvar como" e em codificação coloque: ANSI para que palavras como "ORÇAMENTO" funcionem corretamente...

 

@echo off
chcp 1252 >nul
:: Arraste a pasta base que contém as subpastas OS##-#### para este batch

pushd "%~1"
for /f "delims=" %%a in ('dir /b /s OS*-*') do md "%%a\DESENHOS" "%%a\EMAIL" "%%a\MEMORIAIS" "%%a\ORÇAMENTO" "%%a\PROPOSTAS"
popd
exit

 

[_Diego1985]

Em 28/09/2022 às 11:23, ricardo_br disse:

Você deve arrastar a pasta base que contem os arquivos OS##-#### para o bat, na parte de salvar o bat, vai em "Salvar como" e em codificação coloque: ANSI para que palavras como "ORÇAMENTO" funcionem corretamente...

 

@echo off
chcp 1252 >nul
:: Arraste a pasta base que contém as subpastas OS##-#### para este batch

pushd "%~1"
for /f "delims=" %%a in ('dir /b /s OS*-*') do md "%%a\DESENHOS" "%%a\EMAIL" "%%a\MEMORIAIS" "%%a\ORÇAMENTO" "%%a\PROPOSTAS"
popd
exit

 

@ricardo_brComo posso automatizar o processo de criar uma pasta juntamente como seu script?

Ex.: Irei criar a pasta os-789/22 dentro de Google, no momento que eu criar essa ou qualquer outra pasta dentro do diretório "X" já executar o script para que sejam criadas as subpastas.

[ricardo_br]

@_Diego1985 O ideal é colocar o caminho do batch dentro da variável path para que você possa executar o batch direto só digitando o nome dele no comando executar e ai já criar a pasta de dentro do batch não do Windows:

 

Salve o batch com codificação ANSI para os acentos funcionarem....

 

 

@echo off
chcp 1252 >nul
for /f %%a in ('"prompt $H&for %%b in (1) do rem"') do set "BS=%%a"

:: Informe a pasta onde ficam as empresas aqui:
set PBase=C:\Users\ricar\Desktop\Criar Pastas Automaticamente dentro de Subpastas especificas\Painéis\Orçamentos de Painéis\2022


echo  Informe Empresa e pasta os ex: Google\OS50-2003
echo.
set /p "PastaOS=%BS% Empresa\OS-##-####: "

if not exist "%PBase%\%PastaOS%" md "%PBase%\%PastaOS%"

if not exist "%PBase%\%PastaOS%" exit

pushd "%PBase%\%PastaOS%"
md "DESENHOS" "EMAIL" "MEMORIAIS" "ORÇAMENTO" "PROPOSTAS"
popd
exit

 

[_Diego1985]

@ricardo_bragradeço demais sua atenção e tempo para fazer os scripts e responder ao tópico, agora só faltou fazer com que ele execute o script de forma automática no windows server quando criar uma pasta dentro do diretório especifico. Obrigado!

[ricardo_br]

@_Diego1985 Então a ideia era já criar a pasta de dentro do bat ai ele já cria as pastas. Se não for assim teria que habilitar auditoria nas pastas e usar o Agendador de tarefas para disparar quando um "evento" de criação de pasta fosse acionado que vai executar o bat. Mais não consegui achar qual seria exatamente esse ID de evento.