Visual Basic VisualG:Erro Esperava encontrar entao, fimse, sintaxe incorreta.

[Nylan]

Bom pessoal, estou desenvolvendo um programa em VisualG para uma atividade da Faculdade, que apresente um menu de opções e que permita ao usuário escolher a opção desejada, receba os dados necessários para executar a operação e mostre o resultado. Verificar a possibilidade de opção inválida e não se preocupar com as restrições, como salário inválido. Porém ao executar o mesmo apresenta o erro de "Esperava encontrar entao" e "fimse".

algoritmo "semnome"

var
op: caracter
sal, nsal: real
meses: inteiro
inicio
// Seção de Comandos
escreva ("Informe o salário R$: ")
leia (sal)
limpatela
   	escreval("------------------- Menu ---------------------")
	escreval("1)                Novo Salário                ")
	escreval("2)                Férias                      ")
	escreval("3)                Décimo Terceiro             ")
	escreval("4)                Sair                        ")
	escreval("----------------------------------------------")
   escreva ("Informe a operação: ")
   leia (op)
   limpatela
   escolha op
   enquanto op = 4 faca
   caso "1"
   escreva ("O salário do funcionário é R$:", sal, "reais.")
   se sal <= 350  entao
   escreva ("O novo salário será R$: ", sal*0.15, "reais")
   fimse
   se sal = 350 e <= 600 entao
   escreva ("O novo salário será R$: ", sal*0.10, "reais")
   fimse
   se sal > 600 entao
   escreva ("O novo salário será R$: ", sal*0.05, "reais")
   fimse
   caso "2"
   escreva ("O salário acrescido de férias será R$ :" (sal+(sal*0.3)))
   caso "3"
   escreva ("Informe os meses trabalhados")
   leia (meses)
   escreva ("O seu décimo terceiro será RS: " (sal+(sal*meses)/12))
   caso "4"
   escreva ("Encerrar execução")
   outrocaso
   ("Opção inexistente")
   
	fimescolha
	
	fimenquanto

fimalgoritmo

 

[devair1010]

@anderdl18      o enquanto está fora do lugar , e seu código com algumas modificações poderia ser assim  :

algoritmo "menu"
var
  op        : caracter
  sal, nsal : real
  meses     : inteiro
inicio
  enquanto op <> "4" faca
    escreva ("Informe o salário R$: ")
    leia (sal)
    limpatela
    escreval("------------------- Menu ---------------------")
    escreval("1)                Novo Salário                ")
    escreval("2)                Férias                      ")
    escreval("3)                Décimo Terceiro             ")
    escreval("4)                Sair                        ")
    escreval("----------------------------------------------")
    escreva ("Informe a operação: ")
    leia (op)
    limpatela
    escolha op
    caso "1"
      escreval("O salário do funcionário é R$:", sal, "reais.")
      se sal <= 350  entao
        escreval("O novo salário será R$: ", sal*0.15, "reais")
      fimse
      se (sal > 350) e (sal <= 600) entao
        escreval("O novo salário será R$: ", sal*0.10, "reais")
      fimse
      se sal > 600 entao
        escreval("O novo salário será R$: ", sal*0.05, "reais")
      fimse
    caso "2"
      escreval("O salário acrescido de férias será R$ :", (sal+(sal*0.3)))
    caso "3"
      escreval("Informe os meses trabalhados")
      leia(meses)
      escreval("O seu décimo terceiro será RS: ", (sal+(sal*meses)/12))
    caso "4"
        escreval("Encerrar execução")
    outrocaso
      escreval("Opção inexistente .     Tecle enter !")
      leia(op)
    fimescolha
  fimenquanto
fimalgoritmo

 

[Nylan]

@devair1010 Cara muito obrigado, eu acabei recebendo a ajuda de um amigo que faz o mesmo curso que eu na Faculdade, mas com a sua ajuda e modificações vai me ajudar bastante quando tiver outros parecidos com esse, muito obrigado.