VisualG Esperava encontrar então visualg

[dve]

var
nomes_vet: vetor[1..5] de caractere
nomes: caractere
contador: inteiro
inicio
// Entrada de Dados
para contador de 1 ate 5 faca
escreva("Digite o nome de cinco pessoas: ")
leia(nomes_vet[contador])
fimpara
escreval("Digite um nome para ser buscado: ")
leia(nomes)
se nomes=contador[nomes_vet] ENTAO
escreva("ACHEI.")
senao
escreva("NÃO ACHEI.")
fimse

fimalgoritmo

Salve salve familia. Eu aqui dnv vindo pedir ajuda de vocês. Então, terminei esse codigo, só que na linha 21 consta que esperava encontrar entao, mas o entao ta ali ;(, onde q errei? Enunciado abaixo. 

 

Ler um vetor com 5 nomes de pessoas, após pedir que o usuário digite um nome
qualquer de pessoa. Escrever a mensagem “ACHEI”, se o nome estiver armazenado no
vetor ou “NÃO ACHEI” caso contrário.

[Simon Viegas]

Em 11/09/2021 às 15:38, dve disse:

se nomes=contador[nomes_vet] ENTAO

 

Essa sintaxe não existe no VisualG. A variável contador é do tipo inteiro, ou seja: ele não é um vetor. Assim como o nomes_vet é um vetor e não poderia ser utilizado como uma coordenada de um suposto vetor...

 

Segue um exemplo de possível solução:

 

algoritmo "Localizar nome em vetor"
var
   nomes_vet: vetor[1..5] de caractere
   nome_busca: caractere
   contador: inteiro
   achei: logico
inicio
   escreval("Digite o nome de cinco pessoas: ")
   para contador de 1 ate 5 faca
      escreva ("Nome: ")
      leia(nomes_vet[contador])
   fimpara

   escreval("Digite um nome para ser buscado: ")
   leia(nome_busca)

   achei <- FALSO
   para contador de 1 ate 5 faca
      se nome_busca = nomes_vet[contador] entao
         achei <- VERDADEIRO
      fimSe
   fimPara

   se achei = VERDADEIRO entao
      escreva("ACHEI")
   senao
      escreva("NÃO ACHEI")
   fimSe
fimAlgoritmo