Excel Contador mediante células preenchidas.

[GENECIOFICIAL]

Boa tarde!

 

Solicito um contador automático na coluna A, via fórmula ou VBA, mediante o preenchimento das células das colunas B:G

 

Grato.

Geneci.

ENUMERAR SEQUÊNCIA.xlsx

[Scofieldgyn]

@GENECIOFICIAL

veja se atende:

Sub VerificarPreenchimento()
    Dim ws As Worksheet
    Dim linha As Long, col As Long
    Dim preenchido As Boolean
    Dim ultimaLinha As Long
    Dim contadorItem As Long

    Set ws = ThisWorkbook.Sheets("Planilha1") 'importante não esquece de colocar o nome correto da guia
    contadorItem = 1

    ultimaLinha = ws.Cells(ws.Rows.Count, 2).End(xlUp).Row
    For col = 3 To 7 ' C até G
        ultimaLinha = Application.WorksheetFunction.Max(ultimaLinha, ws.Cells(ws.Rows.Count, col).End(xlUp).Row)
    Next col

    For linha = 1 To ultimaLinha
        preenchido = True

        For col = 2 To 7
            If Trim(ws.Cells(linha, col).Value) = "" Then
                preenchido = False
                Exit For
            End If
        Next col

        If preenchido Then
            ws.Cells(linha, 1).Value = "Item " & contadorItem
            contadorItem = contadorItem + 1
        Else
            ws.Cells(linha, 1).Value = "Pendente"
        End If
    Next linha
End Sub