VisualG Aplicar desconto no valor final

ecampos2018 · 24 de novembro de 2017

Boa tarde galera. Estou com dificuldade em 2 situações no código abaixo.

1-Gostaria que o valor da hora trabalhada já aparecesse automaticamente e não que fosse preciso digitar o valor.

2-Aplicar um desconto no valor final do serviço.

Algoritmo "centro automotivo"
Var

  a,b,opcao,op:inteiro
  c,d, soma: inteiro
  desconto: inteiro

//---------------------------------------------------------------------
procedimento menu_principal
  Inicio //menu principal
    limpatela
    escreval ("CENTRO AUTOMOTIVO")
    escreval("Informe a opção de reparo")
    escreval ("1 - Motor")
    escreval ("2 - Suspensão")
    escreval ("3 - Freio")
    escreval ("4 - sair")
    escreva("=> ")
Fimprocedimento

//---------------------------------------------------------------------
//funcao da opcao 1
procedimento menu_motor
inicio
  limpatela
  escreval ("Opcao informada: MOTOR")
  escreval ("1- Alto consumo de óleo lubrificante")
  escreval ("2- Excesso de fumaça sendo expelida pelo escapamento")
  escreval ("3- Baixa potência")
  escreval ("4- Voltar")
  escreval ("Selecione o problema relatado pelo cliente")
  escreva("=> ")
fimprocedimento
//----------------------------------------------------------------------
//funcao da opcao 2
procedimento menu_suspensao
inicio
  limpatela
  escreval ("Opcao Suspensão")
  escreval ("1- Ruidos  e batidas nas rodas")
  escreval ("2- Vibrações e direção puxando")
  escreval ("3- Desgaste irregular dos pneus")
  escreval ("4- Voltar")
  escreval ("Selecione uma opção")
  escreva("=> ")
fimprocedimento
//---------------------------------------------------------------------
// funcao opcao 3
procedimento menu_freio
inicio
  limpatela
  escreval ("Opcao Freio")
  escreval ("1- Carro ou pedal vibrando ao pisar no pedal do freio")
  escreval ("2- O carro puxa para algum lado quando freia")
  escreval ("3- Chiado ou ronco quando pisa no freio")
  escreval ("4- Voltar")
  escreval ("Selecione uma opção")
  escreva("=> ")
fimprocedimento
//---------------------------------------------------------------------

//---------------------------------------------------------------------
procedimento alto_consumo //Motor
inicio
      escreval("Problema informado: Alto consumo")
      escreval("Custo por Hora/Atividade R$ 100,00")
      escreval("Informe o valor da hora:")
      leia (c)
      escreval("Quantidade de horas utilizadas no serviço:")
      leia (d)
      escreval("Valor total dos serviços R$",c*d)
      escreval("Tecle Enter")
leia(a)
fimprocedimento
//---------------------------------------------------------------------
procedimento excesso_de_fumaca // Motor
inicio
      escreval("Problema informado: Excesso de fumaça")
      escreval("Custo por Hora/Atividade R$ 100,00")
      escreval("Informe o valor da hora:")
      leia (c)
      escreval("Quantidade de horas utilizadas no serviço:")
      leia (d)
      escreval("Valor total dos serviços R$",c*d)
      escreval("Tecle Enter")
leia(a)
fimprocedimento
//---------------------------------------------------------------------
procedimento baixa_potencia //Motor
inicio
      escreval("Problema informado: Baixa potência do motor")
      escreval("Custo por Hora/Atividade: R$ 100,00")
      escreval("Informe o valor da hora:")
      leia (c)
      escreval("Quantidade de horas utilizadas no serviço:")
      leia (d)
      escreval("Valor total dos serviços R$",c*d)
      escreval("Tecle Enter")
leia(a)
fimprocedimento
//---------------------------------------------------------------------
procedimento ruidos_e_batidas_nas_rodas //Suspensão
inicio
      escreval("Problema informado: Ruidos e batidas nas rodas")
      escreval("Custo por Hora/Atividade: R$ 200,00")
      escreval("Informe o valor da hora:")
      leia (b)
      escreval("Quantidade de horas utilizadas no serviço: ")
      leia (d)
      escreval("Valor total dos serviços R$",b*d)
      escreval("Tecle Enter")
