Excel Verificar se está aberto e abrir planilha excel (vba)

[Jefferson TS]

Olá. Existe alguma forma de verificar se a planilha está aberta, e então abrir?

Sub OpenUp()
    Workbooks.Open ("\\SERVIDOR\Users\Usuario\Desktop\FLUXO DE CAIXA\CONTAS A PAGAR.xlsm")
    Workbooks.Open ("\\SERVIDOR\Users\Usuario\Desktop\FLUXO DE CAIXA\ORDEM DE SERVIÇO.xlsm")
    Workbooks.Open ("\\SERVIDOR\Users\Usuario\Desktop\PREFEITURA 2021\Prefeitura Caminhões.xlsm")
    Workbooks.Open ("\\SERVIDOR\Users\Usuario\Desktop\PREFEITURA 2021\Prefeitura Máquinas.xlsm")
    Workbooks("FLUXO DE CAIXA.xlsm").Activate
End Sub

Estou fazendo desta forma, porém, se alguma planilha já está aberta dá erro.
Alguém pode me ajudar?

[Midori]

@Jefferson TS Em que parte dá erro? Você quer verificar se a planilha já aberta no seu Excel ou em rede (no caso de ser compartilhada)?

[Jefferson TS]

Caso somente a planilha fluxo de caixa esteja aberta (a qual vai executar a macro), não dá erro nenhum.

Porém, se alguma das outras planilhas já estiver aberta dá erro pra depurar, pede ser quer reabrir planilha e abre o depurador.

[Midori]

@Jefferson TS  Seria algo assim que está tentando fazer? Para a sua macro não abrir o mesmo arquivo duas vezes?

 

Arquivo = "\\SERVIDOR\Users\Usuario\Desktop\FLUXO DE CAIXA\CONTAS A PAGAR.xlsm"
    
If PlanilhaAberta(Arquivo) = False Then
    Workbooks.Open Arquivo
End If

 

Assim teria que implementar a função para retornar se você ou a macro já abriu a planilha.

[Jefferson TS]

Em 14/05/2021 às 17:28, Midori disse:

Seria algo assim que está tentando fazer? Para a sua macro não abrir o mesmo arquivo duas vezes?

 

Isso mesmo. Tentei conforme abaixo e deu este erro

 

[Midori]

@Jefferson TS Com On Error GoTo poderia usar uma função boolean para testar o Erro 9 ao tentar retornar o nome de uma planilha. A função vai ter como parâmetro o caminho do arquivo e se a planilha não estiver aberta, vai gerar o erro na atribuição do nome, p.ex,

 

Function PlanilhaAberta(ByVal Arquivo As String) As Boolean
    Dim N As String
    On Error GoTo FIM:
    N = Split(Arquivo, "\")(UBound(Split(Arquivo, "\")))
    N = Workbooks(N).Name
    PlanilhaAberta = True
FIM: If Err.Number = 9 Then PlanilhaAberta = False
End Function

 

Antes de tentar abrir a planilha sua macro pode passar o caminho do arquivo para a função. Se não quiser criar um if para cada um pode usar um array e fazer um loop assim,

 

Sub Abrir()
    Dim Arquivos    As Variant
    Dim Planilha    As Variant
        
    Arquivos = Array( _
        "\\SERVIDOR\Users\Usuario\Desktop\FLUXO DE CAIXA\CONTAS A PAGAR.xlsm", _
        "\\SERVIDOR\Users\Usuario\Desktop\FLUXO DE CAIXA\ORDEM DE SERVIÇO.xlsm", _
        "\\SERVIDOR\Users\Usuario\Desktop\PREFEITURA 2021\Prefeitura Caminhões.xlsm", _
        "\\SERVIDOR\Users\Usuario\Desktop\PREFEITURA 2021\Prefeitura Máquinas.xlsm")
    
    For Each Planilha In Arquivos
        If Not PlanilhaAberta(Planilha) Then
            Workbooks.Open Planilha
        End If
    Next Planilha
End Sub

 

[Jefferson TS]

Nossa. Funcionou perfeitamente. Muito obrigado e parabéns.