Ir ao conteúdo

VisualG Erro: Invalid floating point operation


Ir à solução Resolvido por Simon Viegas,

Posts recomendados

Postado

Galera, boa noite estou com um probleminha , está dando o seguinte erro quando utilizo 0 como finalizador no visualg:

 

 

2.png.fabf1dce418dddd60e044b7cb46a0aef.png

 

 

algoritmo "semnome"
   // Função :
   // Autor :
   // Data : 09/11/2018
   // Seção de Declarações
var

   n, qtn, s, p, qtp, sp: inteiro
   mde: real

inicio

   n   <- 0
   qtn <- 0
   s   <- 0
   p   <- 0
   qtp <- 0
   sp  <- 0
   mde <- 0


   // Seção de Comandos
   
   escreva ("Por favor digite o primeiro número ou 0 para finalizar:")
   leia (n)
   se (n = 0)  entao
      escreval ("Algortmo finalizado sem calculos...")
   senao
   repita
   qtn <- qtn+1
   escreva ("Digite o Próximo número ou 0 para finalizar: ")
   leia (n)
      se (n = 0) entao
         escreval ("Algoritmo finalizado, veja: ")
         s <- s+n
         se (n > 0) entao
         qtp <- qtp+1
         p <- n
         sp <- sp+p
      fimse
     fimse
   ate (n = 0)
   fimse
   mde <- sp/qtp
   escreva ("A quantidade de números digitados foi: ")
   escreva ("A Soma dos números digitados foi: ",s)
   se (mde < 0 ) entao
      escreva ("Você não digitou números positivos.")
   senao
      escreva ("A média de números positivos digitados foi: ",mde)
   fimse
fimalgoritmo

 

  • Membro VIP
  • Solução
Postado

@brunord2014, é necessário revisar toda a estrutura do código. Segue um código exemplo:

algoritmo "FCdH"
// Autor : Bruno
// Data  : 09/11/2018
// Descrição:

//Programa que recebe diversos número inteiros e retorna quantos número foram
//digitados, a soma desses números e a média dos números positivos.
var
   n   :inteiro //número digitado pelo usuário
   qtn :inteiro //quantidade de número digitados
   s   :inteiro //soma dos números digitados

   qtp :inteiro //quantidade de número positivos
   sp  :inteiro //soma dos números positivos
   mdp :real    //media dos número positivos
inicio
n   <- 0
qtn <- 0
s   <- 0
qtp <- 0
sp  <- 0
mdp <- 0
escreva("Por favor digite o primeiro número ou 0 para finalizar:")
leia(n)
se (n = 0)  entao
   escreval("Algortmo finalizado sem calculos...")
senao
   repita
      qtn <- qtn+1    //atualiza a quantidade de números digitados
      s   <- s+n      //atualiza a soma dos números
      se (n > 0) entao //se for positivo
         qtp <- qtp+1 //atualiza a qnt de número positivos
         sp  <- sp+n  //atualiza soma dos positivos
      fimSe
      escreval("Digite o próximo número ou 0 para finalizar: ")
      leia(n)
   ate (n = 0) //se for quer finalizar
   escreval()
   escreval("A quantidade de números digitados foi     : ",qtn)
   escreval("A soma dos números digitados foi          : ",s)
   se (qtp = 0 ) entao
      escreval("Você não digitou números positivos.")
   senao
      mdp <- sp/qtp //calcula média dos positivos
      escreval("A média de números positivos digitados foi: ",mdp)
   fimse
fimSe
fimAlgoritmo

 

 

Se tiver com dúvidas sobre alguma parte, é só postar.

 

No aguardo.

Crie uma conta ou entre para comentar

Você precisa ser um usuário para fazer um comentário

Criar uma conta

Crie uma nova conta em nossa comunidade. É fácil!

Crie uma nova conta

Entrar

Já tem uma conta? Faça o login.

Entrar agora

Sobre o Clube do Hardware

No ar desde 1996, o Clube do Hardware é uma das maiores, mais antigas e mais respeitadas comunidades sobre tecnologia do Brasil. Leia mais

Direitos autorais

Não permitimos a cópia ou reprodução do conteúdo do nosso site, fórum, newsletters e redes sociais, mesmo citando-se a fonte. Leia mais

×
×
  • Criar novo...

LANÇAMENTO!

eletronica2025-popup.jpg


CLIQUE AQUI E BAIXE AGORA MESMO!