Outro (BATCH) Como executar comando se conteúdo do arquivo for igual ao esfecificado

[Felipecconde]

Boa tarde! Estou fazendo um terminal/shell baseado em batch, e queria criar um comando que definisse o tema (cor) do meu terminal para sempre.

Exemplo:

 

Abro o meu terminal.bat

> theme dark

Arquivo "theme.txt" criado em "%cd%\variaveis" com o texto "darktheme"

O TEMA DO TERMINAL FOI DEFINIDO PARA "ESCURO"

> exit

Fecho o meu terminal.

Abro-o novamente.

Arquivo "theme.txt" carregado de "%cd%\variaveis" com o texto "dark_theme"

O TEMA DEFINIDO ANTERIORMENTE (DARK) FOI CARREGADO.

>

 

Mas a questão é...: Eu não sei como faz para salvar variáveis ou as exportar para um arquivo e nem lê-las. Resumidamente, não sei fazer o que eu quero fazer.

Se for possível, gostaria de definir TODAS AS VARIAVEIS que eu salvar no meu terminal em um UNICO ARQUIVO.

Se for muito complicado, prefiro salvar em arquivos separados mesmo hehe. (Se for possivel ensinar as duas formas, agradeco!)

[ricardo_br]

Olá @Felipecconde tudo bem?

 

Veja abaixo alguns exemplos:

 

Para salvar o texto: "Eu sou um texto" dentro da variável "Texto":

set Texto=Eu sou um Texto

Para salvar o um texto interativo (pedir para o usuário digitar algo e salvar isso numa variável) digamos que o nome da variável seja TextoInterativo:

set /p TextoInterativo=Favor digite um texto: 

Isso vai fazer com que apareça uma mensagem na tela: Favor insira um texto:

 

Para salvar o valor de uma variável dentro de um arquivo de texto digamos que você quer salvar o conteúdo da variável "Texto" dentro de um arquivo chamado "Arquivo.txt"

echo %texto%>Arquivo.txt

 

Para salvar o conteúdo de um arquivo de texto dentro de uma variável ficaria algo assim:

set /p texto=<Arquivo.txt

 

Veja se e mais ou menos isso que você quer:

 

@echo off
IF /i not exist "%CD%\variaveis\theme.txt" goto :Menu
set /p Tema=<"%CD%\variaveis\theme.txt"
IF "%Tema%"=="darktheme" color 07
IF "%Tema%"=="brighttheme" color 70
cls
echo.
echo Arquivo "theme.txt" carregado de "%cd%\variaveis" com o texto "%Tema%"
echo.
echo O TEMA DEFINIDO ANTERIORMENTE (%Tema%) FOI CARREGADO.
echo.
pause
exit

:Menu
cls
echo.
echo Ola, atualmente voce nao tem um tema definido
echo.
echo (D)arktheme
echo.
echo (B)righttheme
echo.
set /p "opcao=Pressione "D" para escuro ou "B" para claro: "

IF /i "%opcao%"=="D" goto :Escuro
IF /i "%opcao%"=="B" (goto :Claro) else (goto :Menu)


:Escuro
IF /i not exist "%CD%\variaveis" md "%CD%\variaveis"
set Tema=darktheme
echo %Tema%>"%CD%\variaveis\theme.txt"
color 07
cls
echo.
echo ^> theme dark
echo.
echo Arquivo "theme.txt" criado em "%cd%\variaveis" com o texto "%Tema%"
echo.
echo O TEMA DO TERMINAL FOI DEFINIDO PARA "ESCURO"
echo.
pause
exit

:Claro
IF /i not exist "%CD%\variaveis" md "%CD%\variaveis"
set Tema=brighttheme
echo %Tema%>"%CD%\variaveis\theme.txt"
color 70
cls
echo.
echo ^> theme Bright
echo.
echo Arquivo "theme.txt" criado em "%cd%\variaveis" com o texto "%Tema%"
echo.
echo O TEMA DO TERMINAL FOI DEFINIDO PARA "Claro"
echo.
pause
exit

 

 

[Felipecconde]

Muito obrigado pelo ensinamento e me desculpe pelo tempo tomado!