VisualG Pegar 2 var's diferente (caractere e real) e mostrar...

[Semnet]

Tava fazendo um exercicio e para resolver eu preciso pegar o aluno com a maior nota e vai mostrar o "Nome" e a "nota"

eu comecei mas não consigo finalizar

algoritmo "TheBestStudent"
var
   A , cla : Inteiro
   Not: Real
   N : Caractere
inicio
      Escreval("---FaculdadeOrlando---")
      Escreval("Quantos alunos a sala tem?")
      Leia(A)
      Cla <- 0
      Enquanto (Cla <= A) faca
               cla <- cla + 1
                Escreval("Escreva o nome do", cla," aluno")
                Leia(N)
                Escreval("Nota do ",N)
                Leia(Not)
      Fimenquanto


fimalgoritmo

 

adicionado 2 minutos depois

Para quem tiver com duvida na minha pergunta da aqui o exercicio 

 a partir do minuto 22:18

[devair1010]

@Semnet    você pode determinar qual a maior nota comparando a nota digitada com o valor da variável maior que precisa ser inicializada com valor zero ,  e ao mesmo tempo armazenar em uma variável auxiliar do tipo caractere , o nome do aluno , assim no final escreval o conteúdo da variável auxiliar , que será o nome do aluno , e a variável maior que será a maior nota :

algoritmo "TheBestStudent"
var
  quant , cont    : Inteiro
  nota,maior_nota : Real
  nome,auxiliar   : Caractere
inicio
  escreval("---FaculdadeOrlando---")
  escreva ("Quantos alunos a sala tem ? ")
  leia(quant)
  enquanto cont < quant faca
    cont <- cont + 1
    escreval("Escreva o nome do", cont," aluno")
    leia(nome)
    escreva("Nota do ",nome)
    leia(nota)
    se nota > maior_nota entao
      maior_nota := nota
      auxiliar := nome
    fimse
  fimenquanto
  escreval("O Aluno Com A Maior Nota é ",auxiliar," Com A Nota ",maior_nota)
fimalgoritmo

e uma variável que pode conter real e caractere é a variável caractere mesmo ,  mas depois precisa usar outra do tipo real para converter os caractere que são dígitos para real e os que são letras para caractere ,  e isso daria muito trabalho para fazer  .

[Semnet]

valeu cara

[Simon Viegas]

Como a quantidade de alunos é predeterminada, poderia utilizar um para/faca.

algoritmo "TheBestStudent"
var
   quant, cont :inteiro
   nota, maiorNota :real
   nome, nomeMaiorNota :caractere
inicio
   escreval("---FaculdadeOrlando---")
   escreva ("Quantos alunos a sala tem ? ")
   leia(quant)
   para cont de 1 ate quant faca
      escreva("Escreva o nome do ", cont:1," aluno: ")
      leia(nome)
      escreva("Nota do ", nome, ": ")
      leia(nota)
      se nota > maiorNota entao
         maiorNota <- nota
         nomeMaiorNota <- nome
      fimSe
   fimPara
   escreval("O aluno com a maior nota é ", nomeMaiorNota, " com a nota ", maiorNota:1:2)
fimAlgoritmo