Excel Contar linhas entre determinadas palavras no excel

[Janilson Brito]

Poderiam me ajudar?
Preciso fazer a contagem no excel entre uma linha e outra

toda linha onde preciso inserir a contagem começa com a palavra SCHEDULE

anexei uma planilha como modelo.
EX: na A1 tenho a palavra SCHEDULE abaixo dele na A2 tenho uma linha
então na B1 (a frente da linha onde tenho a palavra SCHEDULE) teria um total de 01

entre a A32 e a A40 eu teria um total de 07

modelo contar entre linhas.xlsx

[Scofieldgyn]

@Janilson Brito Infelizmente o Excel ainda não possui uma função acumulador pra realizar uma contagem dessa complexidade via fórmula, mas é possível fazer uma coluna auxiliar para que se consiga contar.

 

Na [B1] cole a fórmula =SE(ÉERROS(PROCURAR("SCHEDULE";A1));0;1) e arraste até o final.

na [C1] cole a fórmula =SE(B1=1;CORRESP(1;DESLOC(B1;1;0;98-LIN());0)-1;"")

 

pronto, conseguirá o resultado esperado.

 

a outra forma de resolver via VBA também, caso necessite, avisa.

[Janilson Brito]

@Scofieldgyn obrigado pela ajuda, e como ficaria na forma de VBA? vou tentar ver como fica com a formula, tenho receio de ficar muito pesado, pois minha planilha tem mais de 50.000 linhas

 

[Scofieldgyn]

@Janilson Brito

crie um módulo e cole o código abaixo.

depois é só executar ALT+F8

 

Sub ContarLinhasEntreSchedules()
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets("Planilha2")

    Dim lastRow As Long
    lastRow = ws.Cells(ws.Rows.count, "A").End(xlUp).Row

    Dim i As Long
    i = 1

    Do While i <= lastRow
        If InStr(1, ws.Cells(i, 1).Value, "SCHEDULE", vbTextCompare) > 0 Then
            Dim count As Long
            count = 0
            Dim j As Long
            j = i + 1
            Do While j <= lastRow And InStr(1, ws.Cells(j, 1).Value, "SCHEDULE", vbTextCompare) = 0
                count = count + 1
                j = j + 1
            Loop
            ws.Cells(i, 2).Value = count
        End If
        i = i + 1
    Loop

    MsgBox "Contagem concluída!", vbInformation
End Sub

 

[Janilson Brito]

@Scofieldgyn muito obrigado pela sua ajuda, ficou perfeito e exatamente como eu precisava.