Excel Criar pdf's com nomes distintos usando mala direta por meio de um código VBA

Andressa Cristina da Silva · 11 de janeiro de 2023

Boa tarde!

Estou com a seguinte dúvida e gostaria de ajuda, eu criei uma mala direta com 500 dados e a partir dela eu gostaria de gerar pdf's separados de cada um dos arquivos da mala direta de modo que esses pdf's sejam já renomeados a partir de uma coluna do próprio excel usada na mala direta. Eu fiz um código base, mas ele não gera os documentos de todos os arquivos da mala direta.

Sub SalvaPDFsIndividuais()
  Const Caminho = "C:\Users\cm-co\Documents\Documentos greve\Nota Técnica"
  Dim i As Long
  Dim Nome_do_recebedor
  For i = 1 To ThisDocument.Range.Information(wdNumberOfPagesInDocument)
     ThisDocument.ExportAsFixedFormat OutputFileName:=Caminho & Nome_do_recebedor & i, _
                                      ExportFormat:=wdExportFormatPDF, _
                                      Range:=wdExportAllDocument
  Next i
End Sub

A base de dados fictícia usada para os testes segue em anexo

duvida vba.xlsx

Midori · 11 de janeiro de 2023

@Andressa Cristina da Silva Para exportar os dados de toda a base, a macro deve selecionar cada registro antes da exportação. Isso pode ser feito com os membros de MailMergeDataSource. Veja se assim resolve,

Sub SalvaPDFsIndividuais()
    Const Caminho = "C:\Users\cm-co\Documents\Documentos greve\Nota Técnica\"
    Dim Conta   As Long
    Dim Nome    As String
    Dim Base    As MailMergeDataSource
    
    Set Base = ThisDocument.MailMerge.DataSource
    Base.ActiveRecord = wdFirstRecord
   
    For Conta = 1 To Base.RecordCount
        Nome = Base.DataFields("Nome_do_recebedor").Value
        
        Call ThisDocument.ExportAsFixedFormat( _
            OutputFileName:=Caminho & Nome & Conta, _
            ExportFormat:=wdExportFormatPDF, _
            Range:=wdExportAllDocument)
        
        Base.ActiveRecord = wdNextRecord
    Next Conta
End Sub