Portugol Algoritmo, visualg de equação 1ºgrau

[Amilton Cândido]

Aonde está o erro? Não estou conseguindo fazer. 

Função : f(x)=2x+4

 

Desenvolver um programa para calcular a área definida entre o gráfico de uma função e o
eixo x dentro de um valor inicial x=a até um valor final x=b

 

sugestão: construir uma função que receba um valor de x e retorne o valor de f(x) para
uma função matemática qualquer (adotar). Com isso podemos calcular facilmente para
qualquer função (é só trocar)

 

 

[Simon Viegas]

Olá, por favor, código em forma de texto. (não dá para copiar o código da imagem)

 

No aguardo.

[Amilton Cândido]

Var
   a, b, r,  f(x): real
Inicio
   Escreva  ("digite o valor inicial")
   Leia (a)
   Ecreva  ("digite o valor final”)
   Leia (b)
   Escreva  ("digite o nº retângulos")
   Leia (r) base = (b*a)/r
   area = 0
   i=1
   Para  i=1;  i < = r
      xm =  a + base*(i + 1) + base/2
      area = area + base* fx
      i =  i + 1
   Fimpara
   Escreva  ("o valor da area da função desde o x  inicial ate o x final é:", area)
Fimalgoritmo

 

[Simon Viegas]

Olá @Amilton Cândido.

 

Tome cuidado com a sintaxe do Visualg, e o uso das variáveis... ou seja, toda variável que usar deve está previamente declarada.

 

 

Em relação ao código, são várias pontos que precisariam ser verificado... abaixo tentei fazer algumas alterações e deixei alguns comentários para tentar explicar cada parte.

Algoritmo "FCdH
//Função : f(x)=2x+4
//Desenvolver um programa para calcular a área definida entre o gráfico de uma
//função e o eixo x dentro de um valor inicial x=a até um valor final x=b
Var
   //a, b, r,  f(x): real
   a, b    :real    //x inicial e x final
   nr      :inteiro //número de retângulos
   base, FX:real    //base e altura do retângulo (altura encontrada pela F(X))
   mediana :real    //mediana da base do retângulo (para encontrar a altura do retângulo)
   areaR   :real    //área do retângulo
   areaT   :real    //área do triângulo

   x1,x2  :real
   i      :inteiro
Inicio
   escreva ("Digite o valor inicial :")
   leia(a)
   escreva ("Digite o valor final   :")
   leia(b)
   escreva ("Ddigite o nº retângulos:")
   {leia(nr) base = (b*a)/nr} //visualg não aceita comandos ao lado
   leia(nr)
   escreval()
   {base = (b*a)/nr} //o comando é <- e a fórum é -, não *
   base<-(b-a)/nr
   escreval("BASE:",base:3:2)
   areaT<-0
   {i=1} //não precisa inicializar, pois já é inicializado no Para
   {Para i=1;  i < = r} //sintaxe incorreta
   Para i de 1 ate nr faca
      //h <- a + base*(i + 1) + base/2
      {h <- (a+base*(i-1)) + ((base*i)+a) /2} //separar para poder mostrar na tela
      x1<- a + base*(i-1)
      x2<- a + base*i
      mediana<-(x1+x2)/2
      escreva ("(",x1:6:2,"+",x2:6:2,")/2=",mediana:6:2)

      FX<-2*(mediana)+4
      escreva ("   F(x)=",FX:6:2)

      areaR <-BASE*FX
      escreval("   A",i:3,":",areaR:6:2)
      areaT <- areaT+areaR
      {i =  i + 1} //o para já incrementa o i
   FimPara
   {escreva ("o valor da area da função desde o x  inicial ate o x final é:", areaT)} //muito mimimi
   escreva ("AREA APROXIMADA:", areaT:6:2)
Fimalgoritmo

Obs.: Creio eu, que como a figura é uniforme, não faz a menor diferença quantos retângulos usar!!

 

Obs. 2: Sobre: «Quanto maior for o número de retângulos, mais correto será o cálculo da área.». Na verdade, o seria mais correto dizer que "...mais preciso será o cálculo", ou seja, esse método é baseado em "aproximação". Dessa forma, para chegar no valor "correto", teriam-se que fazer infinitas operações. (isso levando em consideração a questão do tipo de figura, pois como os testes demonstram, para algumas figuras, o resultado não muda), ou seja, OU sempre vai ser o valor exato, OU nunca vai ser exato (acho eu).

 

 

Qualquer dúvidas é só perguntar.