VisualG Meu visualg esta dando um erro, e não sei como resolver.

[Mr-86]

Algoritmo "semnome"

Var

   preco, litros, reajuste, valorfinal, precogas: real
   tipocomb: caractere

Inicio

      escreva("qual o tipo de combustivel ?? A/G : ")
      leia(tipocomb)

      escreva("quantos litros voce ira querer ?? : ")
      leia(litros)

      escolha(tipocomb)
       caso"A" //alcool
        precogas <- 4.50
         se(litros <= 20)entao
           reajuste <- 2
          senao
            reajuste <- 4
         fimse

       caso"G" //gasolina
        precogas <- 3
           se(litros <= 15)entao
             reajuste <- 3.5
            senao
              reajuste <- 6
           fimse

      fimescolha

      preco <- precogas * litros
      valorfinal <- (preco * reajuste)/100 //calcular o desconto
      escreva("O valor total a pagar é: ",valorfinal)

fimalgoritmo

quando executo o codigo ele diz que esperava um "fimalgoritmo". mas o mais estranho é que ele sempre fala que o erro esta duas linhas abaxio da ultima coisa escrita.

alguém poderia me ajudar

[kgin]

16 horas atrás, Mr-86 disse:

quando executo o codigo ele diz que esperava um "fimalgoritmo". mas o mais estranho é que ele sempre fala que o erro esta duas linhas abaxio da ultima coisa escrita.

alguém poderia me ajudar

Pelo que eu percebi e por causa do comando caso está próximo da letra, é também porque você comentou na mesma linha do comando caso

16 horas atrás, Mr-86 disse:

caso"A" //alcool

deixe dessa maneira que funciona.

	// Alcool
	caso "A"

 

seu algoritmo corrigido

Algoritmo "semnome"

Var

   preco, litros, reajuste, valorfinal, precogas: real
   tipocomb: caractere

Inicio

   escreva("qual o tipo de combustivel ?? A/G : ")
   leia(tipocomb)

   escreva("quantos litros voce ira querer ?? : ")
   leia(litros)

   escolha (tipocomb)
      // Alcool
   caso "A"
      precogas <- 4.50
      se(litros <= 20)entao
         reajuste <- 2
      senao
         reajuste <- 4
      fimse
      // Gasolina
   caso "G"
      precogas <- 3
      se(litros <= 15)entao
         reajuste <- 3.5
      senao
         reajuste <- 6
      fimse

   fimescolha

   preco <- precogas * litros
   valorfinal <- (preco * reajuste)/100 //calcular o desconto
   escreva("O valor total a pagar é: ",valorfinal)

fimalgoritmo

O seu calculo do combustível está errado.

[devair1010]

@Mr-86    e também você colocou o "caso"  junto da opção "A"  sem pular espaços , assim o visualg entende como sendo uma coisa só ,  e esse compilador nem sempre mostra o erro mesmo , mas diz que tem um erro , e assim você que precisa descobrir qual é .

[Mr-86]

@kgin @devair1010  obrigado aos dois, me fizeram perceber erros minúsculos meus. 

[Simon Viegas]

16 horas atrás, kgin disse:

Pelo que eu percebi e por causa do comando caso está próximo da letra, e também porque você comentou na mesma linha do comando caso

 

Normalmente era para aceitar os comentários no lado, mas tem coisas que não funcionam bem no VisualG (toda versão tem uns bugs!). Deixando acima da linha ajuda a evitar.