leia(a)
fimprocedimento
//---------------------------------------------------------------------
procedimento Vibracoes_e_direcao_puxando //Suspensão
inicio
      escreval("Problema informado: Vibrações e Direção puxando")
      escreval("Custo por Hora/Atividade: R$ 200,00")
      escreval("Informe o valor da hora:")
      leia (b)
      escreval("Quantidade de horas utilizadas no serviço: ")
      leia (d)
      escreval("Valor total dos serviços R$",b*d)
      escreval("Tecle Enter")
leia(a)
fimprocedimento
//---------------------------------------------------------------------
procedimento desgaste_irregular_dos_peneus //Suspensão
inicio
      escreval("Problema informado: Pneus desgastando de forma irregular")
      escreval("Custo por Hora/Atividade: R$ 200,00")
      escreval("Informe o valor da hora:")
      leia (b)
      escreval("Quantidade de horas utilizadas no serviço: ")
      leia (d)
      escreval("Valor total dos serviços R$",b*d)
      escreval("Tecle Enter")
leia(a)
fimprocedimento
//---------------------------------------------------------------------
procedimento carro_ou_pedal_vibra_ao_pisar //Freio
inicio
      escreval("Problema informado: Carro ou pedal vibrando ao pisar no freio")
      escreval("Custo por Hora/Atividade: R$ 300,00")
      escreval("Informe o valor da hora:")
      leia (b)
      escreval("Quantidade de horas utilizadas no serviço: ")
      leia (d)
      escreval("Valor total dos serviços R$",b*d)
      escreval("Tecle Enter")
  leia(a)
fimprocedimento
//---------------------------------------------------------------------
procedimento carro_puxa_para_algum_lado //Freio
inicio
  escreval("Problema informado: Veículo com tendencia de saída para os lados")
      escreval("Custo por Hora/Atividade: R$ 300,00")
      escreval("Informe o valor da hora:")
      leia (b)
      escreval("Quantidade de horas utilizadas no serviço: ")
      leia (d)
      escreval("Valor total dos serviços R$",b*d)
      escreval("Tecle Enter")
  leia(a)
fimprocedimento
//---------------------------------------------------------------------
procedimento Chiado_ou_ronco_quando_pisa //Freio
inicio
  escreval("Problema informado: Chiado ou ronco ao acionar pedal do freio")
      escreval("Custo por Hora/Atividade: R$ 300,00")
      escreval("Informe o valor da hora:")
      leia (b)
      escreval("Quantidade de horas utilizadas no serviço: ")
      leia (d)
      escreval("Valor total dos serviços R$",b*d)
      escreval("Tecle Enter")
  leia(a)
fimprocedimento
//---------------------------------------------------------------------
Inicio
repita
  menu_principal
  leia(Opcao)
  limpatela
  escolha opcao
    caso 1
      repita
        menu_motor
        leia(op)
        escolha op
          caso 1
            alto_consumo
          caso 2
            excesso_de_fumaca
          caso 3
            baixa_potencia
          caso 4
            escreval("voltando . . .    Tecle Enter")
            leia(a)
        fimescolha
      ate op=4
    caso 2
      repita
        menu_suspensao
        leia(op)
        escolha op
          caso 1
            Ruidos_e_batidas_nas_rodas
          caso 2
            Vibracoes_e_direcao_puxando
          caso 3
            desgaste_irregular_dos_peneus
          caso 4
            escreval("voltando . . .    Tecle Enter")
            leia(a)
        fimescolha
      ate op=4
    caso 3
      repita
        menu_freio
        leia(op)
        escolha op
          caso 1
            carro_ou_pedal_vibra_ao_pisar
          caso 2
            carro_puxa_para_algum_lado
          caso 3
            Chiado_ou_ronco_quando_pisa
          caso 4
            escreval("voltando . . .    Tecle Enter")
            leia(a)
        fimescolha
      ate op=4
    caso 4
      escreval("você pediu para sair, saindo . . . !")
  fimescolha
ate opcao=4
Fimalgoritmo

