VisualG Gabarito de Prova Visualg

[José Elson]

Estou aprendendo lógica agora e estou tentando montar um programa que eu coloco as respostas certas primeiro, depois coloco os alunos e assim depois vejo quantas respostas foram certas e coloco numa tela final.

 

Var
// Seção de Declarações das variáveis 
Gab, Resp : vetor[1..5] de caractere
C : inteiro
Nome: vetor[1..3] de caractere
Acertos: vetor[1..3] real


Inicio
// Seção de Comandos, procedimento, funções, operadores, etc... 
   EscrevaL("--GABARITO DA PROVA--")
   Para C <- 1 ate 5 faca
        Escreva("Questão ",C ," : ")
        leia(Gab[C])
   fimpara
   limpatela
   para C <- 1 ate 3 faca
        escrevaL("-------------------------")
        Escreva("NOME : ")
        Leia (Nome[C])
        EscrevaL("-------------------------")
            para C <- 1 ate 5 faca
                 Escreva("Questão ", C ," : ")
                 leia (Resp[C])
            fimpara
    fimpara
    para C <- 1 ate 3 faca
         se (Gab[C] = Resp[C]) então
         Acertos[C] <- Acertos[C] + 2
         fimse
    fimpara
    limpatela
    EscrevaL("Notas Finais")
    EscrevaL("---------------")
    EscrevaL(Nome[C], " : ", Acertos[C])

Fimalgoritmo

 

Só que não consigo pegar os acertos de cada pessoa separada e acaba dando erro na hora de executar 

[kgin]

no vetor Acertos faltou colocar o "de"

Errado!

Acertos: vetor[1..3] real 

Certo!

Acertos: vetor[1..3] de real 

 

Para postar código no fórum use o botão code <>

55 minutos atrás, José Elson disse:

Só que não consigo pegar os acertos de cada pessoa separada e acaba dando erro na hora de executar 

Para pegar as respostas de cada pessoa você deveria usar uma matriz.

Exemplo

Algoritmo "semnome"
const
   QUANTIDADE_ALUNOS = 3
   QUANTIDADE_RESPOSTAS = 5
Var
   // Seção de Declarações das variáveis
   Gab, Resp : vetor[1..5] de caractere
   C : inteiro
   Nome: vetor[1..3] de caractere
   Acertos: vetor[1..3] de real
   contador1, contador2:inteiro
   gabarito_alunos:vetor [1..QUANTIDADE_ALUNOS, 1..QUANTIDADE_RESPOSTAS] de caractere


Inicio
   // Seção de Comandos, procedimento, funções, operadores, etc...
   EscrevaL("--GABARITO DA PROVA--")
   Para C <- 1 ate 5 faca
      Escreva("Questão ",C ," : ")
      leia(Gab[C])
   fimpara

   limpatela
   para contador1 <- 1 ate QUANTIDADE_ALUNOS faca
      // Pega o nome dos alunos
      escreval("Digite o nome do aluno")
      leia(nome[contador1])
      // Pega o gabarito de cada prova
      para contador2 <- 1 ate QUANTIDADE_RESPOSTAS faca
         escreva("Questão ", contador2, " : ")
         leia(gabarito_alunos[contador1, contador2])
      fimPara
   fimPara

   limpaTela
   // Mostra as respostas de cada aluno
   para contador1 <- 1 ate QUANTIDADE_ALUNOS faca
      escreval("Nome aluno:", nome[contador1])
      escreval("     Gabarito da prova")
      para contador2 <- 1 ate QUANTIDADE_RESPOSTAS faca
         escreval("Questão ", contador2, ":", gabarito_alunos[contador1, contador2])
      fimPara
   fimPara
Fimalgoritmo