Excel simplificar Macro VBA reduzindo repetições

[Jeff_Sandes]

Como simplificar esse trecho da macro? evitando repetições da mesma instrução

sub teste()
                [Z10].Value = "0": [Z10].AutoFill [Z10:Z59], xlFillSeries
                [A9].Value = "0": [A9].AutoFill [A9:AX9], xlFillSeries
                [AY1].Value = "0": [AY1].AutoFill [AY1:AY59], xlFillSeries
                [AZ9].Value = "0": [AZ9].AutoFill [AZ9:BW9], xlFillSeries
                [B7].Value = "00:00": [B7].AutoFill [B7:B31], xlFillSeries
                [BQ1].Value = "1": [BQ1].AutoFill [BQ1:BT1], xlFillSeries
end sub

tentei pegar uma ideia no ChatGPT, mas mesmo a IA não deu uma resposta boa

Sub FillSeriesAndTime()
    Dim Ranges As Variant
    Dim RowRange As Range
    Ranges = Array( _
        [Z10:Z59], [A9:AX9], [AY1:AY59], _
        [AZ9:BW9],[B7:B31], [BQ1:BT1])
    For Each RowRange In Ranges
        RowRange.Cells(1, 1).Value = "0"
        RowRange.Cells(1, 1).AutoFill RowRange, xlFillSeries
    Next RowRange
    [B7].Value = "00:00"
    [B7].AutoFill [B7:B31], xlFillSeries
    [BQ1].Value = "1"
    [BQ1].AutoFill [BQ1:BT1], xlFillSeries
End Sub

 

achei interessante o uso de array, assim posso apenas alterar os elementos dentro da array, mas assim não funcionou, a variável 'RowRange' recebe o valor Nothing

[Midori]

@Jeff_Sandes Como tem mais de um valor ou referência para cada preenchimento você pode usar um array de arrays. Assim é só fazer um loop e ir pegando cada elemento,

 

Sub Preenche()
    Dim Matriz      As Variant
    Dim Elemento    As Variant
    
    Matriz = Array( _
        Array("0", [Z10:Z59]), _
        Array("0", [A9:AX9]), _
        Array("0", [AY1:AY59]), _
        Array("0", [AZ9:BW9]), _
        Array("00:00", [B7:B31]), _
        Array("1", [BQ1:BT1]) _
    )
    
    For Each Elemento In Matriz
        Elemento(1).Cells(1).Value = Elemento(0)
        Call Elemento(1).Cells(1).AutoFill(Elemento(1), xlFillSeries)
    Next Elemento
End Sub

 

[Jeff_Sandes]

@Midori funcionou perfeitamente