Bat .BAT para renomear arquivos

[Iago Vitorio Castaldi]

Olá prezados, 

Possuo conhecimento básico sobre o assunto, e tenho a seguinte questão:

Meu sistema gera PDF,s das NFSE gerados no sistema, em um diretório específico (pasta do sistema) acontece que ele cria um PDF novo com o mesmo nome do arquivo passado o que causa a substituição do mesmo.

Gostaria de saber se é possível realizar um arquivo.bat ou alguma alternativa simples para que ao arquivo ser criado no diretório, o mesmo seja renomeado automaticamente, podendo ser com algum número a mais no final em ordem ou algo outro carácter.

[ricardo_br]

 

 

 

[Iago Vitorio Castaldi]

@ricardo_br não consigo abrir sua GIF kkkk

[ricardo_br]

O nome com que esse arquivo é salvo pelo sistema é sempre o mesmo? Qual seria?

[Iago Vitorio Castaldi]

@ricardo_br Na verdade muda a cada dia, não teria um "valor" fixo no nome. O problema é que em um dia fica apenas o último PDF salvo.

Os arquivos poderiam ser renomeados para uma sequência lógica, como: 1, 2 e assim vai 

[ricardo_br]

@Iago Vitorio Castaldi Esse bat renomeia os arquivos conforme a data em que foram criados:

 

@echo off

:: Especifique aqui a pasta onde ficam os PDFs:
set Pasta=%userprofile%\Desktop\PDFs

for /f "delims=" %%a in ('dir /s /b /tc "%Pasta%\*.pdf"') do call :Renomear "%%~a" "%%~ta" "%%~dpa" "%%~nxa"
exit

:Renomear
set "Arq1=%~1"
set "Data=%~2"
set "Nome1=%~4"
set "Nome2=%Data:~6,4%-%Data:~3,2%-%Data:~0,2% %Data:~11,2%%Data:~14,2%"
IF "%Nome1%"=="%Nome2%.pdf" goto :EOF
set Numero=1

:Repete
set /a Numero+=1
set NumeroZ=0%Numero%
set NumeroZ=%NumeroZ:~-2%
if exist "%~3%Nome2%.pdf" (if exist "%~3%Nome2%_%NumeroZ%.pdf" (goto :repete) else (ren "%Arq1%" "%Nome2%_%NumeroZ%.pdf")) else (ren "%Arq1%" "%Nome2%.pdf")
goto :EOF