Excel localizar informações na tabela

[Jeff_Sandes]

Estou com uma planilha onde contém os dados de paradas de um equipamento, onde as colunas indicam as horas e as linhas indicam os minutos. Seria possível criar um código VBA capaz de localizar qual hora e minuto o equipamento parou e qual hora voltou a funcionar? Na planinha a baixo tem as seguintes informações, parou às 8hrs e 3min e voltou a funcionar às 8hrs e 47min, em seguida parou novamente às 10hrs e 59min e voltou a funcionar às 13hrs e 37mins.

teste.xlsx

[Midori]

@Jeff_Sandes Como essas informações devem ser apresentadas? Na planilha tem vários casos e horários, é para localizar todos e mostrar uma lista?

[Jeff_Sandes]

@Midori O resultado é uma lista contento o horário que parou e que voltou a rodar

 

[Midori]

@Jeff_Sandes Veja se assim resolve,

 

Sub Atualiza()
    Call RegistraEvento([C3:Z62], [AB2])
End Sub

Sub RegistraEvento(Tabela As Range, Registro As Range)
    Dim Evento      As Range
    Dim Inicio      As String
    Dim Fim         As String
    Dim Anterior    As String
    Dim Coluna      As Integer
    Dim Linha       As Long
    
    For Coluna = 1 To Tabela.Columns.Count
        Linha = 0
        For Each Evento In Range(Tabela.Columns(Coluna).Address)
            Linha = Linha + 1
            If Evento.Value <> Anterior Then
                If Evento.Value = "Inactive" Then
                    Inicio = Tabela(0, Coluna) & ":" & Tabela(Linha, 0)
                Else
                    If Inicio <> "" Then
                        Fim = Tabela(0, Coluna) & ":" & Tabela(Linha, 0)
                    End If
                End If
            End If
            
            If Inicio <> "" And Fim <> "" Then
                Registro(1, 1).Value = Inicio
                Registro(1, 2).Value = Fim
                Set Registro = Registro(2)
                Fim = ""
            End If
        Anterior = Evento.Value
        Next Evento
    Next Coluna
End Sub

 

[Jeff_Sandes]

@Midori Deu super certo!!!  Nossa espero muito aprender o suficiente pra chegar a esse nível