Excel vba - incluir novo cadastro/consultar cadastro

[RAIMUNDO LIMA DE ARAUJO]

Prezados, boa noite. 

Alguém pode me ajudar? 

Estou cadastrando os dados dos motoristas na aba(CADASTRO MOTORISTA), gostaria de ao digitar o CPF na ABA(Ordem de carregamento), o exel retornar-se pra mim o Nome e as placas do motoristas. 

Queria vê se é possível fazer botão para:

1. Incluir novo cadastro
2. Consultar se já tem cadastro com base no CPF se não, apareceria o botão, realizar novo cadastro. 
3.  

ORDEM DE CARREGAMENTO.xlsx.xlsm.zip

[Midori]

Para retornar os dados da planilha de cadastro você pode usar um Procv ou Procx para fazer a busca pelo CNPJ. Sobre incluir um novo cadastro, você pode dar essa opção caso a fórmula não encontre.

[RAIMUNDO LIMA DE ARAUJO]

@Midori poderia me ajudar, fazendo esse cadastro vba e consulta dos dados cadastro em VBA? ?

[Midori]

@RAIMUNDO LIMA DE ARAUJO Sua planilha pode ter os dois procedimentos. Só é preciso definir um evento para chamar cada um, pode ser por meio de um botão ou Change da planilha. O procedimento de Consulta deve ser o primeiro a ser chamado, já que se em contrar o CPF na base retornará os dados no formulário, caso contrário será o critério para cadastrar o novo registro, p.ex,

 

Sub Ordem()
    Dim PlanOrdem   As Worksheet
    Dim Registro    As Range
    Dim Tabela      As ListObject
    
    Set Tabela = ThisWorkbook.Sheets("CADASTRO MOTORISTA").[Tabela8].ListObject
    Set PlanOrdem = ThisWorkbook.Sheets("ORDEM DE CARREGAMENTO")
    Set Registro = Consulta(Tabela.ListColumns("CPF"), PlanOrdem.[C14])

    If Registro Is Nothing Then
        Call Cadastra(Tabela, _
            PlanOrdem.[C11], _
            PlanOrdem.[C14], _
            "1111111111", _
            PlanOrdem.[J11], _
            PlanOrdem.[L11], _
            PlanOrdem.[N11])
    Else
        PlanOrdem.[C11] = Registro.Offset(0, -1)
        PlanOrdem.[J11] = Registro.Offset(0, 2)
        PlanOrdem.[L11] = Registro.Offset(0, 3)
        PlanOrdem.[N11] = Registro.Offset(0, 4)
    End If
End Sub

Function Consulta(Coluna As ListColumn, Texto As String) As Range
    If Not Coluna.DataBodyRange Is Nothing Then
        Dim Registro    As Range
        
        Set Registro = Coluna.DataBodyRange.Find( _
            What:=Texto, LookIn:=xlValues, LookAt:=xlWhole)
        
        If Not Registro Is Nothing Then
            Set Consulta = Registro
        End If
    End If
End Function

Sub Cadastra(Tabela As ListObject, Nome As String, _
    CPF As String, Telefone As String, _
    Cavalo As String, Carreta1 As String, Carreta2 As String)
    Dim Linha   As ListRow
    
    Set Linha = Tabela.ListRows.Add
    Linha.Range = Array(Nome, CPF, Telefone, Cavalo, Carreta1, Carreta2)
End Sub

 

Assim você pode adaptar o código, execute a Sub Ordem para testar.

[RAIMUNDO LIMA DE ARAUJO]

@Midori

Como enviar arquivo salva em PDF para whatsapp?

[Midori]

@RAIMUNDO LIMA DE ARAUJO Nativamente o Excel não tem esse recurso, mas você pode tentar com sendkeys que é um procedimento que simula o teclado. Se procurar vai encontrar tópicos sobre isso aqui no fórum.

[RAIMUNDO LIMA DE ARAUJO]

@Midori

Boa noite, 

Peço ajuda novamente? 

Usei o codigo que você mandou para cadastrar deu certo, poderia me ajudar para verificar se já tem um dado cadastrado com aquele CPF? E se não tiver apare a mensagem realizar novo cadastro. 

E se possível,poderia incluir também para retornar os dados cadastrados ao digitar o CPF?

Ou seja, digitou CPF, ele retorna Nome e Placas. 

Vi que no codigo tem Consulta, mas não consegui aplicar

[Midori]

@RAIMUNDO LIMA DE ARAUJO Para verificar o dado é com a função Consulta. Ela tem dois parâmetros, o primeiro é do campo da tabela e o segundo é o dado. Se nada for encontrado a função retorna Nothing, caso contrário retorna o range. No caso do CPF deve ser exatamente como está cadastrado, então se tiver zeros a esquerda (no formato texto) ou pontuação, a busca também deve ter.

 

Quando o resultado é encontrado você pode fazer como no código que postei que pega os deslocamentos do range na tabela, p.ex,

PlanOrdem.[C11] = Registro.Offset(0, -1)
PlanOrdem.[J11] = Registro.Offset(0, 2)
PlanOrdem.[L11] = Registro.Offset(0, 3)
PlanOrdem.[N11] = Registro.Offset(0, 4)

 

O Offset(0,-1) é o Nome, o Offset(0, 3) é a Carreta1, etc.

 

Outro exemplo de busca com a função,

Sub Teste()
    Dim Registro As Range
    
    Set Registro = Consulta([Tabela8].ListObject.ListColumns("CPF"), "00073967165")
    
    If Registro Is Nothing Then
        MsgBox "Dado não encontrado"
    Else
        MsgBox "O dado está na célula " & Registro.Address
    End If
End Sub