Ajuda com Urna Eletronica no visulg

matheusxfx · 14 de junho de 2013

Olá pessoal estou com problemas na elaboração desse algoritmo.

Quando tento corrigir meu voto ele diz que tem um fimenquanto sem um enquanto. Algué pode me ajudar.

Aaixo o codigo:

// Função:
// Autor:
// Data: 14/06/2013
// Seção de Declarações
var

c1, c2, c3, c4, c5, bracos, nulos, votos, senha, csenha, mv1, mv2, mv3, tvotos: real
enter, aux, corrigir: caractere

inicio

c1 <- 0
c2 <- 0
c3 <- 0
c4 <- 0
c5 <- 0
bracos <- 0
nulos <- 0
votos <- 0
senha <- 0
csenha <- 123
mv1 <- 0
mv2 <- 0
mv3 <- 0
tvotos <- 0
enter <- "e"
aux <- ""
corrigir <- ""

escreval (" ==========Bem Vindo as Eleições 2013==========")
escreval (" Para votar tecle: 'V' --- Para apurar tecle: 'A'")
leia (aux)
limpatela

enquanto (aux = "v") ou (aux = "a") faca
se (aux = "v") então
escreval (" ==========Você está no menu para votação========== ")
escreval ("Os seguintes candidatos estão concorrendo a presidência: ")
escreval (" _______________________________________________ ")
escreval ("| Nome: | Numero: | ")
escreval ("|_____________________________________|_________| ")
escreval ("| Joaquim José da Silva Xavier | 5001 | ")
escreval ("| Olavo Bilac | 5002 | ")
escreval ("| Pedro Alcântara do Nascimento | 5003 | ")
escreval ("| Tarcila do Amaral | 5004 | ")
escreval ("| Emília Borba | 5005 | ")
escreval (" ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ ¯¯¯¯¯¯¯¯¯ ")
escreva ("Informe o número do candidato. Se deseja votar em 'BRANCO' tecle '1' ")
leia (votos)
limpatela
se (votos >= 5001) ou (votos <= 5005) ou (votos = 0) ou (votos = 1) então
se (votos = 5001) então
c1 <- (c1 + 1)
escreval ("Você votou em: Joaquim José da Silva Xavier")
escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER'")
leia (enter)
limpatela
se (enter = "e") então
c1 <- (c1 + 1)
escreval (" ==========Eleições 2013========== ")
escreval ("Para votar tecle: 'V' --- Para apurar tecle: 'A'")
leia (aux)
senao
escreval (" ==========Eleições 2013========== ")
escreval ("Informe o número do candidato. Se deseja votar em 'BRANCO' tecle '1'")
leia (votos)
limpatela
senao
se (votos = 5002) então
escreval ("Você votou em: Olavo Bilac")
escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER'")
leia (enter)
limpatela
se (enter = "e") então
c2 <- (c2 + 1)
senao
escreval (" ==========Eleições 2013========== ")
escreval ("Para votar tecle: 'V' --- Para apurar tecle: 'A'")
leia (aux)
limpatela
senao
se (votos = 5003) então
escreval ("Você votou em: Pedro Alcântara do Nascimento")
escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER")
leia (enter)
limpatela
se (enter = "e") então
c3 <- (c3 + 1)
senao
escreval (" ==========Eleições 2013========== ")
escreval ("Para votar tecle: 'V' --- Para apurar tecle: 'A'")
leia (aux)
limpatela
senao
se (votos = 5004) então
escreval ("Você votou em: Tarcila do Amaral")
escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER")
leia (enter)
limpatela
se (enter = "e") então
c4 <- (c4 + 1)
senao
escreval (" ==========Eleições 2013========== ")
escreval ("Para votar tecle: 'V' --- Para apurar tecle: 'A'")
leia (aux)
limpatela
senao
se (votos = 5005) então
escreval ("Você votou em: Emília Borba")
escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER")
leia (enter)
limpatela
se (enter = "e") então
c5 <- (c5 + 1)
senao
escreval (" ==========Eleições 2013========== ")
escreval ("Para votar tecle: 'V' --- Para apurar tecle: 'A'")
leia (aux)
limpatela
senao
se (votos = 1) então
escreval ("Você votou em 'BRANCO'")
escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER")
leia (enter)
limpatela
se (enter = "e") então
brancos <- (brancos + 1)
senao
escreval (" ==========Eleições 2013========== ")
escreval ("Para votar tecle: 'V' --- Para apurar tecle: 'A'")
leia (aux)
limpatela
senao
nulos <- (nulos + 1)
fimse
fimse
fimse
fimse
fimse
fimse
fimse
fimse
fimse
fimse
fimse
fimse
senao
se (aux = "a") então
escreval ("==========Apuração==========")
escreval ("Você está no menu para apuração dos votos")
escreval ("Por favor informe a senha: ")
leia (senha)
limpatela
se (senha = csenha) então
escreval ("Bem vindo a apuração dos votos")
escreval ("Se deseja continuar tecle 'E' --- Se deseja voltar tecle 'V'")
leia (aux)
limpatela
se (aux = "e") então
escreval ("==========Apuração==========")
escreval
tvotos <- ((c1 + c2 + c3 + c4 + c5 + brancos + nulos) / 2 + 1)
se (c1 < tvotos) então
escreval ("O canditato, Joaquim José da Silva Xavier, é o novo presidente!")
senao
se (c2 < tvotos)
fimse
fimse
fimse
fimse
fimse
fimse
fimenquanto
fimalgoritmo
algoritmo "UrnaEletronica"

