Como altero valor "Destino" de vários atalhos duma vez?

[LMGarrido]

Olá. Fiz no Notebook alguns atalhos (mais de 100) do VLC de canais de TV (AZ-America), que utilizam um IP para funcionamento. Exemplo: "D:\Program Files\VideoLAN\VLC\vlc.exe" "http://192.168.1.103:8085/player.15466893". Isso está escrito no "destino" do atalho. O problema é que de vez em quando o número IP se modifica. Gostaria de saber como eu posso alterar o número IP em lote, para mudar o IP de todos os atalhos e não de um em um.

Desde já obrigado.

[ricardo_br]

@LMGarrido Poderia colocar um desses atalhos em anexo.

[LMGarrido]

Um deles

[ricardo_br]

E os atalhos estão todos na mesma pasta? Poderia colocar alguns em uma arquivo ZIP e anexar aqui?

[LMGarrido]

Sim. Os atalhos estão todos na mesma pasta.

 

AZ-América Champions.rar

[ricardo_br]

Todos os atalhos devem mudar para o mesmo IP correto? Você digita um IP e ai todos os atalhos devem mudar o IP para aquele IP especificado e o resto do link fica tudo igual?

[LMGarrido]

Sim. Correto.

[ricardo_br]

Não tenho Windows 11 mais acredito que não tenha meio de fazer isso por meios nativos do Windows 11. A solução seria criar um script powershell, VBS ou outro como phyton etc que faça a função.

 

Fiz uns testes com um script hibrido (batch & VBS) veja se seria isso o resultado esperado:

 

 

[LMGarrido]

É isso mesmo. Na mosca. Melhor impossível. Obrigado.

[ricardo_br]

Aqui vão as instruções:

 

Passo 01: Copie o código abaixo e cole no bloco de notas (notepad)

 

@echo off
chcp 1252 > nul
mode con: cols=50 lines=12
if /i exist "%~1" (if /i not exist "%~1\" (exit) else (set "Pasta=%~1")) else (exit)

echo.
set /p "NovoIP=Informe o novo IP: "
pushd "%Pasta%"
for /f "Delims=" %%a in ('dir /b *.lnk') do call :PegaDestino "%%~fa"                                            

exit

:PegaDestino

>"%temp%\PegaParametro.vbs" echo strTargetPath="%~1"

>>"%temp%\PegaParametro.vbs" echo Set wshShell    = CreateObject^("WScript.Shell"^)
>>"%temp%\PegaParametro.vbs" echo Set objShortcut = wshShell.CreateShortcut^(strTargetPath^)
>>"%temp%\PegaParametro.vbs" echo WScript.Echo objShortcut.Arguments

for /f "Delims=" %%a in ('CScript.exe "%temp%\PegaParametro.vbs"') do set Parametro=%%a
for /f tokens^=^1^,^2^ delims^=^" %%a in ("%Parametro%") do (
                                                             set Parametro1=%%a
                                                             set Parametro2=%%b
                                                            )

for /f "tokens=2 Delims=:/" %%a in ("%Parametro%") do set IP=%%a

call set Parametro1=%%Parametro1:%IP%=%NovoIP%%%

>"%temp%\SalvaParametro.vbs" echo Par1 = "%Parametro1%"
>>"%temp%\SalvaParametro.vbs" echo Par2 = "%Parametro2%"
>>"%temp%\SalvaParametro.vbs" echo Dim objShortcut, objShell
>>"%temp%\SalvaParametro.vbs" echo Set objShell = WScript.CreateObject ^("Wscript.Shell"^)
>>"%temp%\SalvaParametro.vbs" echo Set objShortcut = objShell.CreateShortcut ^("%~1"^)
>>"%temp%\SalvaParametro.vbs" echo objShortcut.Arguments = chr(34) ^& Par1 ^& chr(34) ^& Par2
>>"%temp%\SalvaParametro.vbs" echo objShortcut.Save
>>"%temp%\SalvaParametro.vbs" echo WScript.Quit
cls
echo.
echo  Modificando "%~nx1"
echo  %IP% -^> %NovoIP%

"%temp%\SalvaParametro.vbs"	

goto :EOF

 

Passo 02: Salve o arquivo com o nome que você quiser mais com extensão de arquivo *.bat

 

Passo 03: Faça uma cópia dos atalhos em local seguro para o caso de algo der errado.

 

Passo 04: Arraste a pasta onde estão os atalhos para o arquivo *.bat que você criou

 

Passo 05: Na parte "Informe o novo IP" você devera especificar o novo IP que deseja usar e depois pressionar ENTER

 

 

 

[LMGarrido]

Fiz um teste e perfeito. Obrigado de novo!