devair1010 · 26 de novembro de 2017

@ecampos2018 seu código está funcionando bem , para que dê desconto no final, precisa colocar as formulas para fazer o calculo, então seu código com algumas modificações ficaria assim :

Algoritmo "centro automotivo"
Var

  a,b,opcao,op : inteiro
  c,d,soma,cont: inteiro
  desconto     : inteiro
  servicos     : vetor[0..100,0..2] de caractere
//---------------------------------------------------------------------
procedimento menu_principal
  Inicio //menu principal
    limpatela
    escreval ("CENTRO AUTOMOTIVO")
    escreval("Informe a opção de reparo")
    escreval ("1 - Motor")
    escreval ("2 - Suspensão")
    escreval ("3 - Freio")
    escreval ("4 - Mostrar Orçamento")
    escreval ("5 - sair")
    escreva("=> ")
Fimprocedimento

//---------------------------------------------------------------------
//funcao da opcao 1
procedimento menu_motor
inicio
  limpatela
  escreval ("Opcao informada: MOTOR")
  escreval ("1- Alto consumo de óleo lubrificante")
  escreval ("2- Excesso de fumaça sendo expelida pelo escapamento")
  escreval ("3- Baixa potência")
  escreval ("4- Voltar")
  escreval ("Selecione o problema relatado pelo cliente")
  escreva("=> ")
fimprocedimento
//----------------------------------------------------------------------
//funcao da opcao 2
procedimento menu_suspensao
inicio
  limpatela
  escreval ("Opcao Suspensão")
  escreval ("1- Ruidos  e batidas nas rodas")
  escreval ("2- Vibrações e direção puxando")
  escreval ("3- Desgaste irregular dos pneus")
  escreval ("4- Voltar")
  escreval ("Selecione uma opção")
  escreva("=> ")
fimprocedimento
//---------------------------------------------------------------------
// funcao opcao 3
procedimento menu_freio
inicio
  limpatela
  escreval ("Opcao Freio")
  escreval ("1- Carro ou pedal vibrando ao pisar no pedal do freio")
  escreval ("2- O carro puxa para algum lado quando freia")
  escreval ("3- Chiado ou ronco quando pisa no freio")
  escreval ("4- Voltar")
  escreval ("Selecione uma opção")
  escreva("=> ")
fimprocedimento
//---------------------------------------------------------------------

//---------------------------------------------------------------------
procedimento alto_consumo //Motor
inicio
      escreval("Problema informado: Alto consumo")
      escreval("Custo por Hora/Atividade R$ 100,00")
      c:=100
      servicos[cont,1] := "Alto Consumo"
      Le_horas
fimprocedimento
//---------------------------------------------------------------------
procedimento excesso_de_fumaca // Motor
inicio
      escreval("Problema informado: Excesso de fumaça")
      escreval("Custo por Hora/Atividade R$ 100,00")
      c:=100
      servicos[cont,1] := "Excesso De Fumaça"
      Le_horas
fimprocedimento
//---------------------------------------------------------------------
procedimento baixa_potencia //Motor
inicio
      escreval("Problema informado: Baixa potência do motor")
      escreval("Custo por Hora/Atividade: R$ 100,00")
      c:=100
      servicos[cont,1] := "Baixa Potencia Do Motor"
      Le_horas
fimprocedimento
//---------------------------------------------------------------------
procedimento ruidos_e_batidas_nas_rodas //Suspensão
inicio
      escreval("Problema informado: Ruidos e batidas nas rodas")
      escreval("Custo por Hora/Atividade: R$ 200,00")
      c:=200
      servicos[cont,1] := "Ruidos e Batidas Nas Rodas"
      Le_horas
fimprocedimento
//---------------------------------------------------------------------
procedimento Vibracoes_e_direcao_puxando //Suspensão
inicio
      escreval("Problema informado: Vibrações e Direção puxando")
      escreval("Custo por Hora/Atividade: R$ 200,00")
      c:=200
      servicos[cont,1] := "Vibração e Direção Puxando"
      Le_horas
