Excel macro para permitir somente colar valores

CoOloKey · 1 de maio de 2016

Bom dia.

Preciso de ajuda com uma planilha minha que utilizo para fazer projeção de custo, a mesma está tudo ok, o que preciso é de algum macro ou opção mesmo do excel (que não achei ainda) que não permita que o usuário não altere o tamanho/cor/tipo da fonte (na verdade quero que todos os dados copiados utilizassem automaticamente a opção copiar apenas valores), pois o bloqueio padrão do Excel permite este bloqueio desde que o usuário digite os dados manualmente, entretanto neste caso os dados serão copiados de outro lugar e colados na célula, quando os mesmo são copiados o bloqueio deixa passar a formatação de origem.

Obrigado desde já!

Basole · 1 de maio de 2016

@CoOloKey este codigo refaz a acao inserindo os dados como texto mantendo a formatacao nome da fonte, tamanho, cor, etc.

* cole o codigo no editor da "aba" que voce quer bloquear, por exemplo Plan1:

Option Explicit

 Private Sub Worksheet_Change(ByVal Target As Range)
    Dim UndoList As String
 
    Application.ScreenUpdating = False
    Application.EnableEvents = False
 
    On Error GoTo Whoa
    
    UndoList = Application.CommandBars("Standard").Controls("&Desfazer").List(1)
  
    If Left(UndoList, 5) <> "Colar" And UndoList <> "Preenchimento Automático" _
    Then GoTo LetsContinue
 
    Application.Undo
 
    If UndoList = "Preenchimento Automático" Then Selection.Copy

    On Error Resume Next
 
    Target.Select
    ActiveSheet.PasteSpecial Format:="Texto", _
    Link:=False, DisplayAsIcon:=False
 
    Target.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, _
    SkipBlanks:=False, Transpose:=False
    On Error GoTo 0
    
    Union(Target, Selection).Select
 
LetsContinue:
    Application.ScreenUpdating = True
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume LetsContinue
End Sub