Tiago Grunge · 24 de junho de 2013

Inicialmente o problema do fimenquanto sem o enquanto era por conta que suas condições SE não estarem todas fechadas. Dê uma analisada no seu código. espero ter ajudado!

Cara eu dei uma mexidinha no teu código espero que tenha ficado como você desejava.


algoritmo "Urna Eletrônica"
// Função :
// Autor :
// Data : 24/06/2013
// Seção de Declarações
var
c1, c2, c3, c4, c5, brancos, nulos, votos, senha, csenha, mv1, mv2, mv3, tvotos: real
enter, aux, corrigir: caractere

procedimento  correção
var
voto:         real
inicio
escreval ("       ==========Eleições 2013==========            ")
escreval (" __________________Correção_____________________    ")
escreval ("| Nome:                               | Numero: |   ")
escreval ("|_____________________________________|_________|   ")
escreval ("| Joaquim José da Silva Xavier        |   5001  |   ")
escreval ("| Olavo Bilac                         |   5002  |   ")
escreval ("| Pedro Alcântara do Nascimento       |   5003  |   ")
escreval ("| Tarcila do Amaral                   |   5004  |   ")
escreval ("| Emília Borba                        |   5005  |   ")
escreval (" ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ ¯¯¯¯¯¯¯¯¯    ")
escreval ("Informe o número do candidato. Se deseja votar em 'BRANCO' tecle '1'")
leia (voto)

se voto = 1 então
   brancos<- brancos + 1
senao
   se voto = 5001 então
      c1<- c1 + 1
   senao
      se voto = 5002 então
         c2<- c2 + 1
      senao
         se voto = 5003 então
            c3<- c3 + 1
         senao
            se voto = 5004 então
               c4<- c4 + 1
            senao
               se voto = 5005 então
                  c5<- c5 + 1
               fimse
            fimse
         fimse
      fimse
   fimse
fimse
limpatela
fimprocedimento

inicio
// Seção de Comandos
c1       <- 0
c2       <- 0
c3       <- 0
c4       <- 0
c5       <- 0
brancos  <- 0
nulos    <- 0
votos    <- 0
senha    <- 0
csenha   <- 123
mv1      <- 0
mv2      <- 0
mv3      <- 0
tvotos   <- 0
enter    <- "e"
aux      <- ""
corrigir <- ""

escreval ("                   ==========Bem Vindo as Eleições 2013==========")
escreval ("                  Para votar tecle: 'V' --- Para apurar tecle: 'A'")
leia (aux)
limpatela

