Programa que feche uma janela caso caia minha net.

robsonhess · 1 de setembro de 2011

preciso de um programa que fexe uma janela caso caia minha net(troque meu ip)

exxiste algum?

tem como fazer?

não entendo nada disso

Obrigado.

AlyssonMaster · 2 de setembro de 2011

Boa tarde robsonhess,

Sim é possível. Posso criar um batch que fica testando a conexão com um site qualquer ("Google" por exemplo) e assim que a conexão falhar a janela desejada será fechada, mas pra isso preciso das seguintes informações:

* Nome do programa que será fechado (Por exemplo: "Internet Explorer")

* Título da janela que será fechada (Por exemplo: "Internet Explorer - Google")

* Nome do executável do programa (Por exemplo: "iexplore.exe")

Com essas informações posso criar o batch. Até mais!

robsonhess · 2 de setembro de 2011

Boa tarde robsonhess,
Sim é possível. Posso criar um batch que fica testando a conexão com um site qualquer ("Google" por exemplo) e assim que a conexão falhar a janela desejada será fechada, mas pra isso preciso das seguintes informações:

* Nome do programa que será fechado (Por exemplo: "Internet Explorer")

* Título da janela que será fechada (Por exemplo: "Internet Explorer - Google")

* Nome do executável do programa (Por exemplo: "iexplore.exe")

Com essas informações posso criar o batch. Até mais!

boa noite alyssonmaster

eu ficaria muito feliz se podesse me ajudar.

é uma jenela de um servidor online,que ele abrirá automaticamnte com o restarter com novo ip logo em seguida.

para isto será nescessario o programa checar a conexao a cada +/- 3 minutos.Uso no-ip para obter ip fixo.

* Nome do programa que será fechado (Alissow Server)

* Título da janela que será fechada ("Alissow Server")

* Nome do executável do programa ("Alissow Server.exe")

para facilitar coloquei o mesmo nome no .exe e na janela.

se você conseguir me ajudar eu vou fica muito feliz mesmo.

um abraço aguardo resposta.

AlyssonMaster · 6 de setembro de 2011

Bom dia robsonhess, você quer que a janela seja fechada e reaberta automaticamente?

robsonhess · 6 de setembro de 2011

Bom dia robsonhess, você quer que a janela seja fechada e reaberta automaticamente?

Bom dia AlyssonMaster

não será preciso ,pois tenho um programa que irá trocar o ip nas configurações e reabrir o programa.

Obrigado

AlyssonMaster · 8 de setembro de 2011

Bom dia robsonhess, eu havia criado seu código monitorando a conexão com a internet e se por acaso ela falhasse fecharia a janela, mas dessa forma o programa fica passível de erro já que não é o IP que está sendo monitorado. Tive então a necessidade de utilizar um outro aplicativo em conjunto com meu batch para monitorar o IP e fechar a janela assim que o mesmo for alterado.

A função do batch é verificar a cada 3 minutos se o IP foi alterado, e se foi, finaliza o aplicativo "Alissow Server.exe".

Aqui está o link para download dos aplicativos: DOWNLOAD

Baixe o arquivo zipado acima e extraia-o para qualquer pasta. Lembrando que os arquivos WindowCloser.bat e wget.exe devem estar na mesma pasta.

Testa aí e qualquer coisa pode me falar que eu altero.

Abaixo está o código do batch, só pra constar mesmo

@ECHO OFF
SETLOCAL EnableDelayedExpansion EnableExtensions
@MODE con Cols=18 Lines=14
TITLE Conexao
COLOR A0
SET WCL=0
SET RUNTIME=%TIME:~0,8%
SET CHECK=0

:MAIN

	COLOR A0
	CALL :GETIP
	CALL :DISPLAY
	PING -n 1 -w 180000 1.2.3.4>NUL
	IF [%CHECK%]==[0] CALL :CHECKIP
	IF [%CHECK%]==[1] CALL :CLOSEWINDOW
	IF [%CHECK%]==[2] GOTO WAITCONNECTION
	GOTO MAIN

:DISPLAY

	CLS
	ECHO.
	ECHO. Conectado desde:
	ECHO.    %RUNTIME%
	ECHO.------------------
	ECHO.    IP atual:
	ECHO.  %LASTIP%
	ECHO.------------------
	ECHO.  Janela fechada:
	ECHO.     %WCL% vezes.
	ECHO.------------------
	GOTO :EoF

:GETIP

	DEL /F /Q WindowCloser.dat>NUL
	WGET -q -O WindowCloser.dat http://automation.whatismyip.com/n09230945.asp
	FOR /F "delims=^" %%I in (WindowCloser.dat) do (SET NEWIP=%%I)
	IF NOT DEFINED LASTIP (SET LASTIP=%NEWIP%)
	GOTO :EoF

:CHECKIP

	IF [%LASTIP%]==[%NEWIP%] GOTO :EoF
	SET CHECK=1
	SET LASTIP=%NEWIP%
	GOTO :EoF

:CLOSEWINDOW

	TASKKILL /F /IM "Alissow Server.exe">NUL
	SET /A WCL=%WCL%+1
	SET CHECK=2
	GOTO :EoF

:WAITCONNECTION

	COLOR C0
	CALL :DISPLAY
	PING -n 1 -w 2000 www.google.com.br > NUL
	IF %ERRORLEVEL% EQU 0 (
	SET RUNTIME=%TIME:~0,8%
	SET CHECK=0
	GOTO MAIN
	)
	PING -n 2 -w 2000 1.2.3.4 > NUL
	GOTO WAITCONNECTION

:END

	EXIT