fimprocedimento
//---------------------------------------------------------------------
procedimento desgaste_irregular_dos_peneus //Suspensão
inicio
      escreval("Problema informado: Pneus desgastando de forma irregular")
      escreval("Custo por Hora/Atividade: R$ 200,00")
      c:=200
      servicos[cont,1] := "Peneus DesgastandoDe Forma Irregular"
      Le_horas
fimprocedimento
//---------------------------------------------------------------------
procedimento carro_ou_pedal_vibra_ao_pisar //Freio
inicio
      escreval("Problema informado: Carro ou pedal vibrando ao pisar no freio")
      escreval("Custo por Hora/Atividade: R$ 300,00")
      c:=300
      servicos[cont,1] := "Carro Ou Pedal Vibrando Ao Pisar No Freio"
      Le_horas
fimprocedimento
//---------------------------------------------------------------------
procedimento carro_puxa_para_algum_lado //Freio
inicio
  escreval("Problema informado: Veículo com tendencia de saída para os lados")
      escreval("Custo por Hora/Atividade: R$ 300,00")
      c:=300
      servicos[cont,1] := "Veiculo Com Tendencia De Saída Para Os Lados"
      Le_horas
fimprocedimento
//---------------------------------------------------------------------
procedimento Chiado_ou_ronco_quando_pisa //Freio
inicio
  escreval("Problema informado: Chiado ou ronco ao acionar pedal do freio")
      escreval("Custo por Hora/Atividade: R$ 300,00")
      c:=300
      servicos[cont,1] := "Chiado Ou Ronco Ao Acionar Pedal Do Freio"
      Le_horas
fimprocedimento
//---------------------------------------------------------------------
procedimento Le_horas
inicio
  escreval("Quantidade de horas utilizadas no serviço: ")
  leia (d)
  escreval("Valor total dos serviços R$",c*d)
  servicos[cont,2] := numpcarac(c*d)
  cont := cont+1
  escreval("Tecle Enter")
  leia(a)
fimprocedimento
//---------------------------------------------------------------------
procedimento orcamento
var
  i   : inteiro
  v,u : real
inicio
  escreval("----  Aqui Estâo Os Serviços Já Anotados  ---")
  para i de 0 ate cont-1 faca
    escreval(i+1," - ",servicos[i,1],"  -> R$ ",servicos[i,2])
    v := v + caracpnum(servicos[i,2])
  fimpara
  se v > 100 ENTÃO
    u:=v*10/100
    escreval("total dos serviços --------> R$",v)
    escreval("Desconto de 10 por cento --> R$",u)
    v := v - u
  fimse
  escreval("Total Geral Dos Serviços --> R$",v)
  escreval
  escreval("     Tecle")
  leia(a)
fimprocedimento
Inicio
repita
  menu_principal
  leia(Opcao)
  limpatela
  escolha opcao
    caso 1
      repita
        menu_motor
        leia(op)
        escolha op
          caso 1
            alto_consumo
          caso 2
            excesso_de_fumaca
          caso 3
            baixa_potencia
          caso 4
            escreval("voltando . . .    Tecle Enter")
            leia(a)
        fimescolha
      ate op=4
    caso 2
      repita
        menu_suspensao
        leia(op)
        escolha op
          caso 1
            Ruidos_e_batidas_nas_rodas
          caso 2
            Vibracoes_e_direcao_puxando
          caso 3
            desgaste_irregular_dos_peneus
          caso 4
            escreval("voltando . . .    Tecle Enter")
            leia(a)
        fimescolha
      ate op=4
    caso 3
      repita
        menu_freio
        leia(op)
        escolha op
          caso 1
            carro_ou_pedal_vibra_ao_pisar
          caso 2
            carro_puxa_para_algum_lado
          caso 3
            Chiado_ou_ronco_quando_pisa
          caso 4
            escreval("voltando . . .    Tecle Enter")
            leia(a)
        fimescolha
      ate op=4
    caso 4
      orcamento
    caso 5
      escreval("você pediu para sair, saindo . . . !")
  fimescolha
  se cont >100 ENTÃO
    escreval("Já Tem 100 Serviços Contratados, Só Pode Esses")
    opcao:=4
  fimse
ate opcao=5
Fimalgoritmo