Excel VBA - Criar MsgBox que desaparece automaticamente

[AfonsoMira]

Boas,

Estou com alguns problemas para conseguir criar um Msgbox que feche automaticamente, e caso eu clique em um botão ele cancela a macro.

 

A intenção é ao aparecer a MsgBox se a pessoa clicar em OK ele não fecha o ficheiro, mas caso a pessoa não clique, a Msgbox desaparece e fecha o ficheiro.

 

Isso é possível ?

Obrigado.

[Midori]

@AfonsoMira Acho mais fácil usar um UserForm em vez de tentar com Msgbox. Assim você pode usar OnTime em Initialize para chamar uma Sub que fecha a planilha caso o botão não seja acionado.

[Muca Costa]

Tente assim:

 

Sub MessageBoxTimer()
    Dim AckTime As Integer, InfoBox As Object
    Set InfoBox = CreateObject("WScript.Shell")
    'Configure a caixa de mensagem para fechar após 10 segundos
    AckTime = 10
    Select Case InfoBox.Popup("Click OK (Se não clicar em OK, a planilha janela fecha automaticamente após 10 segundos).", _
    AckTime, "© Muca Sistemas - 2021", 0)
        Case 1
            Exit Sub
        Case -1
            Application.ThisWorkbook.Save
            Application.Quit
    End Select
End Sub

 

[AfonsoMira]

Boas @Muca Costa ,

Seria quase isso, mas não me está a fechar automaticamente após os 10 segundos.

[AfonsoMira]

Consegui utilizando o seguinte código:

 

Private Declare PtrSafe Function MsgBoxTimeout _
        Lib "user32" _
        Alias "MessageBoxTimeoutA" ( _
            ByVal hwnd As LongPtr, _
            ByVal lpText As String, _
            ByVal lpCaption As String, _
            ByVal wType As VbMsgBoxStyle, _
            ByVal wlange As Long, _
            ByVal dwTimeout As Long) _
    As Long
Sub btnMsgbox()
     
     Select Case MsgBoxTimeout(0, "Deseja continuar a utilizar o ficheiro ?", "Fechar Automaticamente", vbInformation + vbYesNo, 0, 5000)
     
     Case 6
        MsgBox "Não Fecha"
     Case Else
        MsgBox "Fecha"
     End Select
     
End Sub