enquanto (aux = "v") ou (aux = "a") faca
   se aux = "a" então
      escreval ("==========Apuração==========")
      escreval ("Você está no menu para apuração dos votos")
      escreval ("Por favor informe a senha: ")
      leia (senha)
      limpatela
      se (senha = csenha) então
         escreval ("Bem vindo a apuração dos votos")
         escreval ("Se deseja continuar tecle 'E' --- Se deseja voltar tecle 'V'")
         repita
            leia (aux)
         ate (aux = "E") ou (aux = "V")
         limpatela
         se (aux = "e") então
            tvotos <- (c1 + c2 + c3 + c4 + c5 + brancos + nulos)
            escreval ("==========Apuração==========")
            escreval
            escreval("Joaquim José da Silva Xavier  ",c1)
            escreval("Olavo Bilac                   ",c2)
            escreval("Pedro Alcântara do Nascimento ",c3)
            escreval("Tarcila do Amaral             ",c4)
            escreval("Emília Borba                  ",c5)
            escreval("Votos em brando               ",brancos)
            escreval("Total de Votos                ",tvotos)

            se (c1 > c2) e (c1 > c3) e (c1 > c4) e (c1 > c5)  então
               escreval("----------------------------------------------------------------------------")
               escreval("O canditato, Joaquim José da Silva Xavier é o novo presidente! ",c1," Votos" )
               escreval("----------------------------------------------------------------------------")
            senao
               se (c2 > c1) e (c2 > c3) e (c2 > c4) e (c2 > c5)  então
                  escreval("----------------------------------------------------------------------------")
                  escreval("O canditato, Olavo Bilac é o novo presidente! ",c2," Votos")
                  escreval("----------------------------------------------------------------------------")
               senao
                  se (c3 > c1) e (c3 > c2) e (c3 > c4) e (c3 > c5)  então
                     escreval("----------------------------------------------------------------------------")
                     escreval("O canditato, Pedro Alcântara do Nascimento é o novo presidente! ",c3," Votos")
                     escreval("----------------------------------------------------------------------------")
                  senao
                     se (c4 > c1) e (c4 > c2) e (c4 > c3) e (c4 > c5)  então
                        escreval("----------------------------------------------------------------------------")
                        escreval("O canditato, Tarcila do Amaral é o novo presidente! ",c4," Votos")
                        escreval("----------------------------------------------------------------------------")
                     senao
                        se (c5 > c1) e (c5 > c2) e (c5 > c3) e (c5 > c4)  então
                           escreval("----------------------------------------------------------------------------")
                           escreval("O canditato, Emília Borba é o novo presidente! ",c5," Votos")
                           escreval("----------------------------------------------------------------------------")
                           leia(aux)
                           limpatela
                        fimse
                     fimse
                  fimse
               fimse
            fimse
         fimse
      fimse
   fimse


   se (aux = "v") então
      escreval ("    ==========Você está no menu para votação==========      ")
      escreval ("Os seguintes candidatos estão concorrendo a presidência: ")
      escreval (" _______________________________________________    ")
      escreval ("| Nome:                               | Numero: |   ")
      escreval ("|_____________________________________|_________|   ")
      escreval ("| Joaquim José da Silva Xavier        |   5001  |   ")
      escreval ("| Olavo Bilac                         |   5002  |   ")
      escreval ("| Pedro Alcântara do Nascimento       |   5003  |   ")
      escreval ("| Tarcila do Amaral                   |   5004  |   ")
      escreval ("| Emília Borba                        |   5005  |   ")
      escreval (" ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ ¯¯¯¯¯¯¯¯¯    ")
      escreva ("Informe o número do candidato. Se deseja votar em 'BRANCO' tecle '1' ")
      leia (votos)
      limpatela

      escolha votos
      caso 1
         escreval ("Você votou em 'BRANCO'")
         escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER")
         leia (enter)
         limpatela
         se (enter = "e") então
            brancos <- (brancos + 1)
         senao
            limpatela
            correção
         fimse
      caso 5001
         escreval ("Você votou em: Joaquim José da Silva Xavier")
         escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER'")
         leia (enter)
         limpatela
         se (enter = "e") então
            c1 <- (c1 + 1)
            escreval ("        ==========Eleições 2013==========       ")
            escreval ("Para votar tecle: 'V' --- Para apurar tecle: 'A'")
            leia (aux)
            limpatela
         senao
            limpatela
            correção
         fimse
      caso 5002
         escreval ("Você votou em: Olavo Bilac")
         escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER'")
         leia (enter)
         limpatela
         se (enter = "e") então
            c2 <- (c2 + 1)
            escreval ("        ==========Eleições 2013==========       ")
            escreval ("Para votar tecle: 'V' --- Para apurar tecle: 'A'")
            leia (aux)
            limpatela
         senao
            limpatela
            correção
         fimse
      caso 5003
         escreval ("Você votou em: Pedro Alcântara do Nascimento")
         escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER'")
         leia (enter)
         limpatela
         se (enter = "e") então
            c3 <- (c3 + 1)
            escreval ("        ==========Eleições 2013==========       ")
            escreval ("Para votar tecle: 'V' --- Para apurar tecle: 'A'")
            leia (aux)
            limpatela
         senao
            limpatela
            correção
         fimse
      caso 5004
         escreval ("Você votou em: Tarcila do Amaral")
         escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER'")
         leia (enter)
         limpatela
         se (enter = "e") então
            c4 <- (c4 + 1)
            escreval ("        ==========Eleições 2013==========       ")
            escreval ("Para votar tecle: 'V' --- Para apurar tecle: 'A'")
            leia (aux)
            limpatela
         senao
            limpatela
            correção
         fimse
      caso 5005
         escreval ("Você votou em: Emília Borba ")
         escreval ("Para confirmar tecle: 'E' --- Para corrigir tecle: 'ENTER'")
         leia (enter)
         limpatela
         se (enter = "e") então
            c5 <- (c5 + 1)
            escreval ("        ==========Eleições 2013==========       ")
            escreval ("Para votar tecle: 'V' --- Para apurar tecle: 'A'")
            leia (aux)
            limpatela
         senao
            limpatela
            correção
         fimse
      fimescolha
   fimse
fimenquanto
fimalgoritmo