Vb6

[Alberto09]

Olá pessoal,

Alguém aí sabe como é possível colocar um picture box junto com um scrool bar para que o form funcione mais ou menos como uma página web? Quero fazer um formulário com vários combo boxes dentro mas não sei como fazer isso.

Grato desde já,

Alberto

[Clemente Silva]

Tem que colocar dois PictureBox, um ScrollBar Vertical e outro Horizontal.

Os dois PictureBox tem que colocar um dentro do outro, sendo que o PictureBox que vai rolar com as barras será o que estiver contido dentro do outro.

Vou postar um exemplo:

1) Abra o Bloco de Notas do Windows

2) Copie o código abaixo (tudo o que estiver na janela "code") e cole dentro da janela do bloco de notas:

VERSION 5.00
Begin VB.Form frmTeste 
   Caption         =   "Teste! "
   ClientHeight    =   4305
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   6045
   LinkTopic       =   "Form1"
   ScaleHeight     =   4305
   ScaleWidth      =   6045
   StartUpPosition =   3  'Windows Default
   Begin VB.HScrollBar hscHorizontal 
      Height          =   240
      Left            =   1500
      TabIndex        =   3
      TabStop         =   0   'False
      Top             =   3375
      Width           =   1590
   End
   Begin VB.VScrollBar vscVertical 
      Height          =   915
      Left            =   4200
      TabIndex        =   2
      TabStop         =   0   'False
      Top             =   600
      Width           =   240
   End
   Begin VB.PictureBox picContainer 
      Appearance      =   0  'Flat
      BackColor       =   &H8000000C&
      BorderStyle     =   0  'None
      ForeColor       =   &H80000008&
      Height          =   2415
      Left            =   375
      ScaleHeight     =   2415
      ScaleWidth      =   3465
      TabIndex        =   0
      TabStop         =   0   'False
      Top             =   300
      Width           =   3465
      Begin VB.PictureBox picScroll 
         Appearance      =   0  'Flat
         BackColor       =   &H80000005&
         ForeColor       =   &H80000008&
         Height          =   1815
         Left            =   225
         ScaleHeight     =   1785
         ScaleWidth      =   2835
         TabIndex        =   1
         TabStop         =   0   'False
         Top             =   225
         Width           =   2865
         Begin VB.Label lblLabel 
            AutoSize        =   -1  'True
            BackStyle       =   0  'Transparent
            Caption         =   "Teste ScrollBar! Teste ScrollBar! Teste ScrollBar! "
            BeginProperty Font 
               Name            =   "Tahoma"
               Size            =   72
               Charset         =   0
               Weight          =   400
               Underline       =   0   'False
               Italic          =   0   'False
               Strikethrough   =   0   'False
            EndProperty
            Height          =   1740
            Left            =   225
            TabIndex        =   4
            Top             =   225
            Width           =   31275
         End
      End
   End
End
Attribute VB_Name = "frmTeste"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Private Sub Form_Load()
    
    picScroll.Move 300, 300, lblLabel.Width, 15000
    
    With vscVertical
        .Min = -300
        .LargeChange = 600
        .SmallChange = 1200
        .Value = .Min
    End With

    With hscHorizontal
        .Min = -300
        .LargeChange = 600
        .SmallChange = 1200
        .Value = .Min
    End With
    
End Sub

Private Sub Form_Resize()
    If WindowState = vbMinimized Then Exit Sub
    On Local Error Resume Next
    picContainer.Move 0, 0, (ScaleWidth - vscVertical.Width), (ScaleHeight - hscHorizontal.Height)
    With vscVertical
        .Move picContainer.ScaleWidth, 0, 240, picContainer.ScaleHeight
        .Max = ((picScroll.ScaleHeight + 300) - picContainer.ScaleHeight)
    End With
    With hscHorizontal
        .Move 0, picContainer.Height, picContainer.ScaleWidth, 240
        .Max = ((picScroll.ScaleWidth + 300) - picContainer.ScaleWidth)
    End With
    Err.Clear
End Sub

Private Sub vscVertical_Change()
    picScroll.Top = -(vscVertical.Value)
End Sub

Private Sub vscVertical_Scroll()
    picScroll.Top = -(vscVertical.Value)
End Sub

Private Sub hscHorizontal_Change()
    picScroll.Left = -(hscHorizontal.Value)
End Sub

Private Sub hscHorizontal_Scroll()
    picScroll.Left = -(hscHorizontal.Value)
End Sub

3) Salve o arquivo no bloco de notas como "frmTeste.frm" (atenção para NÃO salvar como TEXTO)

Depois abra no VB e veja como funciona.

[Alberto09]

Obrigado, Clemente!