VisualG <code> Uso do repita

[Michael Pereira Cabral]

[Sou leigo ainda, me desculpem], Fiz esse pseudocódigo no VisualG usando estrutura repita, mas toda vez que eu coloco a resposta "N" ele trava tudo e fecha programa. Não consigo achar porque está dando errado, se alguém puder me ajudar  

 

Faça um programa usando a estrutura “repita” que leia a idade de várias pessoas. A cada laço, você deverá perguntar para o usuário se ele quer ou não continuar a digitar dados. No final, quando o usuário decidir parar, mostre na tela:

a) Quantas idades foram digitadas

b) Qual é a média entre as idades digitadas

c) Quantas pessoas tem 21 anos ou mais.

 

Algoritmo "semnome"

Var
   contador, soma, idade, contador21: inteiro
   resposta: caractere
   media: real
Inicio
   contador <- 0
   soma <- 0
   contador21 <- 0
   repita
      escreva ("Digitea idade: ")
      leia (idade)
      se idade >= 21 entao
         contador21 <- contador21 + 1
      fimse
      soma <- soma + idade
      contador <- contador + 1
      escreva ("Quer continuar? {S/N] ")
      leia (resposta)
   até maiusc (resposta) = "N"
   media <- soma / contador
   escreval ("Foram digitadas ", contador, " idades")
   escreval (" Media de idade é: ", media)
   escreval ("Tem ", contador21, " pessoas com mais de 21 anos")
Fimalgoritmo

 

[Simon Viegas]

Acho que já corrigiu, né?

O problema poderia está ali no "até". É sem acento.

 

   ate (Maiusc(resposta) = "N")

 

Adendo 1: não precisa do Maiusc()... mas pode deixar. Fica até mais semântico.

 

Adendo 2:

4 horas atrás, Michael Pereira Cabral disse:

   contador <- 0
   soma <- 0
   contador21 <- 0

Também não precisa "zerar" as variáveis no VisualG. É feito automaticamente, mas da mesma forma, melhor deixar!!!

 

Adendo 3: tem alguns ajustes finos... só detalhes mesmo. Segue:

 

1. ali antes do S/N tem um abre chaves em vez do abre colchetes;

2. após o "Foram digitadas" tem um espaço a mais;

3. é possível formatar os números reais, deixando com casas decimais fixas;

4. na último linha também tem um espaço a mais antes do número.

Exemplo de correção:

      escreva ("Quer continuar? [S/N]")
      leia(resposta)
   ate (resposta = "N")
   
   media <- soma / contador
   
   escreval("Foram digitadas ", contador:1, " idades")
   escreval("Media de idade é ", media:1:2)
   escreval("Tem ", contador21:1, " pessoas com mais de 21 anos")
fimAlgoritmo

Resultado: