Outro Como eu faço para gerar zip usando um .bat mas definindo as extensoes

[Pedro_Neres]

Eu preciso de um .bat para fazer backup automático e necessito que seja possível zipar algumas extensões ex: .dbf, .dll, e .fr3
Como eu faria isso?

[ricardo_br]

Deixa eu ver se entendi. Você quer criar backup usando arquivos zip mais apenas de algumas extenões?

 

Digamos que você tenha uma pasta chamada Fonte e uma pasta chamada Backup

 

E dentro da pasta Fonte tem tem:

 

Teste 01.jpg

Teste 02.txt

Teste 03.dbf

Teste 04.dll

Teste 05.fr3

Teste 06.docx

 

Ai salva um fonte.zip que tem os arquivos (Teste 03.dbf,Teste 04.dll e Teste 05.fr3) em Backup é isso?

 

Basicamente você pode usar 7zip, winrar ou powershell para criar os arquivos zip...

 

 

 

[Pedro_Neres]

@ricardo_br

Teoricamente sim.
Eu poderia usar programas terceiros para fazer, porém necessito que seja um prompt de comando agendado nas tarefas do windows

@ricardo_br

tentei usar essa linha de comando mas  da erro no windows e não consegue localizar os arquivos, com certeza está errado minha linha de raciocínio. Porém precisava que fosse mais ou menos assim, pegar somente as extensões e incorporar em um .zip

 

 

"C:\program Files\WinRar\Rar.exe" a -agDDMMYYY-HHMM \\C$\Backup teste\ C:\Logitech\ .dll, .fr3, .dbf

pause

 

Sobre o seu questionamento:

"Ai salva um fonte.zip que tem os arquivos (Teste 03.dbf,Teste 04.dll e Teste 05.fr3) em Backup é isso?"

Não, no caso eu precisaria pegar os arquivos .dll, .dbf e .fr3 de dentro da pasta fonte, adicionar todos a um "backup.zip" e salvar em uma nova pasta

[ricardo_br]

O prompt de comando do winrar "rar.exe" é incapaz de criar arquivos zip que possam ser abertos pelo Explorador de Arquivos (Windows Explorer). No caso você teria que usar a ferramenta gráfica dele winrar.exe mais nela você também pode passar parâmetros igual o "rar.exe".

 

No caso digamos que a Fonte seja uma pasta na área de trabalho e o Destino também sejam uma pasta na área de trabalho ficaria algo assim:

 

Usando o Winrar ficaria algo assim:

 

@echo off

set Fonte=%userprofile%\desktop\Fonte
set Destino=%userprofile%\desktop\Destino
set WinRar=C:\Program Files\WinRAR\WinRAR.exe

for %%a in ("%Fonte%") do set "NFonte=%%~nxa"

pushd "%Fonte%"
"%WinRar%" a -ep1 -y -ag" DD-MM-YYYY-HH-MM" "%Destino%\%NFonte%.zip" *.dbf *.dll *.fr3

 

Usando o 7-zip ficaria algo assim:

 

@echo off

set Fonte=%userprofile%\desktop\Fonte
set Destino=%userprofile%\desktop\Destino
set Seven=C:\Program Files\7-Zip\7z.exe

for %%a in ("%Fonte%") do set "NFonte=%%~nxa"

Set "Data=%Date%-%Time:~0,5%"
set "Data=%Data:/=-%"
set "Data=%Data::=-%"
set "Data=%Data: =0%
echo %Data%

pushd "%Fonte%"

"%Seven%" a -y -tzip "%Destino%\%NFonte% %Data%.zip" *.dbf *.dll *.fr3

 

 

Usando o Powershell seria o cmdlet "Compress-Archive" mais como não tenho esse cmdlet instalado no meu Windows 8.1 não tive como testar.

 

 

[Pedro_Neres]

Beleza, vai me ajudar bastante. Muito Obrigado!