Excel Enviar dados de uma planilha para outra

[lucas.sns]

Olá, estou montando um sistema de gestão pra lojinha da minha mãe, só estou perguntado diretamente por aqui porque meu conhecimento em Excel é básico e realmente não sei nem como pesquisar isso na internet. Não sei qual o grau de complexidade disso, se for o caso aceito links de tutoriais, videos etc... Desde já agradeço quem puder ajudar.

 

Na aba "PDV" digito os códigos e obtenho as informações da aba "PRODUTOS".

 

Preciso que quando apertar o botão "INICIAR" os dados de determinadas células da aba "PDV" sejam apagados, pra ressetar planilha. Quando apertar "FINALIZAR" alguns dados sejam enviados, em suas respectivas colunas, para a sequência de uma tabela na aba "01".

 

Um detalhe é que as informações devem ir para a aba "01" se estivermos em janeiro.. Em fevereiro devem ir para a aba "02" e assim em diante. 

 

 

[Visitante]

8 horas atrás, lucas.sns disse:

Preciso que quando apertar o botão "INICIAR" os dados de determinadas células da aba "PDV" sejam apagados,...

Informe com exatidão quais são as células.

 

Quando apertar "FINALIZAR" alguns dados sejam enviados, em suas respectivas colunas, para a sequência de uma tabela na aba "01".

Informe com exatidão quais dados de quais colunas.

 

Um detalhe é que as informações devem ir para a aba "01" se estivermos em janeiro.. Em fevereiro devem ir para a aba "02" e assim em diante.

Disponibilize uma amostra do seu arquivo Excel (prints, figuras, imagens, fotos, ... não servem) com somente as planilhas envolvidas no processo desejado e com as planilhas destino dos dados de 01 a 04. Coloque alguns dados (4 a 5 linhas) e coloque o resultado desejado com as explicações na própria planilha de como obteve os resultados.

 

 

 

 

[lucas.sns]

15 horas atrás, osvaldomp disse:

 

Boa noite, obrigado pela resposta. Segue planilha com as explicações... Se por gentileza puder dar uma olhada.

 

Caso eu tinha sido meio redundante nas explicações, é bem simples:

Botão iniciar:

- Apaga todos dados das células em azul.

Botão Finalizar:

-Envia os dados conforme tabela de correspondências.

-Subtrai os itens listados do estoque.

-Exibe mensagem "Venda Concluída".

 

Obrigado pela atenção

LJ.xlsx

[Visitante]

Veja se entendi corretamente.

Vincule o código LimpaPDV ao botão INICIAR VENDA e vincule o código ReplicaVenda ao botão FINALIZAR VENDA.

 

Sub LimpaPDV()
 Range("R2:T3,Y2:AD3,B7,O7,Y7").Value = ""
 If [B10] <> "" Then Range("B10:B" & Cells(Rows.Count, 2).End(3).Row).Value = ""
 If [Y10] <> "" Then Range("Y10:Y" & Cells(Rows.Count, 25).End(3).Row).Value = ""
End Sub

Sub ReplicaVenda()
 Dim x As Long, LR As Long, codO As Range, codD As Long
  x = Cells(Rows.Count, 2).End(3).Row - 9
  If x < 1 Then Exit Sub
  'baixa no estoque
  For Each codO In Range("B10:B" & Cells(Rows.Count, 2).End(3).Row)
   codD = Sheets("ESTOQUE").[B:B].Find(codO.Value, lookat:=xlWhole).Row
   Sheets("ESTOQUE").Cells(codD, 17).Value = Sheets("ESTOQUE").Cells(codD, 17).Value - 1
  Next codO
  'replica dados
  With Sheets(Format([R2], "mm"))
   LR = .Cells(Rows.Count, 2).End(3).Row
   .Cells(LR + 1, 2).Resize(x).Value = [R2]
   .Cells(LR + 1, 3).Resize(x).Value = [R3]
   .Cells(LR + 1, 4).Resize(x).Value = [AA7]
   .Cells(LR + 1, 5).Resize(x).Value = [D7]
   .Cells(LR + 1, 6).Resize(x).Value = [Q7]
   .Cells(LR + 1, 23).Resize(x).Value = [Y2]
   .Cells(LR + 1, 7).Resize(x).Value = [B10].Resize(x).Value
   .Cells(LR + 1, 19).Resize(x).Value = [Y10].Resize(x).Value
  End With
  'limpa células azuis de PDV
  'LimpaPDV
  MsgBox "Venda Conluída"
End Sub

obs.

1. no código ReplicaVenda  deixei a opção da chamada para o código LimpaPDV , então após testar o segundo e se o resultado for o desejado, e se você quiser também já limpar PDV ao final da execução do primeiro, bastará remover o apóstrofo inicial da linha 'LimpaPDV

2. um alerta - se você mantiver o código LimpaPDV vinculado ao botão, há que ter em conta que se o botão for acionado (intencionalmente ou não) antes de os dados serem replicados, então tais dados serão perdidos, pois após rodar o código que limpa não haverá possibilidade de recuperá-los via Desfazer/Ctrl+z, no entanto se por alguma razão você quiser manter a opção de limpar PDV sem replicar os dados (no caso de cancelamento da venda, por exemplo) aí seria oportuno incorporar o LimpaPDV  ao ReplicaVenda  e criar outro código contendo um alerta de confirmação antes de limpar e aí sim, vincular esse novo código ao botão INICIAR VENDA